如何运行调色板的初始化代码？

Question

有时，最好有一些调色板（按钮）的初始化代码。例如，它可以定义调色板按钮使用的一些功能。

定义/运行调色板初始化代码的最简单和最好的方法是什么？

• 初始化可以在加载调色板时或第一次按下任何按钮时运行（可能的问题：如果在加载调色板后重新启动内核会怎样？）
• 定义应该以某种方式本地化（即在它们自己的上下文中 - 独特的笔记本上下文在这里有帮助吗？）
• 如果可能，我希望付出最小的努力解决方案（即在尽可能少的地方添加额外代码，自包含调色板文件，没有额外的包文件，使用调色板菜单或CreatePalette等现有的便利工具创建调色板
• （您可以假设初始化代码运行得很快，例如它仅由定义组成）

Answer 1

您对动态可见性问题的担忧是正确的。无论任何单个单元格的可见性如何，绝对保证对Dynamic表达式进行求值的方法是使用NotebookDynamicExpression。下面的示例说明了 NotebookDynamicExpression 在 Dynamic 因隐藏在封闭单元格组中而失败时仍能正常工作：

cell1 = First @ MakeBoxes[
    TextCell["Click to open", "Title", 
        CellMargins -> 0, System`WholeCellGroupOpener -> True],
    StandardForm];
cell2 = First @ MakeBoxes[
    ExpressionCell[DynamicWrapper["hidden cell", Print["DynamicWrapper"]]], 
    StandardForm];
CreatePalette[
    Notebook[{Cell[CellGroupData[{cell1, cell2}, Closed]]}, 
        NotebookDynamicExpression :>
            Dynamic[Refresh[Print["NotebookDynamicExpression"], None]]]]

当您对此进行评估时，请注意 Dynamic NotebookDynamicExpression 中的值立即计算。在您打开单元格组之前，DynamicWrapper 永远不会计算，您可以通过单击“单击打开”文本来完成此操作。

顺便请注意，在此示例中，我用 Refresh 包装了 NotebookDynamicExpression。函数 Refresh[#, None]& 将确保代码仅计算一次 - 当笔记本首次打开时。否则，代码将遵循Dynamic的标准属性，并在任何依赖项发生变化时进行评估。

NotebookDynamicExpression 自 v6 以来就已存在，但仅在 v8 中进行了记录。还记录了其相关的表兄弟 CellDynamicExpression 和 FrontEndDynamicExpression。

Answer 2

带有初始化的DynamicBox能够实现基本功能。您可以调整调色板的大小，使该对象不可见，但它仍然可以运行。

这是一个小示例调色板的代码。它为 var 设置一个值。活动代码用空格偏移。

(* Beginning of Notebook Content *)
Notebook[{
Cell[BoxData[{
 TagBox[GridBox[{
    {
     ButtonBox["\<\"TSV\"\>",
      Appearance->Automatic,
      ButtonFunction:>None,
      Evaluator->Automatic,
      Method->"Preemptive"]},
    {
     ButtonBox["\<\"CSV\"\>",
      Appearance->Automatic,
      ButtonFunction:>None,
      Evaluator->Automatic,
      Method->"Preemptive"]},
    {
     ButtonBox["\<\"Table\"\>",
      Appearance->Automatic,
      ButtonFunction:>None,
      Evaluator->Automatic,
      Method->"Preemptive"]}
   },
   GridBoxAlignment->{"Columns" -> {{Left}}},
   GridBoxItemSize->{"Columns" -> {{Automatic}}, "Rows" -> {{Automatic}}}],
  "Column"], "\[IndentingNewLine]", 

DynamicBox[Null,
   Initialization :> ($CellContext`var = "It is done, Master.")
]

}], NotebookDefault,
 CellMargins->{{0, 0}, {0, 0}},
 CellBracketOptions->{"Color"->RGBColor[0.269993, 0.308507, 0.6]},
 CellHorizontalScrolling->True,
 PageBreakAbove->True,
 PageBreakWithin->False,
 ShowAutoStyles->True,
 LineSpacing->{1.25, 0},
 AutoItalicWords->{},
 ScriptMinSize->9,
 ShowStringCharacters->False,
 FontFamily:>CurrentValue["PanelFontFamily"],
 FontSize:>CurrentValue["PanelFontSize"]]
},
WindowSize->{55, 105},
WindowMargins->{{Automatic, 583}, {Automatic, 292}},
WindowFrame->"Palette",
WindowElements->{},
WindowFrameElements->{"CloseBox", "MinimizeBox"},
StyleDefinitions->"Palette.nb"
]
(* End of Notebook Content *)