使用 Oracle XMLgen 实用程序使用内存表数据创建 XML

Question

我正在 Oracle 中使用 dbms.xmlgen 实用程序从保存到 Oracle 内存表的数据创建 XML 文档。

我的过程是将数据保存在 Oracle 类型 ITEM_ARRAY 中。这是 ITEM_OBJECT 类型的表。

最后，数据出现在我的 ITEM_ARRAY 中。现在我想将这些数据转换为 XML。所以我使用以下代码

ctx:= DBMS_XMLGEN.newContext(' SELECT *  FROM TABLE(CAST(V_ITEMLIST AS ITEM_ARRAY))  where (ITEM_NO is not null or trim(ITEM_NO) is not null) order by ITEM_NO,PARTYABBRVCODE ');
DBMS_XMLGEN.setRowTag (ctx, 'itembom');
DBMS_XMLGEN.setRowSetTag (ctx, 'itemboms');
xmldoc := DBMS_XMLGEN.getXML(ctx); 

我的此代码返回错误 V_ITEMLIST 不存在。

但是当我像这样执行 dbms_out 时

For I In 1..V_Itemlist.Count Loop
Dbms_Output.Put_Line('Partyabbrvcode '||V_Itemlist(I).Partyabbrvcode);
DBms_Output.Put_Line('Item_No'||V_Itemlist(I).Item_No);

，就会返回值。

我尝试了不同的方法，例如将 V_ITEMLIST 保存到光标中，然后调用此代码，如下所示。

ctx := dbms_xmlgen.newContext (ITEMCUR);
xmldoc := DBMS_XMLGEN.getXML(ctx);
DBMS_XMLGEN.closeContext(ctx);

其中项目光标在

SELECT *  FROM TABLE(CAST(V_ITEMLIST AS ITEM_ARRAY))  where (ITEM_NO is not null or trim(ITEM_NO) is not null) order by ITEM_NO,PARTYABBRVCODE.

这也显示错误数字或值错误。

任何人请建议如何实现这一点。

Answer 1

DBMS_XMLGEN.newContext 执行 SQL 查询，但 SQL 无法直接访问 PL/SQL 数据。查询必须调用返回相关数据的函数。

SQL> set long 1000
SQL>
SQL> create or replace package xml_package as
  2     type varchar2_table is table of varchar2(100);
  3     function get_items return varchar2_table pipelined;
  4     function get_xml return clob;
  5  end;
  6  /

Package created.

SQL>
SQL> create or replace package body xml_package as
  2     g_items varchar2_table := varchar2_table();
  3
  4     function get_items return varchar2_table pipelined is
  5     begin
  6             for i in 1 .. g_items.count loop
  7                     pipe row(g_items(i));
  8             end loop;
  9     end;
 10
 11     function get_xml return clob is
 12             v_xml clob;
 13             v_context number;
 14     begin
 15             g_items := varchar2_table('item1', 'item2', 'item3');
 16             v_context := dbms_xmlgen.newContext(
 17                     'select * from table(xml_package.get_items)');
 18             v_xml := dbms_xmlgen.getXML(v_context);
 19             return v_xml;
 20     end;
 21  end;
 22  /

Package body created.

SQL>
SQL> select xml_package.get_xml from dual;

GET_XML
-------------------------------------------------------------------------------
<?xml version="1.0"?>
<ROWSET>
 <ROW>
  <COLUMN_VALUE>item1</COLUMN_VALUE>
 </ROW>
 <ROW>
  <COLUMN_VALUE>item2</COLUMN_VALUE>
 </ROW>
 <ROW>
  <COLUMN_VALUE>item3</COLUMN_VALUE>
 </ROW>
</ROWSET>