如何从外部查看器调试器可视化工具获取对象或其数据的引用？

Question

我正在尝试为 TJSONObject 或 TJSONValue 编写调试器可视化工具。我的大部分可视化工具都运行良好。我遇到的问题是获取对 TJSONObject 的引用，或者至少是对 TJSONObject 的 tostring() 值的引用。

根据我见过的样本，以及 Jeremy North 在 http://edn 上发表的精彩帖子.embarcadero.com/article/40268，我应该从 IOTADebuggerVisualizerExternalViewer 实现的 Show 方法中获得我需要的内容。具体来说，来自 Expression、TypeName 和 EvalResult 字符串参数。

据我了解，Expression 是被检查（可视化）的变量的名称，TypeName 是变量的类名，EvalResult 是变量的默认字符串表示形式。

为了进行简单的测试，我在我的 TFrame 后代上放置了一个 TMemo。从 IOTADebuggerVisualizerExternalViewer.Show 方法中，我调用 TFrame 的 ShowJSONObject 方法，并向该方法传递 Expression、TypeName 和 EvalResult。相关代码显示在此处：

function TDebuggerJSONVisualizer.Show(const Expression, TypeName, EvalResult: string;
  SuggestedLeft, SuggestedTop: Integer): 
  IOTADebuggerVisualizerExternalViewerUpdater;
var
  AForm: TCustomForm;
  AFrame: TJSONViewerFrame;
  VisDockForm: INTACustomDockableForm;
begin
  VisDockForm := TJSONVisualizerForm.Create(Expression) as INTACustomDockableForm;
  AForm := (BorlandIDEServices as INTAServices).CreateDockableForm(VisDockForm);
  AForm.Left := SuggestedLeft;
  AForm.Top := SuggestedTop;
  (VisDockForm as IFrameFormHelper).SetForm(AForm);
  AFrame := (VisDockForm as IFrameFormHelper).GetFrame as TJSONViewerFrame;
  AFrame.ShowJSONObject(Expression, TypeName, EvalResult);
  Result := AFrame as IOTADebuggerVisualizerExternalViewerUpdater;
end;

{ TStringListViewerFrame }

procedure TJSONViewerFrame.ShowJSONObject(const Expression, TypeName,
  EvalResult: string);
begin
  Memo1.Lines.Add(Expression);
  Memo1.Lines.Add(TypeName);
  Memo1.Lines.Add(EvalResult);
end;

如您所见，我此时仅尝试从我的 ShowJSONObject 方法显示这三个参数的值。

这是我尝试使用可视化工具显示的一个简单的 TJSONObject：

var
 jo: TJSONObject;
begin
  jo := TJSONObject.Create;
  jo.AddPair('one', 'one');
  jo.AddPair('two', TJSONNumber.Create(1)); //a breakpoint here

结果如下所示：

I希望 EvalResult 能够返回 TJSONObject 的 tostring 表示形式，但它只返回无信息的 ()，这与您在局部变量窗口中默认看到的内容相同。

如何获取调用可视化工具的 TJSONObject 的 tostring 表示形式或实际对象的句柄，以便可以解构并显示其值？

Answer 1

您需要使用此过程来评估您的表达式（包括 ToString 调用）（刚刚从我自己的可视化工具源复制，因此它可以使用一些此处未声明的局部变量）：

function TJSONViewerFrame.Evaluate(Expression: string): string;
var
  CurProcess: IOTAProcess;
  CurThread: IOTAThread;
  ResultStr: array[0..4095] of Char;
  CanModify: Boolean;
  ResultAddr, ResultSize, ResultVal: LongWord;
  EvalRes: TOTAEvaluateResult;
  DebugSvcs: IOTADebuggerServices;
begin
  begin
    Result := '';
    if Supports(BorlandIDEServices, IOTADebuggerServices, DebugSvcs) then
      CurProcess := DebugSvcs.CurrentProcess;
    if CurProcess <> nil then
    begin
      CurThread := CurProcess.CurrentThread;
      if CurThread <> nil then
      begin
        EvalRes := CurThread.Evaluate(Expression, @ResultStr, Length(ResultStr),
          CanModify, eseAll, '', ResultAddr, ResultSize, ResultVal, '', 0);
        case EvalRes of
          erOK: Result := ResultStr;
          erDeferred:
            begin
              FCompleted := False;
              FDeferredResult := '';
              FDeferredError := False;
              FNotifierIndex := CurThread.AddNotifier(Self);
              while not FCompleted do
                DebugSvcs.ProcessDebugEvents;
              CurThread.RemoveNotifier(FNotifierIndex);
              FNotifierIndex := -1;
              if not FDeferredError then
              begin
                if FDeferredResult <> '' then
                  Result := FDeferredResult
                else
                  Result := ResultStr;
              end;
            end;
          erBusy:
            begin
              DebugSvcs.ProcessDebugEvents;
              Result := Evaluate(Expression);
            end;
        end;
      end;
    end;
  end;
end;

所以现在您可以将 Show 函数替换为如下所示：

AFrame.ShowJSONObject(Expression, TypeName, Evaluate(Expression + '.ToString'));