转换类型的值变成变体，有可能吗？

Question

这是一个显示我想要实现的目标的片段：

type
  TMyObject<T> = class (TObject)
    function GetVarType(Value: T): TVarType;
  end;


function TMyObject<T>.GetVarType(Value: T): TVarType;
var
  TmpValue: Variant;
begin
  TmpValue := Variant(Value); //Invalid typecast
  Result := VarType(TmpValue);
end;

我知道上面的类型转换方法很幼稚，但我希望你明白。我想用一些转换机制来代替它。

TMyObject 将始终是简单类型，如 Integer、String、Single、Double。

这种转换的目的是函数 VarType 为每个简单类型提供整数常量，我可以将其存储在其他地方。

我想知道这样的转换是否可行？

感谢您抽出时间。

Answer 1

它可以在具有增强 RTTI（2010 及更新版本）的 Delphis 中轻松解决。太糟糕了，您仅限于 2009 年:(

function TMyObject<T>.GetVarType(Value: T): TVarType;
begin
  Result := VarType(TValue.From<T>(Value).AsVariant);
end;

这仅适用于简单类型，但这是问题中指定的约束。

Answer 2

您可以使用 RTTI 来获取此信息，只需检查 TTypeInfo.Kind 属性的值：

检查此示例代码，

{$APPTYPE CONSOLE}

uses
  TypInfo,
  Variants,
  Generics.Collections,
  SysUtils;

type
  TMyObject<T> = class (TObject)
    function GetVarType(Value: T): TVarType;
  end;


function TMyObject<T>.GetVarType(Value: T): TVarType;
begin
  Case PTypeInfo(TypeInfo(T))^.Kind of
    tkInteger : Result:=varInteger;
    tkFloat   : Result:=varDouble;
    tkString  : Result:=varString;
    tkUString : Result:=varUString;
    //add more types here
  End;
end;

Var
  LObj : TMyObject<Integer>;
begin
  try
     Writeln(VarTypeAsText(TMyObject<Integer>.Create.GetVarType(5)));
     Writeln(VarTypeAsText(TMyObject<String>.Create.GetVarType('Test')));
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

这将返回

Integer
UnicodeString

Answer 3

我不明白如何使用泛型来做到这一点。编译器需要知道类型 T 的实例可以分配给任何可能的 T 的 Variant。您无法告诉编译器这是可能的。

如果这是 C++ 中的模板，那么这将是微不足道的。

Answer 4

感谢大家的回答：

正如 @RRUZ 所表明的那样，这是可能的（我的意思不是严格分配，而是提取数据类型）。我在等待任何答案时自己工作，并找到了更通用的解决方案。

所以我把它放在这里：

type
  TMyObject<T> = class (TObject)
    function GetVarType(Value: T): TVarType;
  end;


function TMyObject<T>.GetVarType(Value: T): TVarType;
begin
  Result := GetTypeData(TypeInfo(T)).varType;
end;

再次感谢！