将 Delphi 风格的 ASM 翻译成英文？

Question

我最近继承的一个Delphi项目有一个ASM过程。我是一个完全的ASM新手，所以我不明白它。我已经阅读了各种 ASM 指令来尝试破译程序流程，但我仍然不明白。

有 ASM 经验的人可以帮助我理解并将以下过程翻译成英文（然后我可以翻译回 Delphi，以便将来代码更容易阅读！！！）

Mem1 的声明是一个数组 [0. .15]字节；。 Mem2 是一个 LongInt。

程序如下：

 procedure TForm1.XorMem(var Mem1; const Mem2; Count : Cardinal); register;
 begin
 asm
   push esi
   push edi

   mov  esi, eax         //esi = Mem1
   mov  edi, edx         //edi = Mem2

   push ecx              //save byte count
   shr  ecx, 2           //convert to dwords
   jz   @Continue

   cld
 @Loop1:                 //xor dwords at a time
   mov  eax, [edi]
   xor  [esi], eax
   add  esi, 4
   add  edi, 4
   dec  ecx
   jnz  @Loop1

 @Continue:              //handle remaining bytes (3 or less)
   pop  ecx
   and  ecx, 3
   jz   @Done

 @Loop2:                 //xor remaining bytes
   mov  al, [edi]
   xor  [esi], al
   inc  esi
   inc  edi
   dec  ecx
   jnz  @Loop2

 @Done:
   pop  edi
   pop  esi
 end;

 end;

编辑：感谢 Roman R，我已将 ASM 转换回 Delphi

procedure TForm1.XorMem2(var Mem1; const Mem2 :LongInt; Count : Cardinal);
var
  Key : array [0..3] of byte absolute Mem1;
  Num : array [0..3] of byte absolute Mem2;
  idx : byte;
begin
  for Idx := 0 to Count -1 do Key[idx] := Key[idx] Xor Num[idx];
end;

Answer 1

该函数接受两个指针（指向任何数组）及其长度（以字节为单位）。该函数使用第二个数组字节 (Mem2) 对第一个数组字节 (Mem1) 执行字节到字节 XOR 运算。伪代码：

for Index = 0 to Count - 1
  (Mem1 as Byte Array) [Index] = (Mem1 as Byte Array) [Index] Xor (Mem2 as Byte Array) [Index]

Answer 2

这是一个有效且简单的纯 pascal 版本：

procedure TForm1.XorMem(var Mem1; const Mem2; Count : Cardinal);
var i: integer;
    M1: TByteArray absolute Mem1;
    M2: TByteArray absolute Mem2;
begin
  for i := 0 to Count-1 do
     M1[i] := M1[i] xor M2[i];
end;

这是一个使用 DWORD 读取的优化版本：

procedure TForm1.XorMem(var Mem1; const Mem2; Count : Cardinal);
var i, n: integer;
    M1: TByteArray absolute Mem1;
    M2: TByteArray absolute Mem2;
    I1: TIntegerArray absolute Mem1;
    I2: TIntegerArray absolute Mem2;
begin
  n := Count shr 2;
  for i := 0 to n-1 do
     I1[i] := I1[i] xor I2[i];
  n := n shl 2;
  for i := 0 to (Count and 3)-1 do
     M1[n+i] := M1[n+i] xor M2[n+i];
end;

恕我直言，第二个版本不是强制性的。如果数据是 DWORD 对齐的，则一次读取 DWORD 是有意义的。否则，它实际上会变慢。对于少量数据，一个小的 Delphi 循环将足够快，并且易于阅读。最新的 CPU（如 Core i5 或 i7）在使用小型代码循环时会创造奇迹（不再需要展开循环）。