Spark SkinnableComponent 皮肤销毁策略

Question

作为尝试解决应用程序内存泄漏问题的一部分，我们发现对于每个 SkinnableComponent，skinDestructionPolicy 都设置为 “never”默认情况下。

这意味着当使用静态皮肤部件时，皮肤将永远保留在内存中。
此外，主机组件中对partRemoved()的重写永远不会被触发。 因此，我们在 partAdded() 重写中添加的事件侦听器不会被删除，这实际上会导致视图和皮肤保留在内存中。

当进行大量视图切换时，这是不可接受的。

以下是我们现在如何解决此问题的示例：

public class ViewA extends SkinnableComponent
{
    [SkinPart(required = "true")]
    public var labelA:Label;

    [SkinPart(required = "true")]
    public var buttonA:Button;

    public function ViewA()
    {
        super();
        mx_internal::skinDestructionPolicy = 'auto';
    }

    override protected function getCurrentSkinState():String
    {
        return super.getCurrentSkinState();
    }

    override protected function partAdded(partName:String, instance:Object):void
    {
        super.partAdded(partName, instance);

        trace("ViewA::partAdded " + partName);

        if (instance == buttonA)
        {
            buttonA.addEventListener(MouseEvent.CLICK, buttonClickedHandler);
        }
    }

    override protected function partRemoved(partName:String, instance:Object):void
    {


        trace("ViewA::partRemoved " + partName);

        if (instance == buttonA)
        {
            buttonA.removeEventListener(MouseEvent.CLICK, buttonClickedHandler);
        }

        super.partRemoved(partName, instance);
    }

    override public function stylesInitialized():void
    {
        setStyle("skinClass", ViewASkin);
    }
}

但是，使用 mx::internal 方法来规避此行为对我来说似乎相当奇怪。 有关这方面的文档也很少，因此任何想法都将受到欢迎。

干杯

Answer 1

根据我的经验，在 Flex SDK 中使用 mx::internal 命名空间通常意味着以下内容：“您可以使用此功能，如果您知道自己要做什么的话正在做的事情，而且我们（Adobe，或未来的 Apache 社区）也不保证这个 API 在 Flex 的未来版本中永远不会改变”。

因此，除非您非常关心向后兼容性，否则它的使用并没有真正的问题。如果您确实想避免使用它，您始终可以在子类中实现 skinDestructionPolicy="auto" 的行为。不需要编写太多代码：

    override public function initialize():void {
        addEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
        addEventListener(Event.REMOVED_FROM_STAGE, removedFromStageHandler);

        super.initialize();
    }

    private function addedToStageHandler(event:Event):void {
        if (skin == null) attachSkin();
    }

    private function removedFromStageHandler(event:Event):void {
        detachSkin();
    }

请注意，在 SkinnableComponent 类中，这两个事件侦听器在 commitProperties() 方法中附加（或不附加，具体取决于策略）。我将其移至 initialize() 方法，因为我们不再需要检查 skinDestructionPolicy 属性中的更改。

另请注意，如果同时将 mx::internal SkinDestructionPolicy 设置为 “auto”，则此解决方案可能会导致错误。