Excel 2010：如何在验证列表中使用自动完成功能

Question

我正在使用一个大型验证列表，其中有几个 vlookup() 函数所依赖。这个名单变得越来越大。有没有办法输入我要查找的列表项的第一个字母，而不是手动向下滚动列表搜索该项目？

我做了一些谷歌搜索，但这表明这在早期版本的 Excel 中确实可行，但在 Excel 2010 中不行。希望你们能提供帮助。

Answer 1

这是处理此问题的一个非常好的方法（可在 ozgrid 上找到）：

让我们假设您的列表位于 Sheet2 上，并且您希望在 Sheet1 上使用具有自动完成功能的验证列表。

在 Sheet1 A1 上输入 =Sheet2!A1 并向下复制，包括所需数量的备用行（假设总共 300 行）。隐藏这些行并在引用中使用此公式：对于名为 MyList 的动态命名范围：

=OFFSET(Sheet1!$A$1,0,0,MATCH("*",Sheet1!$A$1:$A$300,-1),1)

现在在最后一个隐藏行正下方的单元格中使用数据验证，对于列表源使用 =MyList

[编辑] Excel 2007+ 的改编版本（虽然无法在 2010 上进行测试，但据我所知，没有任何特定于版本的内容）。
假设您的数据源位于 Sheet2!A1:A300 上，并假设您的验证列表（又名自动完成）位于单元格 Sheet1!A1 上。

1. 创建一个动态命名范围MyList，该范围取决于您放置验证的单元格的值

   =OFFSET(Sheet2!$A$1,MATCH(Sheet1!$A$1&"*",Sheet2!$A$1:$A$300,0)-1,0,COUNTA(Sheet2!$ A:$A))

2. 在引用列表的单元格 Sheet1!A1 上添加验证列表 =MyList

注意事项

1. 这不是一个真实自动完成，因为您必须先输入，然后单击验证箭头：列表将在列表的第一个匹配元素处开始

2. 列表将一直到数据末尾。如果您想更精确（仅在列表中保留匹配元素），您可以使用将计算的SUMLPRODUCT更改COUNTA匹配元素的数量

3. 您的源列表必须已排序

Answer 2

这是另一种选择。它的工作原理是将 ActiveX 组合框放在单元格顶部并启用验证，然后在组合框中提供自动完成功能。

Option Explicit

' Autocomplete - replacing validation lists with ActiveX ComboBox
'
' Usage:
'   1. Copy this code into a module named m_autocomplete
'   2. Go to Tools / References and make sure "Microsoft Forms 2.0 Object Library" is checked
'   3. Copy and paste the following code to the worksheet where you want autocomplete
'      ------------------------------------------------------------------------------------------------------
'      - autocomplete
'      Private Sub Worksheet_SelectionChange(ByVal Target As Range)
'          m_autocomplete.SelectionChangeHandler Target
'      End Sub
'      Private Sub AutoComplete_Combo_KeyDown(ByVal KeyCode As msforms.ReturnInteger, ByVal Shift As Integer)
'          m_autocomplete.KeyDownHandler KeyCode, Shift
'      End Sub
'      Private Sub AutoComplete_Combo_Click()
'          m_autocomplete.AutoComplete_Combo_Click
'      End Sub
'      ------------------------------------------------------------------------------------------------------

' When the combobox is clicked, it should dropdown (expand)
Public Sub AutoComplete_Combo_Click()
    Dim ws As Worksheet: Set ws = ActiveSheet
    Dim cbo As OLEObject: Set cbo = GetComboBoxObject(ws)
    Dim cb As ComboBox: Set cb = cbo.Object
    If cbo.Visible Then cb.DropDown
End Sub

