TStringList 备份从旧版本到最新版本的兼容性

Question

我有一个使用 TStringList 的备份系统，但我使用旧的 Delphi（Ansi 字符串）进行编码。

基本上我在保存时有这个：

...
MyStringList.SaveToStream(Str);
StrSz := Str.Size;
MyBackupStream.Write(StrSz, SizeOf(Integer));
MyBackupStream.Write(Str.Memory^, StrSz);
...

当我重新加载时：

...
MyBackupStream.Read(StrSz, SizeOf(Integer));
Str.SetSize(StrSz);
MyBackupStream.Read(Str.Memory^, StrSz);
MyStringList.SetText := PChar( Str.Memory);
...

我使用这个顺序（大小+数据大小字节，然后大小+数据大小字节等）系统进行各种组件备份。事实上，在字符串列表备份之前，总是会“读取”或“写入”一些内容（我的意思是在字符串列表备份之前和之后都有一些数据）。

我在这里引入一个大问题吗（如果我切换到现代 Delphi 版本）？ 该块在未来的 delphi 版本中是否仍然可以转换（如果我切换？）。我需要在备份标头中写入字符串版本吗？

不幸的是我无法对此进行测试。我认为，如果我至少在标头中写入字符串编码类型，我以后就能够以正确的方式对其进行转换，无论 Delphi 版本是什么，不是吗？

Answer 1

使用 MyStringList.LoadFromStream(Str) 而不是 MyStringList.Text := PChar( Str.Memory)。

首先，您的 TStream 数据不是以 null 终止的，但是按照您的方式使用 PChar 需要一个 null 终止符（您可以使用 SetString()使用字符串变量来解决这个问题）。

其次，从 D2009 开始，String 现在是 UnicodeString 而不是 AnsiString，PChar 现在是 PWideChar< /code> 而不是 PAnsiChar。您的 TStream 数据是 Ansi 而不是 Unicode（即使在 D2009+ 中也是如此，因为 SaveToStream() 默认使用 TEncoding.Default（即 Ansi）进行编码流数据），因此将数据转换为 PWideChar 会将垃圾分配给您的 TStringList。

在所有版本中，您应该使用 LoadFromStream()，但如果您想坚持设置 Text 属性，那么您需要这样做，这适用于所有版本版本：

var
  ...
  S: AnsiString;
begin
  ...
  MyBackupStream.ReadBuffer(StrSz, SizeOf(Integer));
  Str.SetSize(StrSz);
  if StrSz > 0 then MyBackupStream.ReadBuffer(Str.Memory^, StrSz);
  SetString(S, PAnsiChar(Str.Memory), StrSz);
  MyStringList.Text := String(S);
  ...
end;

或这样：

var
  ...
  S: AnsiString;
begin
  ...
  MyBackupStream.ReadBuffer(StrSz, SizeOf(Integer));
  if StrSz > 0 then begin
    SetLength(S, StrSz);
    MyBackupStream.ReadBuffer(S[1], StrSz);
  end;
  MyStringList.Text := String(S);
  ...
end;

或这样：

var
  ...
  Str: TStringStream;
begin
  ...
  Str := TStringStream.Create;
  try
    MyBackupStream.ReadBuffer(StrSz, SizeOf(Integer));
    if StrSz > 0 then Str.CopyFrom(MyBackupStream, StrSz);
    MyStringList.Text := Str.DataString;
  finally
    Str.Free;
  end;
  ...
end;

最后，您应该考虑将流数据更改为使用 UTF-8 而不是 Ansi，以获得更好的未来兼容性。在 D2009+ 中，SaveToStream() 和 LoadFromStream() 都有一个可选的 TEncoding 参数，UTF-8 是无损 Unicode 编码，而 Ansi 可以丢失Ansi/Unicode 转换期间的数据。如果您现有的数据是 ASCII（#127 以上没有 AnsiChar 字符），则 UTF-8 与 ASCII 100% 向后兼容。但是，如果数据是 Ansi （在 #127 之上有 AnsiChar 字符），那么您最好以某种方式更改流格式（添加标头/版本等），以便您可以区分旧版本和较新的格式，然后您可以使用 Ansi 加载较旧的格式，并使用 Unicode/UTF-8 保存/加载较新的格式。

Answer 2

我认为你走在正确的道路上。我记得，几年前，我完成了和你类似的任务。我为每个数据块设置了两个部分：标题和内容。标头包含块的起始地址和长度等信息。内容部分包含实际数据。这种方法从来没有出现过任何问题。在您的情况下，标头仅包含块的大小。至于字符串的版本号，我建议你这样做，因为根据Delphi的发布路线，新版本不向后兼容旧版本的情况是很常见的。即使以后不必使用版本号，也没有什么坏处。