漂亮的 ConfigObject 打印？

Question

我有这个 groovy 程序，它使用 ConfigObject 创建一个 groovy 配置文件。设置 ConfigObject 后，将使用以下命令将其写入文件：

myFile.withWriter {writer -> myConfigObject.writeTo(writer)}

这会导致 ConfigObject 的每个属性都写入一行。例如，一张地图将被打印为：

graphs=[["type":"std", "host":"localhost", "name":"cpurawlinux"], ["type":"std", "host":"localhost", "name":"memory"], ["type":"std", "host":"localhost", "name":"udp"] ... ]

如果有人必须看一下它，这是非常不可读的。 有没有办法获得更友好的输出？类似的东西会很棒：

graphs=[
    ["type":"std", "host":"localhost", "name":"cpurawlinux"],
    ["type":"std", "host":"localhost", "name":"memory"],
    ["type":"std", "host":"localhost", "name":"udp"]
    ...
]

我知道我可以创建自己的 writeTo，但是 Groovy 中不是已经有这样的东西了吗？

Answer 1

不幸的是，您需要像您所说的那样编写自己的 writeTo 。

如果你有一个结构如下的配置文件：

graphs {
  a=["type":"std", "host":"localhost", "name":"cpurawlinux"]
  b=["type":"std", "host":"localhost", "name":"memory"]
}

那么 writeTo 会用结构写出它，但如果你的配置文件只是一个大的旧列表，它会把它写成一个大的旧列表

Answer 2

如果它对任何人有帮助，我有同样的问题并写了这个......不漂亮（哈），但有效：

def prettyPrint(properties, level=1, stringBuilder = new StringBuilder()) {
    return properties.inject(stringBuilder) { sb, name, value ->
        sb.append("\n").append("\t" * level).append(name)
        if (!(value instanceof Map) && !(value instanceof List)) {
            return sb.append("=").append(value)
        } else {
            return prettyPrint(properties.getProperty(name), level+1, sb)
        }
    }
}

Answer 3

基于迈克上面的回答：

def prettyPrint
prettyPrint = {obj, level = 0, sb = new StringBuilder() ->
    def indent = { lev -> sb.append("  " * lev) }
    if(obj instanceof Map){
        sb.append("{\n")
        obj.each{ name, value ->
            if(name.contains('.')) return // skip keys like "a.b.c", which are redundant
            indent(level+1).append(name)
            (value instanceof Map) ? sb.append(" ") : sb.append(" = ")
            prettyPrint(value, level+1, sb)
            sb.append("\n")
        }
        indent(level).append("}")
    }
    else if(obj instanceof List){
        sb.append("[\n")
        obj.each{ value ->
            indent(level+1)
            prettyPrint(value, level+1, sb).append(",")
            sb.append("\n")
        }
        indent(level).append("]")
    }
    else if(obj instanceof String){
        sb.append('"').append(obj).append('"')
    }
    else {
        sb.append(obj)
    }
}

对于如下输入：

{
  grails {
    scaffolding {
      templates.domainSuffix = "Instance"
    }
    enable {
      native2ascii = true
      blah = [ 1, 2, 3 ]
    }
    mime.disable.accept.header.userAgents = [ "WebKit", "Presto", "Trident" ]
  }
}

产生：

{
  grails {
    scaffolding {
      templates {
        domainSuffix = "Instance"
      }
    }
    enable {
      native2ascii = true
      blah = [
        1,
        2,
        3,
      ]
    }
    mime {
      disable {
        accept {
          header {
            userAgents = [
              "WebKit",
              "Presto",
              "Trident",
            ]
          }
        }
      }
    }
  }
}

Answer 4

由于 GreenGiant 的答案在我尝试使用它时似乎已损坏，因此这里有一个工作版本以供将来参考：

static String prettify(obj, level = 0, StringBuilder sb = new StringBuilder()) {
    def indent = { lev -> sb.append("  " * lev) }
    if (!obj) return sb
    if(obj instanceof Map<String, ?>){
        sb.append("{\n")
        obj.each{ name, value ->
            if(name.contains('.')) return // skip keys like "a.b.c", which are redundant
            indent(level+1).append(name)
            (value instanceof Map) ? sb.append(" ") : sb.append(" = ")
            prettify(value, level+1, sb)
            sb.append("\n")
        }
        indent(level).append("}")
    } else if(obj instanceof List){
        sb.append("[\n")
        obj.each{ value ->
            indent(level+1)
            prettify(value, level+1, sb).append(",")
            sb.append("\n")
        }
        indent(level).append("]")
    } else if(obj instanceof String){
        sb.append('"').append(obj).append('"')
    } else {
        sb.append(obj)
    }
}