返回序列中的重复项

Question

我能想到的最好的办法是：

(defn dups [seq]
  (map (fn [[id freq]] id) 
       (filter (fn [[id freq]] (> freq 1))
               (frequencies seq))))

有更简洁的方法吗？

Answer 1

使用列表理解：

(defn dups [seq]
  (for [[id freq] (frequencies seq)  ;; get the frequencies, destructure
        :when (> freq 1)]            ;; this is the filter condition
   id))                              ;; just need the id, not the frequency

Answer 2

(map key (remove (comp #{1} val) 
                 (frequencies seq)))

Answer 3

如果您想根据列表中项目的某些属性查找重复项（即，它是映射列表或记录/java 对象列表）

(defn dups-with-function
  [seq f]
  (->> seq
       (group-by f)
       ; filter out map entries where its value has only 1 item 
       (remove #(= 1 (count (val %))))))

(let [seq [{:attribute    :one
            :other-things :bob}
           {:attribute    :one
            :other-things :smith}
           {:attribute    :two
            :other-things :blah}]]
  (dups-with-function seq :attribute))

输出：

 ([:one
   [{:attribute :one, :other-things :bob}
    {:attribute :one, :other-things :smith}]])

如果您有一个 java 对象列表并且想要查找所有名字重复的人：

(dups-with-function my-list #(.getFirstName %))

Answer 4

最小过滤器和频率 oneliner 可以完成这项工作：

(filter #(< 1 ((frequencies col) %)) col)

但是它在大数据上表现不佳。您必须通过说以下内容来帮助编译器：

(let [ freqs (frequencies col) ]
  (filter #(< 1 (freqs %)) col))

Answer 5

some 是完美的函数。

(defn dups [coll]
  (some (fn [[k v]] (when (< 1 v) k))
    (frequencies coll)))

但是，它基本上与列表理解相同。