CoffeeScript 对象属性和闭包

Question

我有一个 MapHandler 类。

我创建了一个对象 myMaphandler = new MapHandler 并调用了初始化方法。 但是 @userLocationMarker.getPosition() 返回 null :(

如果我评论警报并从 Chrome JS 控制台调用 @userLocationMarker.getPosition() 我会获得必要的坐标。

class window.MapHandler

  initialize: (centerLocation) ->
    @makeMap(centerLocation)
    @defineUserLocation()
    alert @userLocationMarker.getPosition()


  makeMap: (centerLocation) ->
    myOptions =
      zoom: 14
      center: centerLocation
      mapTypeId: google.maps.MapTypeId.ROADMAP
    @map = new google.maps.Map(document.getElementById("map_canvas"), myOptions)


  placeMarker: (location, icon_path) ->
    if icon_path
      markerImage = new google.maps.MarkerImage(icon_path, null, null, null, new google.maps.Size(25, 25))
    else
      markerImage = null
    marker = new google.maps.Marker(
      position: location
      map: @map
      icon: markerImage)

  defineUserLocation: () ->
    @userLocationMarker = @placeMarker(null, null)

    handleMap = (position) =>
      pos = new google.maps.LatLng(position.coords.latitude, position.coords.longitude)
      infowindow = new google.maps.InfoWindow(
        map: @map
        position: pos
        content: 'Если это не ваше местоположение - передвиньте маркер'
      )
      @map.setCenter(pos)
      @userLocationMarker.setPosition(pos)

    if navigator.geolocation
      @userPosition = navigator.geolocation.getCurrentPositon(
        handleMap
      )

LINK

为什么会发生这种情况以及我应该采取什么措施来避免这种情况？

Answer 1

您使用 null 位置初始化 @userLocationMarker：

@userLocationMarker = @placeMarker(null, null)

然后在 handleMap 中设置“真实”位置：

handleMap = (position) =>
  #...
  @userLocationMarker.setPosition(pos)

该位置用作 handleMap 的回调code>getCurrentPosition：

if navigator.geolocation
  @userPosition = navigator.geolocation.getCurrentPosition(
    handleMap
  )

问题在于 getCurrentPosition 是异步的，因此您的 alert 在 handleMap 调用之前被调用获取当前位置。任何依赖于 getCurrentPosition 所做的事情都必须在 handleMap 回调中，否则它们需要准备好处理尚未到达的数据。

您的示例代码中也存在拼写错误，您在 if navigator.geolocation 块中拼写了 getCurrentPosition 错误。

当您尝试从 JavaScript 控制台检查位置时，getCurrentPosition 已调用 handleMap，并且 @userLocationMarker 将正确初始化其位置。