如何迭代这个复杂数据结构的各个部分？

Question

我有一个用 Data::Dumper 打印的对象：

$VAR1 = {
          'record' => [
                      {
                        'text' => 'booting kernel',
                        'version' => '2',
                        'iso8601' => '2011-06-23 11:57:14.250 +02:00',
                        'event' => 'system booted',
                        'modifier' => 'na'
                      },
                      {
                        'text' => 'successful login',
                        'subject' => {
                                     'sid' => '999',
                                     'uid' => 'user',
                                     'audit-uid' => 'user',
                                     'tid' => '0 0 unknown',
                                     'ruid' => 'user',
                                     'rgid' => 'gsp',
                                     'pid' => '999',
                                     'gid' => 'gsp'
                                   },
                        'version' => '2',
                        'iso8601' => '2011-06-23 11:58:00.151 +02:00',
                        'event' => 'login - local',
                        'return' => {
                                    'retval' => '0',
                                    'errval' => 'success'
                                  },
                        'host' => 'unknown'
                      },
                    ],
          'file' => {
                    'iso8601' => '2011-06-23 11:57:40.064 +02:00'
                  }
        };

我想打印导航这样的每个值一个哈希值。据我了解，是一个具有两个键（记录、文件）的哈希，记录指向哈希数组。

您能帮助实现该结构的每个值吗？

我尝试过：

my @array=$VAR1{'record'};
foreach (@array) {
    print $_{'text'};    
}

……但不起作用。

Answer 1

如果您只想迭代它，您可以执行以下操作：

iterate($VAR1);

sub iterate {
    my $input = shift;
    unless (ref $input) {
        print "$input\n";
    } elsif (ref $input eq 'ARRAY') {
        iterate($_) for @$input;
    } elsif (ref $input eq 'HASH') {
        for (keys %$input) {
            print "$_\n";
            iterate($input->{$_});
        }
    } else {
        print ref $input,"\n";
    }
}

这并不像 Data::Dumper 那样完全漂亮地打印它，但如果您想对任意嵌套结构执行其他任何操作，则该技术可能很有用。不太了解。

Answer 2

$VAR1{record} 是数组引用，而不是数组。要访问数组，您需要取消引用：

my @array = @{ $VAR1->{record} };

数组中的每个元素都是哈希引用，因此：

for my $record ( @array ) {
    print $record->{text};
}

Answer 3

$VAR1 是一个参考。您需要取消引用它。
$VAR1->{record} 是一个参考。您也需要取消引用它。
$_ 也是一个引用，因此您需要取消引用它。

perldoc perlreftut

my @array = @{ $VAR1->{'record'} };
foreach (@array) { 
    print $_->{'text'}; 
}