YAML::Tiny 不支持 JSON::XS::Boolean

Question

当读取一些 JSON 数据结构，然后尝试使用 YAML::Tiny 来转储它们时，我有时会收到错误

YAML::Tiny does not support JSON::XS::Boolean

，我理解为什么会出现这种情况（特别是 >YAML::Tiny 不支持布尔值，而 JSON 热衷于与其他标量明确区分开来），但是有没有快速的技巧可以将这些 JSON::XS: :Boolean 对象转换为普通对象0 和 1 只是为了快速转储到屏幕？

Answer 1

YAML::Tiny 不支持对象。不幸的是，它甚至没有一个选项来仅对所有对象进行字符串化，从而处理 JSON::XS::Boolean。

不过，您可以使用递归函数相当轻松地做到这一点：

use strict;
use warnings;
use 5.010; # for say

use JSON::XS qw(decode_json);
use Scalar::Util qw(blessed reftype);
use YAML::Tiny qw(Dump);

my $hash = decode_json('{ "foo": { "bar": true }, "baz": false }');

# Stringify all objects in $hash:
sub stringify_objects {
  for my $val (@_) {
    next unless my $ref = reftype $val;
    if (blessed $val) { $val = "$val" }
    elsif ($ref eq 'ARRAY') { stringify_objects(@$val) }
    elsif ($ref eq 'HASH')  { stringify_objects(values %$val) }
  }
}

stringify_objects($hash);

say Dump $hash;

该函数不会费心处理标量引用，因为 JSON 不会生成它们。它也不检查对象是否确实具有重载的字符串化。

Data::Rmap 对此效果不佳，因为它只会访问特定对象一次，无论它出现多少次。由于 JSON::XS::Boolean 对象是单例，这意味着它只会找到第一个 true 和第一个 false。可以解决这个问题，但需要深入研究源代码来确定如何在其 seen 哈希中生成密钥：

use Data::Rmap qw(rmap_ref);
use Scalar::Util qw(blessed refaddr);

# Stringify all objects in $hash:
rmap_ref { if (blessed $_) { delete $_[0]->seen->{refaddr $_};
                             $_ = "$_" } } $hash;

我认为递归函数更清晰，并且不易受到 中的更改的影响>数据::Rmap。