按值进行简单哈希搜索

Question

我有一个简单的散列，并且想根据 $value 标准返回 $key 。也就是说，对于第 14 行，我需要什么代码来返回 $key（其中 $value 为“黄色”）？

1  #!/usr/bin/perl
2
3  # This program creates a hash then
4  # prints out what is in the hash
5
6  %fruit = (
7   'apple' => ['red','green'],
8   'kiwi' => 'green',
9   'banana' => 'yellow',
10  );
11
12 print "The apple is @{$fruit{apple}}.\n";
13 print "The kiwi is $fruit{kiwi}.\n";
14 print "What is yellow? ";

Answer 1

grep 是完成这项工作的正确工具：

my @all_matches = grep { $fruit{$_} eq 'yellow' } keys %fruit;
print("$_ ") foreach @matching_keys;

my ($any_match) = grep { $fruit{$_} eq 'yellow' } keys %fruit;

Answer 2

我不太确定使用单向哈希是否可以轻松有效地完成这一任务。哈希的全部要点是将键转换为值（如果您正在查看幕后，则将其转换为值的位置）。您可以对所有值进行详尽的搜索，同时收集键，但这不如哈希查找那么有效。

为了有效地采用另一种方式，您可能需要考虑双向哈希，例如：

%fruit = (
    'apple' => ['red','green'],
    'kiwi' => 'green',
    'banana' => 'yellow',
);
%antifruit = (
    'red' => 'apple',
    'green' => ['apple','kiwi'],
    'yellow' => 'banana',
);
print "The apple is @{$fruit{'apple'}}.\n";
print "The kiwi is $fruit{'kiwi'}.\n";
print "A yellow thing is $antifruit{'yellow'}.\n";

Answer 3

sub find_key { 
    my ( $h, $value ) = @_;
    while ( my ( $k, $v ) = each %$h ) { 
        return $k if $v eq $value;
    }
    return;
}

所以你可以这样称呼它：

find_key( \%fruit, 'yellow' );

Answer 4

由于某些值是数组，因此您需要检查这一点。

调用：

my @fruit = getfruit(\%fruit, $colour);

子例程：

sub getfruit {
    my ($fruit, $col) = @_;
    my @result;
    for my $key (keys %$fruit) {
        if (ref $fruit->{$key} eq 'ARRAY') {
            for (@{$fruit->{$key}}) {
                push @result, $key if /^$col$/i;
            }
        } else {
            push @result, $key if $fruit->{$key} =~ /^$col$/i;
        }
    }
    return @result;
}

使用正则表达式代替 eq 是可选的，只需注意保持相同的大小写，因为 Yellow 和 黄色被认为是不同的键。

Answer 5

我注意到你的例子引用了匿名数组，所以我只会做一个冗长的 foreach/if 循环：

my %fruit = (
  'apple' => ['red','green'],
  'kiwi' => 'green',
  'banana' => 'yellow',
);

print "The apple is @{$fruit{apple}}.\n";
print "The kiwi is $fruit{kiwi}.\n";
print "What is yellow? ";

my $ele;
my $search = 'yellow';
my @match = ();

foreach $ele (keys(%fruit)) {
    if(ref($fruit{$ele}) eq 'ARRAY' and
        grep { $_ eq $search } @{ $fruit{$ele} }) {
        push(@match, $ele);
    } elsif(!ref($fruit{$ele}) and $fruit{$ele} eq $search) {
        push(@match, $ele);
    }
}
print join(", ", @match) . "\n";