如何在 perl 中有效地搜索/替换文件中的某些字符串？

Question

我的文件如下所示：

<MAIN>  
  <SUB_MAIN>one</SUB_MAIN>  
  <VER>version#</VER>  
  (OTHER STUFF...)  
  <LOCATION>PATH</LOCATION>  
</MAIN>

<MAIN>  
  <SUB_MAIN>two</SUB_MAIN>  
  <VER>version#</VER>  
  (OTHER STUFF...)  
  <LOC>PATH</LOC>  
</MAIN>

我想要做的是搜索 SUB_MAIN 的值（假设有一个），如果找到它，则查找 LOCATION 的值。转到该位置进行一些同步，从那里获取新版本并更新 VER 信息。

我当前的代码有大约三个循环，而且很丑陋。骨架是这样的：

$value = "one|two|three";

# for each line in file
while ($line < @FileDat) {

    # see if it is a sub module?   
    if ( $line =~ /\<SUB_MAIN\>$value\<\/SUB_MAIN\>/ ) 
    {   
       $found_it = 0;

        while (!$found_it) 
        {       
            $lineNum++;     
            if ( $FileDat[$lineNum] =~ /\<VER\>\d+\<\/VER\>/ ) 
            {
                $currIndex = $lineNum;

                while(1)
                {
                   $lineNum++;
                   if ( $FileDat[$lineNum] =~ /\<LOC\>(.+)\<\/LOC\>/ ) 
                    {   #DO SOME STUFF...
                        $found_it = 1;
                        last;
                    }
                }               
                        #replace version #
                $FileDat[$currIndex] = "    <VER>$latestChangeList</VER>\n";
            }
        }
    }
    $lineNum++;
}

# write the modified array to new file
print NEWCFGFILEPTR @FileDat;

close(OPEN_FILES);

我怎样才能让它变得更好？
谢谢。

Answer 1

使用 XML::Simple。没有必要重新发明轮子，除非你打算让它变得更好，我非常怀疑这是你的任务。

Answer 2

实际上，使用 XML 解析器比仅使用 XML 模块要复杂一些，因为您拥有的不是格式良好的 XML。格式良好的 XML 文件将具有单个根，因此所有 MAIN 元素都将包装在单个元素中。

不过，有一种相对简单的方法可以伪造它，即将 XML 实体中引用的文件包装在适当的高级元素中。

另外，在您的示例数据中，第一个 MAIN 中有一个 LOCATION 元素，然后第二个 MAIN 中有一个 LOC 元素，我认为这是剪切粘贴错误。

这是使用 XML::Twig 执行此操作的一种方法，它可以处理任何大小的输入文件（包括大到适合内存），并且可以输出到标准输出。

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

binmode( STDOUT, ':utf8'); # if your input file is in UTF-8

my $file= shift @ARGV;
# wrap the content of the file in <data>...</data> so it becomes well-formed XML
my $xml= qq{<?xml version="1.0"?>
            <!DOCTYPE data [ <!ENTITY file SYSTEM "$file">]>
            <data>&file;</data>
           };

XML::Twig->new( twig_handlers => { MAIN => \&main },
                keep_spaces => 1,
              )
         ->parse( $xml);

exit;

sub main
  { my( $t, $main)= @_;
    my $location= $main->field( 'LOCATION');
    $main->set_field( VER => get_version( $location));
    $main->print;
    $main->purge; # if the file is big and you want to free the memory
  }

sub get_version
  { my( $location)= @_;
    return "new.version.$location"; # the real code might be different!
  }

如果您的输入文件不是 UTF-8，您可能需要更改包装器以将正确的编码添加到 XML 声明中。如果使用纯 ASCII，那么就很好（如果添加 UTF-8 字符，它仍然可以工作）。

如果您不想使用 XML::Twig，则可以使用相同的技术来创建可由 XML::Simple 或您想要使用的任何其他模块读取的正确 XML。

Answer 3

您有一个 XML 文件。不要使用正则表达式进行解析（这通常被认为是一个坏主意），而是尝试使用现有的 XML 解析模块之一，例如 XML::解析器。还有许多其他类似的模块，您可以通过 搜索 xml 找到它们在 search.cpan.org 上，但这是一个很好的。