“%”是什么意思Fortran 语言中的意思是/做什么？

Question

我正在尝试阅读一些 Fortran 代码，但无法确定 % （百分号）的作用。

它是这样的：

   x = a%rho * g * (-g*a%sigma + m%gb * m%ca * (1.6 * a%rho+g))

它有什么作用？

Answer 1

在 Fortran 90 中，它们允许您创建类似于 C++ 中的结构。它基本上充当点 (.) 运算符。

来自http://www.lahey.com/lookat90.htm：

结构（派生类型）

您可以使用以下方式对数据进行分组：派生类型。这使用户能够将内部类型（包括数组和指针）组合成新类型，可以使用百分号作为分隔符来访问其各个组件。 （派生类型在 VAX Fortran 中称为记录。）
！使用派生类型和模块的示例。

module pipedef
   type pipe                          ! Define new type 'pipe', which
     real diameter                    ! is made up of two reals, an
     real flowrate                    ! integer, and a character.
     integer length
     character(len=10) :: flowtype
   end type pipe
end module pipedef

program main
   use pipedef                ! Associate module pipedef with main.
   type(pipe) water1, gas1    ! Declare two variables of type 'pipe'.
   water1 = pipe(4.5,44.8,1200,"turbulent") ! Assign value to water1.
   gas1%diameter = 14.9                     ! Assign value to parts
   gas1%flowrate = 91.284                   ! of gas1.
   gas1%length = 2550
   gas1%flowtype = 'laminar'
   .
   .
   .
end program

Answer 2

% 作为令牌有许多密切相关的用途。随着 Fortran 的发展，这些用途的数量不断增加。

回到 Fortran 90，以及问题中看到的用法，% 用于访问派生类型的组件。考虑派生类型 a_t 以及该类型的对象 a：

type a_t
  real rho, sigma
end type
type(a_t) a

a 的组件 rho 和 sigma可以使用a%rho 和a%sigma 访问。从问题中可以看出，这些组件可以在表达式中使用（例如 a%rho * g），也可以是赋值的左侧（a%rho =1.）。

派生类型的组件本身可能是派生类型的对象：

type b_t
  type(a_t) a
end type
type(b_t) b

因此在单个引用中可能会多次出现 %：

b%a%rho = ...

这里，派生类型的组件 rho派生类型对象 a 本身是 b 的组件，是赋值的目标。人们可以在一个引用中看到相当可怕的 % 数量，但零件引用始终是从左到右解析的。

来到 Fortran 2003，人们就会看到 % 通过其他几种方式与派生类型相关：

• 引用对象的绑定；
• 查询参数化类型的参数。

考虑派生类型

type a_t(n)
  integer, len :: n=1
  real x(n)
 contains
  procedure f
end type
type(a_t(2)) a

对象a 有一个长度类型参数和一个类型绑定过程。在像绑定f这样的表达式中

x = a%f()

，派生类型对象被引用。

可以引用a的参数n，就像

print *, a%n, SIZE(a%x)

可以引用组件x一样多。

最后，从 Fortran 2008 开始，% 可用于访问复杂对象的实部和虚部：

complex x, y(3)
x%im = 1.
x%re = 0.
y = (2., 1.)
print *, y(2)%im+y(3)%re

Answer 3

它是派生类型的部分标识符。看看这个。 http://www.lahey.com/lookat90.htm