Flex 给出是/否框以取消选择复选框

Question

我想在用户取消选择复选框时向他们显示一个确认框。我的代码可以工作，尽管我认为它有点破解。我听到复选框单击的声音，然后显示警报。根据结果​​，我将复选框设置为再次选中。

我的代码是

<?xml version="1.0"?>
<s:NavigatorContent xmlns:fx="http://ns.adobe.com/mxml/2009"   xmlns:s="library://ns.adobe.com/flex/spark" >
<fx:Script><![CDATA[
    import mx.controls.Alert;
    import mx.events.CloseEvent;

    private function handleCheckBoxChange(e:Event):void {
        if (!CheckBox(e.target).selected) {
            Alert.show("Are you sure you want to deselect?", "Confirm",
                Alert.YES | Alert.NO, null, handleAlert, null, Alert.YES);
        }
    }

    public function handleAlert(event:CloseEvent):void {
        if (event.detail == Alert.YES) {
            trace("yes clicked");
        }
        else if (event.detail == Alert.NO) {
            cb1.selected = true;
            trace("no clicked");
        }
    }
    ]]></fx:Script>

    <s:CheckBox id="cb1" label="cb1" click="handleCheckBoxChange(event)"/>
</s:NavigatorContent>

有两件事我不喜欢这个

1. 代码是特定于 cb1 的，不能重用于其他复选框
2. 当警报显示时，复选框被取消选中。然后，当用户单击“否”时，该复选框将再次被选中。

我理想的情况是，如果用户在警报框中单击“否”，则停止取消选中事件。在Flex中可以拦截这个吗？

谢谢

Answer 1

解决您的两个问题的一种解决方案：创建一个扩展 CheckBox 的自定义类。
您不能在 click 事件中使用 e.stopImmediatePropagation()，因为您的事件是稍后添加的。然而，如果你追踪，你可以看到在ToggleButtonBase（它是CheckBox的父级）中包含一个名为buttonReleased的受保护函数；此函数将对selected值进行更改并调度change事件。您在新类中所需要做的就是覆盖此函数。

public class AlertCheckBox extends CheckBox
    {
        public function AlertCheckBox()
        {
            super();
        }

        override protected function buttonReleased():void
        {
            if (selected) {
                Alert.show("Are you sure you want to deselect?", "Confirm",
                    Alert.YES | Alert.NO, null, handleAlert, null, Alert.YES);
                return;
            }

            super.buttonReleased();
        }

        public function handleAlert(event:CloseEvent):void {
            if (event.detail == Alert.YES) {
                selected = false;
            }
        }
    }