这是 Actionscript 3 中 MVC 的正确实现吗？

Question

该程序所做的就是您单击一个按钮，它会告诉您在文本字段中单击该按钮的次数。

文档类：这是代码的入口点。

package {
    import flash.display.MovieClip;

    /**
     * MVCTest.as
     * @author rotaercz
     */
    public class MVCTest extends MovieClip {
        private var _model:Model;
        private var _view:View;
        private var _control:Control;

        public function MVCTest() {
            _model = new Model();
            _view = new View(this);
            _control = new Control(_model, _view);
        }
    }
}

模型类：基本模型代码。

package {

    /**
     * Model.as
     * @author rotaercz
     */
    public class Model {
        private var _totalClicks:int;

        public function AddClick():void {
            _totalClicks++;
        }

        public function get Clicks():int {
            return _totalClicks;
        }

        public function Model() {
            _totalClicks = 0;
        }
    }
}

控制类：控制此处模型和视图的输入和更新。

package {
    import flash.events.MouseEvent;

    /**
     * Control.as
     * @author rotaercz
     */
    public class Control {
        private var _model:Model;
        private var _view:View;

        public function Control(model:Model, view:View):void {
            _model = model;
            _view = view;
            _view.addEventListener(MouseEvent.CLICK, OnClick);
        }

        private function OnClick(e:MouseEvent):void {
            _model.AddClick();
            _view.Text = "clicked " + _model.Clicks;
        }
    }
}

视图类：程序的可视化表示。

package {
    import flash.display.MovieClip;
    import flash.events.EventDispatcher;
    import flash.events.MouseEvent;
    import flash.text.TextField;

    /**
     * View.as
     * @author rotaercz
     */
    public class View extends EventDispatcher {
        private var _parent:MovieClip;
        private var _button:MovieClip;

        private var _dt:TextField;

        public function set Text(s:String):void {
            _dt.text = s;
        }

        public function View(parent:MovieClip) {
            _parent = parent;
            _dt = _parent.getChildByName("dt") as TextField;
            _button = _parent.getChildByName("mcButton") as MovieClip;
            _button.addEventListener(MouseEvent.CLICK, OnClick);
        }

        private function OnClick(e:MouseEvent):void {
            dispatchEvent(e);
        }
    }
}

Answer 1

在传统的 MVC 模式中，视图确实像 www0z0k 所写的那样直接依赖于模型，但我也认为这不是一个理想的解决方案。

他们设置控制器的方式是充当模型和视图之间的中介，这当然是一个非常有效的解决方案。

但是，如果您希望从模型到视图进行更直接的通信（这会节省一些代码），您可以创建一个中央事件调度程序，将其传递给模型并让它们使用中央事件调度程序来调度其更新事件，然后还传递中央事件调度程序到视图，让视图直接监听模型调度的事件。这样视图就不会直接依赖于模型，但它仍然可以侦听它们发送的事件。在这种情况下，控制器只会将视图事件转换为模型。

图表：
http://bit.ly/sTSDVT

控制器直接更新模型，但它也监听中央事件调度程序从模型获取更新（如果需要）并将其转换为视图。
它还侦听视图事件

该模型仅依赖于事件调度程序并使用它来调度更新事件。

视图仅依赖于事件调度程序并侦听来自模型的更新事件。它也调度自己的事件。 （您可以使用中央事件调度程序，但我不推荐它）

Answer 2

我相信我的 介绍Flex 应用程序的架构 - Redux 将会引起您的极大兴趣。

如需更华丽的方法，您可以查看FLit Framework。 MVCSprite 是与您的解决方案非常相似。

多年来使用了如此多的框架，我开始相信追求“正确”和“理想”的实现并不是很务实。设计模式并不正式——这些只是想法，应该始终根据您想要实现的质量属性进行调整。请记住，在一次迭代中真正确定该方法的情况非常罕见 - 有时需要完成许多项目才能找到更好的方法 - 以获得更深入的见解。

Answer 3

控制器监听视图并更新模型，这部分符合我对 MVC 的愿景。
但我试图避免让控制器参与将模型绑定到视图：

    _model = new Model();
    _view = new View(this, _model);
    _control = new Control(_model, _view);

在模型中：

public class Model extends EventDispatcher{
    //............
    public function AddClick():void {
        _totalClicks++;
        dispatchEvent(new Event('one more click'));
    }

在视图中：

    private var _model:Model;
    public function View(parent:MovieClip, model:Model) {
        _parent = parent;
        _model = model;
        _model.addEventListener('one more click', update);
        _dt = _parent.getChildByName("dt") as TextField;
        _button = _parent.getChildByName("mcButton") as MovieClip;
        _button.addEventListener(MouseEvent.CLICK, OnClick);
    }

    private function update(e:Event):void{
        _dt.text = _model.clicks;
    }