使用 XSL 样式表将 GPX 导入 Filemaker Pro

Question

我了解 GPSbabel，并使用它将 GPX 文件转换为 CSV，然后将其导入 Filemaker Pro 进行操作。但是，我希望能够更简单地导入 GPX 文件整齐地转换为 FMP，并希望我可以编写一个 XSL 样式表，将 XML 的 GPX 形式转换为 FMPXMLRESULT 语法。

我正在查看来自 Garmin Foretrex、Dakota、Nuvi 和 的 GPX 文件。 GPSmap296 设备。我对 XSL 样式表的最新尝试（使用从各种示例抄袭的片段）如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes" method="xml"/>
    <xsl:template match="trkseg">
        <FMPXMLRESULT xmlns="http://www.filemaker.com/fmpxmlresult">
            <ERRORCODE>0</ERRORCODE>
            <PRODUCT BUILD="01-25-2011" NAME="FileMaker" VERSION="ProAdvanced 11.0v3"/>
            <DATABASE DATEFORMAT="Yyyy-m-d" LAYOUT="" NAME="gpx_import_test.fp7" RECORDS="{@count}"
                TIMEFORMAT="k:mm:ss "/>
            <METADATA>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="ele" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="lat" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="lon" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="time_text" TYPE="TEXT"/>
            </METADATA>
            <RESULTSET FOUND="@count">
                <xsl:for-each select="trkpt">
                    <ROW MODID="0" RECORDID="{position()}">
                        <COL>
                            <DATA>
                                <xsl:value-of select="lat"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="lon"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="ele"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="time_text"/>
                            </DATA>
                        </COL>
                    </ROW>
                </xsl:for-each>
            </RESULTSET>
        </FMPXMLRESULT>
    </xsl:template>
</xsl:stylesheet>

当我尝试使用上述样式表时，FMP 抱怨“XML 解析错误：无效的文档结构”。

我欢迎任何建议 - 我想我犯了一些非常简单和明显的错误。

此致

Rowland

这是我尝试导入的 Garmin Dakota 20 中典型 GPX 文件的截取版本。

<?xml version="1.0" encoding="UTF-8" standalone="no" ?>
<gpx xmlns="http://www.topografix.com/GPX/1/1"
xmlns:gpxx="http://www.garmin.com/xmlschemas/GpxExtensions/v3"
xmlns:wptx1="http://www.garmin.com/xmlschemas/WaypointExtension/v1"
xmlns:gpxtpx="http://www.garmin.com/xmlschemas/TrackPointExtension/v1"
creator="Dakota 20" version="1.1"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:schemaLocation="http://www.topografix.com/GPX/1/1
http://www.topografix.com/GPX/1/1/gpx.xsd
http://www.garmin.com/xmlschemas/GpxExtensions/v3
http://www8.garmin.com/xmlschemas/GpxExtensionsv3.xsd
http://www.garmin.com/xmlschemas/WaypointExtension/v1
http://www8.garmin.com/xmlschemas/WaypointExtensionv1.xsd
http://www.garmin.com/xmlschemas/TrackPointExtension/v1
http://www.garmin.com/xmlschemas/TrackPointExtensionv1.xsd">
<metadata>
<link href="http://www.garmin.com">
<text>Garmin International</text>
</link>
<time>2011-10-21T16:55:50Z</time>
</metadata>
<trk>
<name>Current Track: 20 OCT 2011 10:31</name>
<extensions>
<gpxx:TrackExtension>
<gpxx:DisplayColor>Black</gpxx:DisplayColor>
</gpxx:TrackExtension>
</extensions>
<trkseg>
<trkpt lat="51.6084605176" lon="-2.2182025295">
<ele>43.40</ele>
<time>2011-10-20T09:31:44Z</time>
</trkpt>
<trkpt lat="51.6084605176" lon="-2.2182025295">
<ele>47.24</ele>
<time>2011-10-20T09:31:53Z</time>

</trkpt>
</trkseg>
</trk>
</gpx>

Answer 1

这里有几个问题。其中之一是：

<xsl:template match="trkseg">

您不是从根开始，因此 XSLT 处理器将使用默认规则（即输出元素的值）处理根和所有其他元素。这可能会在 FMPXMLRESULT 周围添加额外的文本。要修复它，我们需要执行以下操作：

