有没有一种简单的方法来验证哈希元素比较的哈希值？

Question

有没有一种简单的方法来验证哈希元素比较的哈希值？

我需要验证哈希元素 $Table{$key1}{$key2}{K1}{Value} 的 Perl 哈希，与哈希中的所有其他元素进行比较，

第三个键将是 k1 到 kn，我想比较这些元素和其他键是相同的

if ($Table{$key1}{$key2}{K1}{Value} eq $Table{$key1}{$key2}{K2}{Value}
    eq  $Table{$key1}{$key2}{K3}{Value} ) 
{
   #do whatever
}

Answer 1

像这样的事情可能会起作用：

use List::MoreUtils 'all';

my @keys = map "K$_", 1..10;

print "All keys equal"
    if all { $Table{$key1}{$key2}{$keys[1]}{Value} eq $Table{$key1}{$key2}{$_}{Value} } @keys;

Answer 2

我会使用 Data::Dumper 来帮助完成这样的任务，特别是对于更一般的问题（其中第三个键比“K1”...“Kn”更任意）。使用 Data::Dumper 将数据结构字符串化，然后比较字符串。

use Data::Dumper;

# this line is needed to assure that hashes with the same keys output
# those keys in the same order.
$Data::Dumper::Sortkeys = 1;

my $string1= Data::Dumper->Dump($Table{$key1}{$key2}{k1});

for ($n=2; exists($Table{$key1}{$key2}{"k$n"}; $n++) {

    my $string_n = Data::Dumper->Dump($Table{$key1}{$key2}{"k$n"});

    if ($string1 ne $string_n) {
        warn "key 'k$n' is different from 'k1'";
    }

}

这可用于更一般的情况，其中 $Table{$key1}{$key2}{k7}{value} 本身包含复杂的数据结构。然而，当检测到差异时，它并不能帮助您找出差异在哪里。

Answer 3

相当复杂的结构。您应该考虑使用面向对象的编程技术。这将大大简化您的编程和这些复杂结构的处理。

首先，让我们简单一点。当你说：

$Table{$key1}{$key2}{k1}{value}

你真的是说：

my $value = $Table{$key1}->{$key2}->{k1};

或者

my $actual_value = $Table{$key1}->{$key2}->{k1}->{Value};

我会假设第一个。如果我错了，请告诉我，我会更新我的答案。

让我们简化一下：

my %hash = %{$Table{$key1}->{$key2}};

现在，我们只处理哈希。您可以使用两种技术：

1. 按值对该哈希的键进行排序，然后如果两个键具有相同的值，它们将在排序列表中彼此相邻，从而轻松检测重复项。优点是所有重复的密钥将被打印在一起。缺点是这是一种需要时间和资源的排序。
2. 反转哈希，因此它是按值作为键的，并且该键的值就是键。如果一个键已经存在，我们就知道另一个键有重复的值。这比第一种技术更快，因为不涉及排序。但是，将检测到重复项，但不会将其打印在一起。

这是第一个技术：

my %hash = %{$Table{$key1}->{$key2}};
my $previous_value;
my $previous_key;
foreach my $key (sort {$hash{$a} cmp $hash{$b}} keys %hash) {
    if (defined $previous_key and $previous_value eq $hash{$key}) {
        print "\$hash{$key} is a duplicate of \$hash{$previous_key}\n";
    }
    $previous_value = $hash{$key};
    $previous_key = $key;   
}

第二个：

my %hash = %{$Table{$key1}->{$key2}};
my %reverse_hash;
foreach $key (keys %hash) {
   my $value = $hash{$key};
   if (exists $reverse_hash{$value}) {
       print "\$hash{$reverse_hash{$value}} has the same value as \$hash{$key}\n";
   }
   else {
       $reverse_hash{$value} = $key;
   }
}

Answer 4

解决这个问题的另一种方法是创建实用程序函数，如果所有键的某个函数返回的值相同，它将比较所有键：

sub AllSame (&\%) {
  my ($c, $h) = @_;
  my @k = keys %$h;
  my $ref;
  $ref = $c->() for $h->{shift @k};
  $ref ne $c->() and return for @$h{@k};
  return 1
}

print "OK\n" if AllSame {$_->{Value}} %{$Table{$key1}{$key2}};

但是如果您开始以这种方式思考，您会发现这种方法更加通用（推荐方式）：

sub AllSame (@) {
  my $ref = shift;
  $ref ne $_ and return for @_;
  return 1
}

print "OK\n" if AllSame map {$_->{Value}} values %{$Table{$key1}{$key2}};

如果映射操作很昂贵，您可以制作相同的惰性对应项：

sub AllSameMap (&@) {
  my $c = shift;
  my $ref;
  $ref = $c->() for shift;
  $ref ne $c->() and return for @_;
  return 1
}

print "OK\n" if AllSameMap {$_->{Value}} values %{$Table{$key1}{$key2}};

如果您只想要键的某些子集，您可以使用哈希切片语法，例如：

print "OK\n" if AllSame map {$_->{Value}} @{$Table{$key1}{$key2}}{map "K$_", 1..10};