在 Perl 中，如何打印哈希中最大值对应的键？

Question

如何仅打印哈希的第一个键和元素？

我已经有一个排序的哈希，但我只想打印第一个键和相应的值 谢谢，

感谢大家，最后我将键和值推送到两个不同的 @array 并打印每个数组的元素 0 并且它有效:)

Answer 1

哈希值具有无序的键。因此，哈希中不存在第一个键这样的键。

但是，如果您需要首先排序的键（以获得最大键值）：

my %hash = (
    'foo' => 'bar',
    'qux' => 'baz',
);

my ($key) = sort { $b cmp $a } keys %hash;
print "$key => $hash{$key}";  # Outputs: qux => baz

请记住使用 <=> 而不是 cmp 进行数字排序。

Answer 2

在 Perl 哈希中，键没有排序。使用 sort 函数按您想要的顺序获取键，或者您可以按键创建哈希时将其放入数组中，并且您的第一个键将位于数组中的第零个索引中

您可以使用下面的代码，我假设哈希名称是 my_hash，键和值是数字。如果您有字符串，则可以使用 cmp 而不是 <=>。更多详情请参阅排序文档

获取最大值键

foreach (sort {$b <=> $a} keys %my_hash) {
    print "Keys is $_\n";
    print "Value is $my_hash{$_}\n";
    last;
}

获取最大值对应的键

foreach (sort {$my_hash{$b} <=> $my_hash{$a}} keys %my_hash) {
    print "Keys is $_\n";
    print "Value is $my_hash{$_}\n";
    last;
}

Answer 3

foreach my $key (sort keys(%hash)) { 
   print "$key" .  "$hash{$key}" . "\n"; 
   last;
} 

Answer 4

对于大型哈希，如果您出于任何其他原因不需要排序的键，那么最好避免排序。

#!/usr/bin/env perl

use strict; use warnings;

my %hash = map { $_ => rand(10_000) } 'aa' .. 'zz';

my ($argmax, $max) = each %hash;
keys %hash; # reset iterator

while (my ($k, $v) = each %hash) {
    if ($v >= $max) {
        $max = $v;
        $argmax = $k;
    }
}

print "$argmax => $max\n";

如果您打算排序，则只需要具有最大值的键，而不是 keys 和 values 的整个数组：

#!/usr/bin/env perl

use strict; use warnings;

my %hash = map { $_ => rand(10_000) } 'aa' .. 'zz';
my ($argmax) = sort { $hash{$b} <=> $hash{$a} } keys %hash;

print "$argmax => $hash{$argmax}\n";

Answer 5

正如艾伦所写 - 散列没有特定的顺序，但您可以对散列键进行排序：

foreach my $key (sort keys(%hash)) {
   print $key . ': ' . $hash{$key} . "\n";
}

或者，如您所愿，从键数组中获取第一个元素：

my @keys = keys(%hash);
print $keys[0];