在 Perl 中，我如何找到上周四的日期？

Question

可能的重复：
在 Perl 中，如何找到给定日期的上周一的日期？

在perl中，如何编写一个函数来获取上周四的日期？今天（11/21），我想要11/17。如何判断给定日期是否是星期日？

Answer 1

看起来像是 DateTime 的作品（通常推荐在 Perl 中操作日期的模块）。这个小例子应该可以回答您的两个问题：

use strict;
use warnings;

use DateTime;

my $d = DateTime->now;

while ( $d->day_of_week != 4 ) {
    $d->subtract( days => 1 );
}

print $d->ymd;

Answer 2

其他帖子也使用 DateTime，但它们存在本文所解决的问题。

use DateTime qw( );
my $dt = DateTime->today( time_zone => 'local' );
$dt->subtract( days => ($dt->day_of_week - 4) % 7 );
say $dt->ymd('');  # 20111117

解决的问题：

• 使用当地日期而不是英格兰境内或附近的日期。
• 使用today 而不是now，因为您只处理日期。
• 避免不必要的循环。

注意：

• 返回当前日期今天是星期四。您接受了同样的答案，所以我认为这就是您想要的。

---

更新：上述操作可能在某些日期、某些时区失败。 （并非所有日子都有午夜！）解决方案：

use DateTime qw( );
my $dt = DateTime->now( time_zone => 'local' );
$dt->set_time_zone('floating');
$dt->truncate( to => 'days' );
$dt->subtract( days => ($dt->day_of_week - 4) % 7 );
say $dt->ymd('');  # 20111117

Answer 3

我会使用拉森写的内容，尽管阅读 本地时间参考 不会伤害你。你可以这样做来检查是否是周日：

($second, $minute, $hour, $dayOfMonth, $month, $yearOffset, 
                         $dayOfWeek, $dayOfYear, $daylightSavings) = localtime();
if ($dayOfWeek == 0) print("Don't go to work!");

Answer 4

如果您想要测试的只是星期几，则 localtime() 的数组切片可以很好地工作：

print q(Today is Sunday) if ((localtime)[6]==0)

Answer 5

您还可以使用 Date::Calc：

如何计算任何给定日期的最后一个星期六和下一个星期六？

  use Date::Calc qw( Today Day_of_Week Add_Delta_Days
                     Day_of_Week_to_Text Date_to_Text );

  $searching_dow = 6; # 6 = Saturday

  @today = Today();

  $current_dow = Day_of_Week(@today);

  if ($searching_dow == $current_dow)
  {
      @prev = Add_Delta_Days(@today,-7);
      @next = Add_Delta_Days(@today,+7);
  }
  else
  {
      if ($searching_dow > $current_dow)
      {
          @next = Add_Delta_Days(@today,
                    $searching_dow - $current_dow);
          @prev = Add_Delta_Days(@next,-7);
      }
      else
      {
          @prev = Add_Delta_Days(@today,
                    $searching_dow - $current_dow);
          @next = Add_Delta_Days(@prev,+7);
      }
  }

  $dow = Day_of_Week_to_Text($searching_dow);

  print "Today is:      ", ' ' x length($dow),
                               Date_to_Text(@today), "\n";
  print "Last $dow was:     ", Date_to_Text(@prev),  "\n";
  print "Next $dow will be: ", Date_to_Text(@next),  "\n";

Answer 6

use Date::Calc qw(:all);

($week, $year) = Week_of_Year(Today());# Week_of_Year(2011,11,21);
print Date_to_Text(Add_Delta_Days(Monday_of_Week($week - 1,$year),3));#THU - MON = 3
#output:Thu 17-Nov-2011

#isSunday?
Day_of_Week(2011,11,20) == 7 # 7 is Sunday enum code(from 1 : Monday)

Answer 7

仅使用 localtime 和 POSIX 基础模块，您可以这样做：

my @ltime = localtime();
my $t 
    = POSIX::mktime(( 0 ) x 3
    , $ltime[3] - ( 7 - 4 + $ltime[6] )
    , @ltime[4,5] 
    );

这将始终为您提供最后一个星期日之前的最后一个星期四。因此，如果当天是星期六，它将为您提供上一周的星期四，但如果当天是星期日，它将为您提供过去的最后一个星期四。

如果您更喜欢上周四的计算，您可以这样做：

my $t 
    = POSIX::mktime(( 0 ) x 3
    , $ltime[3] - $ltime[6] + ( $ltime[6] > 4 ?  4 : -3 )
    , @ltime[4,5] 
    );

Answer 8

Date::Simple 有一个非常干净的界面。

#!/usr/bin/perl
use strict;
use warnings;
use Date::Simple qw/ today /;

my $d = today;

# If today is already Thurs, subtract 1 before searching for prior Thursday.
# If today is Thurs and you want to capture that (and not Thur a week ago),
# don't subtract the 1 from $d.
$d--; 

$d-- while $d->day_of_week != 4;    
print $d->strftime("%Y%m%d");