如何共享包含文件句柄的对象？

Question

Perl 线程不支持共享文件句柄。共享数据结构的所有元素都必须共享。如果需要共享包含文件句柄的对象，这就会出现问题。

{
    package Foo;
    use Mouse;

    has fh =>
      is      => 'rw',
      default => sub { \*STDOUT };
}

use threads;
use threads::shared;
my $obj = Foo->new;
$obj = shared_clone($obj);           # error: "Unsupported ref type: GLOB"
print {$obj->fh} "Hello, world!\n";

文件句柄是否“共享”并不重要，它仅用于输出。也许有一个技巧可以将文件句柄存储在共享对象之外？

该对象实际上包含在另一个共享对象中，而另一个共享对象又在另一个共享对象中，依此类推。具有讽刺意味的是，所讨论的对象本身从不使用线程，但如果用户使用线程，则必须在整个进程中保持协调。

有问题的真实代码可以在这里看到：这些对象用于配置格式化输出的位置。对象是必要的，因为 输出并不总是发送到文件句柄。

Answer 1

我目前无法访问线程 Perl，因此不能保证这会起作用。

但是一种有点简单的方法是使用抽象级别并将键/索引存储到全局文件句柄哈希/数组中到对象中，类似于以下内容：

my @filehandles = (); # Stores all the filehandles         ### CHANGED

my $stdout; # Store the index into @filehandles, NOT filehandle.
            # Should really be renamed "$stdout_id" instead.

sub stdout {
    my $self = shift;

    return $stdout if defined $stdout;

    $stdout = scalar(@filehandles);                         ### CHANGED
    my $stdout_fh = $self->dup_filehandle(\*STDOUT);        ### CHANGED
    push @filehandles, $stdout_fh;                          ### CHANGED

    $self->autoflush($stdout_fh);                           ### CHANGED
    $self->autoflush(\*STDOUT);

    return $stdout;
}

sub safe_print {
    my $self = shift;
    my $fh_id = shift;                                       ### CHANGED
    my $fh = $filehandles[$fh_id];                           ### CHANGED

    local( $\, $, ) = ( undef, '' );
    print $fh @_; 
}

我有一种强烈的感觉，您还需要以某种方式线程-确保 ID 列表的安全，因此可能需要一个共享索引计数器，而不是 $stdout = scalar(@filehandles);

Answer 2

作为我使用全局数组的其他答案的替代方案，这是 Perlmonks 的另一种方法：

http://perlmonks.org/?node_id=395513

它的工作原理是实际存储 fileno （文件描述符）文件句柄。以下是他的示例代码，基于 BrowserUk 发布的内容：

my $stdout; # Store the fileno, NOT filehandle.
            # Should really be renamed "$stdout_fileno" instead.

sub stdout {
    my $self = shift;

    return $stdout if defined $stdout;

    my $stdout_fh = $self->dup_filehandle(\*STDOUT);        ### CHANGED
    $stdout = fileno $stdout_fh;                            ### CHANGED

    $self->autoflush($stdout_fh);                           ### CHANGED
    $self->autoflush(\*STDOUT);

    return $stdout;
}

sub safe_print {
    my $self = shift;
    my $fh_id = shift;                                       ### CHANGED
    open(my $fh, ">>&=$fh_id")                                ### CHANGED
        || die "Error opening filehandle: $fh_id: $!\n";     ### CHANGED

    local( $\, $, ) = ( undef, '' );
    print $fh @_; 
}

注意 - 截至 2004 年，此代码存在一个错误，您无法从 >1 个线程的共享文件句柄中读取。我猜写作是可以的。有关如何在共享文件句柄上进行同步写入（来自同一 Monk）的更多具体信息：http://www.perlmonks.org/ ?node_id=807540

Answer 3

我突然想到有两种可能的解决方案：

1. 将文件句柄放在 Streamer 对象之外。
2. 将 Streamer 对象放在 Formatter 之外。

@DVK 的建议都是关于执行 1。

但是 2 在某些方面比 1 更简单。Formatter 可以保存 Streamer 对象的标识符，而不是保存 Streamer 对象本身。如果 Streamer 是由内向外实现的，那自然会发生！

不幸的是，引用地址在线程之间发生变化，即使是共享线程也是如此。这可以通过 Hash::Util::FieldHash 来解决，但这是5.10的事情，我必须支持5.8。可以使用 CLONE 将一些东西放在一起。

Answer 4

这就是我的结论...

package ThreadSafeFilehandle;

use Mouse;
use Mouse::Util::TypeConstraints;

my %Filehandle_Storage;    # unshared storage of filehandles
my $Storage_Counter = 1;   # a counter to use as a key

# This "type" exists to intercept incoming filehandles.
# The filehandle goes into %Filehandle_Storage and the
# object gets the key.
subtype 'FilehandleKey' =>
  as 'Int';
coerce 'FilehandleKey' =>
  from 'Defined',
  via {
      my $key = $Storage_Counter++;
      $Filehandle_Storage{$key} = $_;
      return $key;
  };

has thread_safe_fh =>
  is            => 'rw',
  isa           => 'FilehandleKey',
  coerce        => 1,
;

# This converts the stored key back into a filehandle upon getting.
around thread_safe_fh => sub {
    my $orig = shift;
    my $self = shift;

    if( @_ ) {                  # setting
        return $self->$orig(@_);
    }
    else {                      # getting
        my $key = $self->$orig;
        return $Filehandle_Storage{$key};
    }
};

1;

使用类型强制可以确保即使在对象构造函数中也会发生从文件句柄到键的转换。

它可以工作，但有缺陷：

每个对象都冗余地存储其文件句柄。如果一堆对象都存储相同的文件句柄，它们可能只存储一次。诀窍是如何识别相同的文件句柄。 fileno 或 refaddr 是选项。

删除对象时，文件句柄不会从 %Filehandle_Storage 中删除。我最初使用 DESTROY 方法来执行此操作，但由于对象克隆习惯用法是 $clone = shared_clone($obj) 一旦 $obj 消失，$clone 的文件句柄就会被丢弃的范围。

儿童发生的变化不会被分享。

对于我的目的来说，这些都是可以接受的，每个进程只会创建少数这些对象。

Answer 5

话又说回来，如果没有的话，可以使用 https://metacpan.org/module/Coro对它的巨魔过敏反应。