获取草稿的收件人（AppleScript、Mail.app）

Question

我想使用 AppleScript 获取 Mail.app 草稿文件夹中草稿的收件人（“收件人”字段等）。似乎找不到正确的语法。

谢谢。

Answer 1

实际上，与之前提出的 Cocoa 解决方案不同，纯 AppleScript 是可能的。以下是用于获取“TO”收件人字段的输入值的代码片段。

tell application "Mail"
    set draftMessages to every message in drafts mailbox
    set draftMessagesID to {}

    # go through each draft message
    repeat with draftMessage in draftMessages
         set draftMessageID to id of draftMessage as string
         copy draftMessageID to the end of draftMessagesID
    end repeat

    # go through the list of draft message ids and process the most recent item
    if (count of the draftMessagesID) is greater than 1 then
        set sortedDraftMessagesID to the reverse of my sortAlphabetically(the draftMessagesID)
        # get only the first item, as this is the most recent
        set lastDraftMessageID to first item of sortedDraftMessagesID as integer
        # get the most recent draft message
        set draftMessage to first message of drafts mailbox whose id is lastDraftMessageID

        set toAddresees to {}
        repeat with toRecipient in (get to recipients of draftMessage)
            set toName to name of toRecipient
            set toAddress to address of toRecipient
            set toFinal to my composeNameAndAddress(toName, toAddress)
            copy toFinal to end of toAddresees
        end repeat

        # now you have the input values of the TO field
        log toAddresees
    end if
end tell

#handler to compose name and address when one is missing
on composeNameAndAddress(name, address)
    if name is missing value then
        return address
    else
        return name & space & "<" & address & ">"
    end if
end composeNameAndAddress

#handler to sort a list alphabetically
on sortAlphabetically(theList)
    set the indexList to {}
    set the sortedList to {}
    repeat (the number of items in theList) times
        set the lowItem to ""
        repeat with i from 1 to (number of items in theList)
            if i is not in the indexList then
                set thisItem to item i of theList as string
                if the lowItem is "" then
                    set the lowItem to thisItem
                    set the lowItemIndex to i
                else if thisItem comes before the lowItem then
                    set the lowItem to thisItem
                    set the lowItemIndex to i
                end if
            end if
        end repeat
        set the end of sortedList to the lowItem
        set the end of the indexList to the lowItemIndex
    end repeat
    return the sortedList
end sortAlphabetically   

您提到您需要一个特定的草稿，对于此脚本，我假设您可以（例如）通过获取具有最高 ID 的草稿消息来获取最新草稿。这就是上面的脚本使用带有通用简单排序处理程序的反向命令所做的事情。

Answer 2

草稿邮箱包含在消息查看器中。由于邮件尚未发送，因此您无法获取其“收件人”。但是，您可以获取包含收件人列表的消息源。诀窍是从该文本中提取收件人。

tell application "Mail"
set the_messages to every message in drafts mailbox
repeat with this_message in the_messages
    set message_content to the source of this_message
    log message_content
end repeat
end tell

Answer 3

下面是在 Scripting Bridge (Cocoa) 中执行此操作的代码：

for (MailRecipient *recp in message.recipients) {
                MailToRecipient *theRecipient = [[[mail classForScriptingClass:@"to recipient"] alloc] initWithProperties:[NSDictionary dictionaryWithObjectsAndKeys:recp.address, @"address", nil]];
            }