如何读入文本文件并将其打印到 Prolog 中的文件中？

Question

我有一个文本文件，我想读入它并在屏幕上打印它们并将它们写入新的输出文件。所以到目前为止我所做的是

main :-
    open('text.txt', read, ID),  % open a stream
    repeat,             % try again forever
    read(ID, X),        % read from the stream
    write(X), nl,       % write to current output stream
    X == end_of_file,   % fail (backtrack) if not end of 
    !,
    close(ID).

但我只收到一条错误消息，例如

ERROR: text.txt:1:0: Syntax error: Operator expected

我应该做什么？

Answer 1

read/2 读取有效的 Prolog 文本。该消息表明，在 text.txt 的第 1 行中，您有一些无效的 Prolog 文本。也许是几个用空格分隔的单词。

如果您想阅读常规文本，您可以使用 get_char/2 进行非常低级的操作，或者您可能想使用语法进行更高级别的操作。 SWI-Prolog 有用于此目的的library(pio)。

这是 Prolog 程序员相当于 grep -q 的命令。

?- phrase_from_file((...,"root",...),'/etc/passwd').
   true
;  true
;  true
;  false.

实际上，这更像是 grep -c。

您需要为其加载以下定义：

... --> [] | [_], ... .

Answer 2

如果您想要一个可重用的代码片段：

%%  file_atoms(File, Atom) is nondet.
%
%   read each line as atom on backtrack
%
file_atoms(File, Atom) :-
    open(File, read, Stream),
    repeat,
    read_line_to_codes(Stream, Codes),
    (   Codes \= end_of_file
    ->  atom_codes(Atom, Codes)
    ;   close(Stream), !, fail
    ).

这将调用 read_line_to_codes，一个 SWI-Prolog 内置函数。

Answer 3

is_eof(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        CharCode == -1,
        append(FileAkku, [CurrentLine], FileContent),
        close(FlHndl), !.

is_newline(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        CharCode == 10,
        append(FileAkku, [CurrentLine], NextFileAkku),
        read_loop(FlHndl, '', NextFileAkku, FileContent).

append_char(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        char_code(Char, CharCode),
        atom_concat(CurrentLine, Char, NextCurrentLine),
         read_loop(FlHndl, NextCurrentLine, FileAkku, FileContent).

read_file(FileName, FileContent) :-
        open(FileName, read, FlHndl),
        read_loop(FlHndl, '', [], FileContent), !.

read_loop(FlHndl, CurrentLine, FileAkku, FileContent) :-
        get_code(FlHndl, CharCode),
        ( is_eof(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)
        ; is_newline(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)
        ; append_char(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)).

main(InputFile, OutputFile) :-
    open(OutputFile, write, OS),
    (   read_file(InputFile,InputLines),
        member(Line, InputLines),
        write(Line), nl,
        write(OS,Line),nl(OS),
        false
        ;
        close(OS)
    ).

因此，您可以像 main('text.txt', 'output.txt') 一样使用它。