如何打印 SAS 数据集的最后一次观察结果？

Question

我有一个包含 1000 个观察值的数据集。我只想打印最后的观察结果。使用以下内容：

proc print data=apple(firstobs = 1000 obs = 1000); 
run;

我可以获得最后的观察结果。但我必须提前知道我的数据集有 1000 个观察值。在不知道这一点的情况下我该如何做到这一点？

Answer 1

有很多方法可以做到这一点。这里有两个：

proc sql noprint;
 select n(var1) into :nobs
 from apple;
quit;

proc print data=apple(firstobs=&nobs); run;

这只是将观察数量读取到宏变量中，然后使用它来指定第一个观察。 （请注意，var1 引用数据中的变量。）

另一种方法是创建一个仅保留最后观察结果的数据视图，然后打印该结果：

data tmp / view=tmp;
 set apple nobs=nobs;
 if _n_=nobs;
run;

proc print data=tmp; run;

Answer 2

我认为 SET、MERGE、MODIFY 或 UPDATE 的 end 选项> 声明非常有用。

data x;
  do i = 1 to 1000;
    output;
  end;
run;

data x;
  set x end = _end;
  end = _end;
proc print data = x;
  where end;
run;

Answer 3

有很多方法可以找到观测值的数量；以下宏是一个示例。

%macro nobs (dsn);
   %let nobs=0;
   %let dsid = %sysfunc(open(&dsn));
   %if &dsid %then %let nobs = %sysfunc(attrn(&dsid,nobs));
   %let rc   = %sysfunc(close(&dsid));
   &nobs
%mend nobs;

%let n = %nobs(apple);

proc print data=apple (firstobs=&n obs=&n); run;

Answer 4

有两种简单的解决方案：

解决方案 1：

data result;
    set apple end=end;
    if end then output;
run;
proc print data=result;
run;

解决方案 2：

data result;
    set apple nobs=nobs;
    if _N_=nobs then output;
run;
proc print data=result;
run;