' Make it easier to navigate between cells
Public Sub KeyDownHandler(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    Const UP As Integer = -1
    Const DOWN As Integer = 1

    Const K_TAB_______ As Integer = 9
    Const K_ENTER_____ As Integer = 13
    Const K_ARROW_UP__ As Integer = 38
    Const K_ARROW_DOWN As Integer = 40

    Dim direction As Integer: direction = 0

    If Shift = 0 And KeyCode = K_TAB_______ Then direction = DOWN
    If Shift = 0 And KeyCode = K_ENTER_____ Then direction = DOWN
    If Shift = 1 And KeyCode = K_TAB_______ Then direction = UP
    If Shift = 1 And KeyCode = K_ENTER_____ Then direction = UP
    If Shift = 1 And KeyCode = K_ARROW_UP__ Then direction = UP
    If Shift = 1 And KeyCode = K_ARROW_DOWN Then direction = DOWN

    If direction <> 0 Then ActiveCell.Offset(direction, 0).Activate

    AutoComplete_Combo_Click
End Sub

Public Sub SelectionChangeHandler(ByVal Target As Range)
    On Error GoTo errHandler

    Dim ws As Worksheet: Set ws = ActiveSheet
    Dim cbo As OLEObject: Set cbo = GetComboBoxObject(ws)
    Dim cb As ComboBox: Set cb = cbo.Object

    ' Try to hide the ComboBox. This might be buggy...
    If cbo.Visible Then
        cbo.Left = 10
        cbo.Top = 10
        cbo.ListFillRange = ""
        cbo.LinkedCell = ""
        cbo.Visible = False
        Application.ScreenUpdating = True
        ActiveSheet.Calculate
        ActiveWindow.SmallScroll
        Application.WindowState = Application.WindowState
        DoEvents
    End If

    If Not HasValidationList(Target) Then GoTo ex

    Application.EnableEvents = False

    ' TODO: the code below is a little fragile
    Dim lfr As String
    lfr = Mid(Target.Validation.Formula1, 2)
    lfr = Replace(lfr, "INDIREKTE", "") ' norwegian
    lfr = Replace(lfr, "INDIRECT", "") ' english
    lfr = Replace(lfr, """", "")
    lfr = Application.Range(lfr).Address(External:=True)

    cbo.ListFillRange = lfr
    cbo.Visible = True
    cbo.Left = Target.Left
    cbo.Top = Target.Top
    cbo.Height = Target.Height + 5
    cbo.Width = Target.Width + 15
    cbo.LinkedCell = Target.Address(External:=True)
    cbo.Activate
    cb.SelStart = 0
    cb.SelLength = cb.TextLength
    cb.DropDown

    GoTo ex

errHandler:
    Debug.Print "Error"
    Debug.Print Err.Number
    Debug.Print Err.Description
ex:
    Application.EnableEvents = True
End Sub

' Does the cell have a validation list?
Function HasValidationList(Cell As Range) As Boolean
    HasValidationList = False
    On Error GoTo ex
    If Cell.Validation.Type = xlValidateList Then HasValidationList = True
ex:
End Function

' Retrieve or create the ComboBox
Function GetComboBoxObject(ws As Worksheet) As OLEObject
    Dim cbo As OLEObject
    On Error Resume Next
    Set cbo = ws.OLEObjects("AutoComplete_Combo")
    On Error GoTo 0
    If cbo Is Nothing Then
        'Dim EnableSelection As Integer: EnableSelection = ws.EnableSelection
        Dim ProtectContents As Boolean: ProtectContents = ws.ProtectContents

        Debug.Print "Lager AutoComplete_Combo"
        If ProtectContents Then ws.Unprotect
        Set cbo = ws.OLEObjects.Add(ClassType:="Forms.ComboBox.1", Link:=False, DisplayAsIcon:=False, _
                            Left:=50, Top:=18.75, Width:=129, Height:=18.75)
        cbo.name = "AutoComplete_Combo"
        cbo.Object.MatchRequired = True
        cbo.Object.ListRows = 12
        If ProtectContents Then ws.Protect
    End If
    Set GetComboBoxObject = cbo
End Function

Answer 3

基于 JMax 的答案，将此公式用于动态命名范围以使解决方案适用于多行：

=OFFSET(Sheet2!$A$1,MATCH(INDIRECT("Sheet1!"&ADDRESS(ROW(),COLUMN(),4))&"*",Sheet2!$A$1:$A$300,0)-1,0,COUNTA(Sheet2!$A:$A))

Answer 4

只要有垂直列的项目，Excel 就会自动执行此操作。如果您选择列下方（或上方）的空白单元格并开始输入，它会根据列中的所有内容自动完成。

Answer 5

正如其他人所建议的，您需要使用组合框。然而，大多数教程只向您展示如何设置一个组合框，并且该过程相当乏味。

由于我之前在从列表中输入大量数据时遇到过这个问题，我建议您使用 这个自动完成加载项。它可以帮助您在选择的任何单元格上创建组合框，并且您可以定义要显示在下拉列表中的列表。

Answer 6

=OFFSET(NameList!$A$2:$A$200,MATCH(INDIRECT("FillData!"&ADDRESS(ROW(),COLUMN(),4))&"*",NameList!$A$2:$A$200,0)-1,0,COUNTIF($A$2:$A$200,INDIRECT("FillData!"&ADDRESS(ROW(),COLUMN(),4))&"*"),1)

1. 将工作表名称创建为Namelist。在 A 列中填写数据列表。

2. 创建另一个工作表名称为 FillData，用于根据需要制作数据验证列表。

3. 输入第一个字母并选择，将根据您的输入显示下拉菜单。