将 Mathematica 值列表转换为布尔列表

Question

首先，对混乱的标题表示歉意。

我想要做的是将 {1, 4, 9} 转换为：

{True, False, False, True, False, False, False, False, True}

也就是说，只有第一个列表中的索引才会具有值 True，其余的将为错误。

我感觉有一些非常简单的解决方案，但我对 Mathematica 和函数式编程都很陌生。我可以在循环中迭代地执行此操作，但必须有一些东西可以与整个列表一起使用。正确的？ ：）

感谢您的帮助。

---

编辑：为了表明我在提出要求之前尝试做某事，这是迄今为止我的进展：

first={1,4,9}
ReplacePart[Table[False, {x, Max[first]}], {1} -> True]
(* gives {True, False, False, False, False, False, False, False, False} *)

不幸的是，它不适用于 {1,4,9} ->  True，但可以与 {1 ->;正确，4 ->确实，9 ->正确}。但我不知道如何做到这一点...

---

编辑2：明白了。

ReplacePart[Table[False, {x, Max[first]}], Table[x -> True, {x, first}]]

我仍然很想看到您的解决方案！这对我来说似乎是一个丑陋的黑客......:)

Answer 1

这是一个简单的方法：

first = {1, 4, 9};
list = ConstantArray[False, Max@first];
list[[first]] = True;

list
Out[1]= {True, False, False, True, False, False, False, False, True}

---

这是将上述解决方案编写为一个方便的函数：

Clear[convertIndices]
convertIndices[index_List] := 
 Module[{list = ConstantArray[False, Max@index]}, 
  list[[index]] = True; list]

用法：

convertIndices@{1, 4, 9}
Out[2]= {True, False, False, True, False, False, False, False, True}

Answer 2

我将使用 SparseArray 来执行此操作。在我看来，它非常容易理解，而且也很高效，特别是当索引为 True 的比例较低时。

true = {1, 4, 9};
SparseArray[(List /@ true) -> True, Automatic, False]

或者使用 Transpose（粘贴到 Mathematica 中时看起来更好）：

SparseArray[{true}\[Transpose] -> True, Automatic, False]

如果必须将输出转换为普通数组，则可以使用 Normal，但是大多数操作不需要这样做。

---

另外，为了简洁而牺牲实用性：

#==1 & /@ SparseArray[List /@ true -> 1]

Answer 3

实际上，我自己会使用 Yoda 的答案，但这里有一种替代方法：

first = {1, 4, 9};
MemberQ[first, #] & /@ Range[Max[first]]

(* ===> {True, False, False, True, False, False, False, False, True}*)

或者这个：

Or @@@ Outer[Equal, Range[Max[first]], first]


(* ===> {True, False, False, True, False, False, False, False, True}*)

两者都有跳过 Yoda 的 ConstantArray 初始化步骤的优点。