如何在 Common Lisp 中复制数组？

Question

我想复制我的二维数组，这感觉是处理数组的一种很好的、​​实用的、非破坏性的方式。这样做的 lispy 方式是什么？

Answer 1

更新：如今，alexandria 有一个副本- array 与下面给出的实现非常相似。用那个。

过时的答案：我使用了以下内容，我认为它比当时的 alexandria 版本更好：

(defun copy-array (array &key
                   (element-type (array-element-type array))
                   (fill-pointer (and (array-has-fill-pointer-p array)
                                      (fill-pointer array)))
                   (adjustable (adjustable-array-p array)))
  "Returns an undisplaced copy of ARRAY, with same fill-pointer and
adjustability (if any) as the original, unless overridden by the keyword
arguments."
  (let* ((dimensions (array-dimensions array))
         (new-array (make-array dimensions
                                :element-type element-type
                                :adjustable adjustable
                                :fill-pointer fill-pointer)))
    (dotimes (i (array-total-size array))
      (setf (row-major-aref new-array i)
            (row-major-aref array i)))
    new-array))

alexandria 版本的问题是 adjust-array
hack 导致结果（至少在 SBCL 上）永远不会是
simple-array，这是其他一些库（例如opticl）所期望的。这
上面的版本对我来说也更快。

其他人在不同的地方发布了非常相似的版本
图书馆，但我忘记了人和图书馆的名字。

Answer 2

Common Lisp 库 Alexandria （可通过 quicklisp) 包含任意等级和维度的 copy-array 实现：

(defun copy-array (array &key
                   (element-type (array-element-type array))
                   (fill-pointer (and (array-has-fill-pointer-p array)
                                      (fill-pointer array)))
                   (adjustable (adjustable-array-p array)))
  "Returns an undisplaced copy of ARRAY, with same fill-pointer and
adjustability (if any) as the original, unless overridden by the keyword
arguments. Performance depends on efficiency of general ADJUST-ARRAY in the
host lisp -- for most cases a special purpose copying function is likely to
perform better."
  (let ((dims (array-dimensions array)))
    ;; Dictionary entry for ADJUST-ARRAY requires adjusting a
    ;; displaced array to a non-displaced one to make a copy.
    (adjust-array
     (make-array dims
                 :element-type element-type :fill-pointer fill-pointer
                 :adjustable adjustable :displaced-to array)
     dims)))

Answer 3

这取决于你的 2D 数组如何表示，以及你使用什么风格的 Lisp。

如果您使用的是 Common Lisp，则 copy-seq可能有用。

Answer 4

如果您想要以良好的、实用的、非破坏性的方式做事，那么您为什么还需要复制它呢？

• 如果您复制它是为了更新它——那么您就没有按照功能方式进行操作。

• 如果您以功能方式执行此操作 - 那么您不需要副本。您可以将其传递到任何地方。

也许你想改变它。在这种情况下，您可以使用 Lisp 的众多纯函数之一，例如 mapcar 或 filter。