<xsl:template match="/">
  <xsl:for-each select="//trkseg/trkpt"> <!-- or use a full path -->
    ...
  </xsl:for-each>

这还不够，因为 trkseg 不仅仅是 trkseg，它还是 GPX 命名空间中的 trkseg。如果没有正确的名称空间声明，样式表根本找不到元素。最后一个问题是 lat 和 lon 是属性，您需要将它们称为 @lat 和 @lon代码>.这是有效的 XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:gpx="http://www.topografix.com/GPX/1/1"
    exclude-result-prefixes="gpx">
    <xsl:output indent="yes" method="xml"/>
    <xsl:template match="/">
        <FMPXMLRESULT xmlns="http://www.filemaker.com/fmpxmlresult">
            <ERRORCODE>0</ERRORCODE>
            <PRODUCT BUILD="01-25-2011" NAME="FileMaker" VERSION="ProAdvanced 11.0v3"/>
            <DATABASE DATEFORMAT="Yyyy-m-d" 
                LAYOUT=""  NAME="gpx_import_test.fp7" RECORDS="{@count}"
                TIMEFORMAT="k:mm:ss "/>
            <METADATA>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="ele" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="lat" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="lon" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="time" TYPE="TEXT"/>
            </METADATA>
            <RESULTSET FOUND="count(//gpx:trkseg/gpx:trkpt)">
                <xsl:for-each select="//gpx:trkseg/gpx:trkpt">
                    <ROW MODID="0" RECORDID="{position()}">
                        <COL>
                            <DATA>
                                <xsl:value-of select="@lat"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="@lon"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="gpx:ele"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="gpx:time"/>
                            </DATA>
                        </COL>
                    </ROW>
                </xsl:for-each>
            </RESULTSET>
        </FMPXMLRESULT>
    </xsl:template>
</xsl:stylesheet>

Answer 2

这是一个 xslt 文件，用于仅读取航路点，而不读取航迹：
方式：我将时间、名称、符号和类型字段添加到导入中。如果
不需要，删除该文件中相应的行。

将虚线下方的文本复制并存储在名为的文件中
“yourchoice.xslt”，其中“yourchoice”可以是您想要的任何名称，
在 filemaker 中将其用作 xslt 转换文件。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:gpx="http://www.topografix.com/GPX/1/1"
    exclude-result-prefixes="gpx">
    <xsl:output indent="yes" method="xml"/>
    <xsl:template match="/">
        <FMPXMLRESULT xmlns="http://www.filemaker.com/fmpxmlresult">
            <ERRORCODE>0</ERRORCODE>
            <PRODUCT BUILD="01-25-2011" NAME="FileMaker" VERSION="ProAdvanced 11.0v3"/>
            <DATABASE DATEFORMAT="Yyyy-m-d" 
                LAYOUT=""  NAME="gpx_import_test.fp7" RECORDS="{@count}"
                TIMEFORMAT="k:mm:ss "/>
            <METADATA>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="latitude" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="longitude" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="elevation" TYPE="NUMBER"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="time" TYPE="TEXT"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="name" TYPE="TEXT"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="sym" TYPE="TEXT"/>
                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="type" TYPE="TEXT"/>
            </METADATA>
            <RESULTSET FOUND="count(gpx:wpt)">
                <xsl:for-each select="gpx:wpt">
                    <ROW MODID="0" RECORDID="{position()}">
                        <COL>
                            <DATA>
                                <xsl:value-of select="@lat"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="@lon"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="gpx:ele"/>
                            </DATA>
                        </COL>
                        <COL>
                            <DATA>
                                <xsl:value-of select="gpx:time"/>
                            </DATA>
                        </COL>
                          <COL>
                            <DATA>
                                <xsl:value-of select="gpx:name"/>
                            </DATA>
                        </COL>
                          <COL>
                            <DATA>
                                <xsl:value-of select="gpx:sym"/>
                            </DATA>
                        </COL>
                          <COL>
                            <DATA>
                                <xsl:value-of select="gpx:type"/>
                            </DATA>
                        </COL>
                    </ROW>
                </xsl:for-each>
            </RESULTSET>
        </FMPXMLRESULT>
    </xsl:template>
</xsl:stylesheet>