使用泛型类型数组的类成员调整类实例大小

Question

下面是一段非常简单的代码，它模仿了我拥有的一些代码中的类结构（该表单仅包含附加到单击事件的单个按钮）。我正在使用 Delphi XE 和 XE II，并且在销毁该类所基于的生产代码中的对象时看到严重的崩溃。仅当我允许在 Clear() 方法中初始化 TMyClass 中的数组项的成员时，才会发生这些崩溃。

不幸的是，到目前为止，在这个示例代码中，崩溃是不可重复的，但它确实模仿了一些非常奇怪的行为，我怀疑这可能是问题的原因。

如果我在 TMyClass.Clear 函数中放置一个断点，并查看该类的 InstanceSize 成员，则报告为 1288。这很奇怪，因为单独的数组成员的大小实际上是 12kb。我可以将 TRecord2 提供的类型更改为 Integer，并且得到相同的 InstanceSize 结果。如果我从类中完全删除数组，我会得到约 264 字节的实例大小，对于仅包含单个 128 字节记录实例的类来说，这似乎超出了上限。这表明编译器已为 TMyClass 中的 V（TT 类型）成员的数组存储分配了 1024 字节。

我怀疑当我将 12kb 数据写入编译器认为大小为 1kb 的对象时，奇怪的实例大小会导致发生不好的事情。

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

type
  TRecord = record A : Array[1..128] of byte; end;
  TRecord2 = packed record S : Single; T : TDateTime; end;

  TBase = class(TObject)
    public
      R : TRecord;
  end;

  TBase2<T> = class(TBase)
    public
      type
        TT = packed array [0..31, 0..31] of T;

      var
        V : TT;
        R2 : TRecord;
  end;

  TMyClass = class(TBase2<TRecord2>)
    public
      procedure Clear;
  end;

procedure TForm1.Button1Click(Sender: TObject);
var
  O : TMyClass;
begin
  O := TMyClass.Create;
  O.Clear;
  O.Free;
end;

{ TMyClass }

procedure TMyClass.Clear;
var
  i, j : integer;
begin
  for i := 0 to 31 do
    for j := 0 to 31 do
      begin
        V[I, J].S := 0;
        V[I, J].T := 0;
      end;
end;

end.

Answer 1

这是一个错误，正如这个最小的复制所示：

program InstanceSizeBug;

{$APPTYPE CONSOLE}

type
  TMyClass<T> = class
    V: array [0..255] of T;
  end;
  TMyClassSingle = class(TMyClass<Single>);

begin
  Writeln(TMyClass<Single>.InstanceSize);
  Writeln(TMyClassSingle.InstanceSize);
  Readln;
end.

输出：

1032
264

请注意，在 Delphi 2010 中可以观察到相同的行为，这是我必须掌握的唯一的其他 Delphi 版本。

在调试器下进行跟踪，您会发现自己处于 _GetMem 中，其中 Size 参数等于 264，因此显然没有分配足够的内存。

为了以防万一，这个版本因 AV 而失败。

program InstanceSizeBug;

{$APPTYPE CONSOLE}

type
  TMyClass<T> = class
    V: array [1..256*256] of T;
  end;
  TMyClassSingle = class(TMyClass<Single>);

begin
  TMyClassSingle.Create.V[256*256] := 0;
end.

我已将此问题提交给 Quality Central，问题为 #100561。

作为解决方法，我建议您使用动态数组，并在构造函数中使用 SetLength 进行分配。我宁愿想象是固定大小的通用数组的存在导致编译器行为不当。