检查 PATH 中是否存在文件

Question

我有这样的东西：

if(! -e $filename) {
    # do something
}

但我需要更改它，以便它甚至在我的路径上查找文件。有没有办法在不分析 PATH 的情况下实现这一目标？

Answer 1

文件::Which

Answer 2

如何在不查看 $ENV{PATH} 的情况下查看文件是否位于 $ENV{PATH} 指定的目录之一中？ ……这是一个反问句。

这是我不久前编写的简短脚本。您应该能够根据您的需求进行调整：

#!/usr/bin/perl

use strict; use warnings;

use File::Basename;
use File::Spec::Functions qw( catfile path );

my $myname = fileparse $0;
die "Usage: $myname program_name\n" unless @ARGV;

my @path = path;
my @pathext = ( q{} );

if ( $^O eq 'MSWin32' ) {
    push @pathext, map { lc } split /;/, $ENV{PATHEXT};
}

PROGRAM: for my $progname ( @ARGV ) {
    unless ( $progname eq fileparse $progname ) {
        warn "Not processed: $progname\n\tArgument is not a plain file name\n";
        next PROGRAM;
    }

    my @results;

    for my $dir ( @path ) {
        for my $ext ( @pathext ) {
            my $f = catfile $dir, "$progname$ext";
            push @results, $f if -x $f;
        }
    }

    print "$progname:\n";
    print "\t$_\n" for @results;
}

Answer 3

系统在加载可执行文件时使用 PATH 变量。因此，为了让底层系统为您完成工作，我相信您需要尝试加载可执行文件。听起来这不是您想要做的。

很可能有一些库可以提供此类功能，但编写自己的库非常简单。您只需要使用 split 然后迭代即可。

Answer 4

补充 daxim 和 Sinan Ünür 的 有用的答案：

在有限情况下，如果您只关心是否给定的程序在系统路径中，您可以采取捷径：

如果目标程序是一个具有无副作用选项（除了生成标准输出）的 CLI，该选项会导致程序成功退出非常快 - 例如，--version - 您可以执行以下操作：

my $exe = 'bash';   # example
`$exe --version` || die "'$exe' not found.";

Answer 5

如果你想使用核心模块，有 can_run() 来自 IPC::Cmd。

use IPC::Cmd qw(can_run);
if (can_run($filename)) {
    # do something
}

File::Which 的 perldoc 指出了一个警告，即这也将搜索当前目录，即使那不在你的路径中：

IPC::Cmd

带有一个“can_run”函数，其语义略有不同
传统的UNIX在哪里。它将在当前目录中查找可执行文件
目录，即使当前目录未被搜索
Unix 上的默认值。