XE2 中的 COM 是否损坏？我该如何解决它？

Question

更新： XE2 Update 2 修复了下述错误。

下面的程序是从实际程序中截取的，在 XE2 中出现异常而失败。这是 2010 年的回归。我没有 XE 来测试，但我希望该程序在 XE 上运行良好（感谢 Primož 确认代码在 XE 上运行良好）。

program COMbug;

{$APPTYPE CONSOLE}

uses
  SysUtils, Variants, Windows, Excel2000;

var
  Excel: TExcelApplication;
  Book: ExcelWorkbook;
  Sheet: ExcelWorksheet;
  UsedRange: ExcelRange;
  Row, Col: Integer;
  v: Variant;

begin
  Excel := TExcelApplication.Create(nil);
  try
    Excel.Visible[LOCALE_USER_DEFAULT] := True;
    Book := Excel.Workbooks.Add(EmptyParam, LOCALE_USER_DEFAULT) as ExcelWorkbook;
    Sheet := Book.Worksheets.Add(EmptyParam, EmptyParam, 1, EmptyParam, LOCALE_USER_DEFAULT) as ExcelWorksheet;

    Sheet.Cells.Item[1,1].Value := 1.0;
    Sheet.Cells.Item[2,2].Value := 1.0;
    UsedRange := Sheet.UsedRange[LOCALE_USER_DEFAULT] as ExcelRange;
    for Row := 1 to UsedRange.Rows.Count do begin
      for Col := 1 to UsedRange.Columns.Count do begin
        v := UsedRange.Item[Row, Col].Value;
      end;
    end;
  finally
    Excel.Free;
  end;
end.

在 XE2 32 位中，错误是：

项目 COMbug.exe 引发了异常类 $C000001D，并带有消息“系统异常（代码 0xc000001d）位于 0x00dd6f3e”。

第二次执行 UsedRange.Columns 时发生错误。

在 XE2 64 位中，错误是：

项目 COMbug.exe 引发异常类 $C0000005，消息为“c0000005 ACCESS_VIOLATION”

再次，我认为该错误发生在第二次执行 UsedRange.Columns 时，但 64 位调试器会单步执行代码有点奇怪，所以我不能 100% 确定。

我已针对该问题提交了质量控制报告。

在我看来，Delphi COM/自动化/接口堆栈中的某些东西似乎已全面损坏。这对我采用 XE2 来说是一个彻底的阻碍。

有人有这个问题的经验吗？有人对我如何尝试解决该问题有任何提示和建议吗？调试这里真正发生的事情超出了我的专业领域。

Answer 1

解决方法

rowCnt := UsedRange.Rows.Count;
colCnt := UsedRange.Columns.Count;
for Row := 1 to rowCnt do begin
  for Col := 1 to colCnt do begin
    v := UsedRange.Item[Row, Col].Value;
  end;
end;

这也有效（并且可以帮助您在更复杂的用例中找到解决方法）：

function ColCount(const range: ExcelRange): integer;
begin
  Result := range.Columns.Count;
end;

for Row := 1 to UsedRange.Rows.Count do begin
  for Col := 1 to ColCount(UsedRange) do begin
    v := UsedRange.Item[Row, Col].Value;
  end;
end;

分析

当在 Delphi XE中执行 _Release 时，它​​会在 DispCallByID 中的 System.Win.ComObj 中崩溃

varDispatch, varUnknown:
  begin
    if PPointer(Result)^ <> nil then
      IDispatch(Result)._Release;
    PPointer(Result)^ := Res.VDispatch;
  end;

尽管在 Delphi XE 中此相同过程的 PUREPASCAL 版本（XE 使用汇编程序）版本）不同……

varDispatch, varUnknown:
  begin
    if PPointer(Result)^ <> nil then
      IDispatch(Result.VDispatch)._Release;
    PPointer(Result)^ := Res.VDispatch;
  end;

两种情况下的汇编代码是相同的（编辑：不正确，请参阅最后我的注释）：

@ResDispatch:
@ResUnknown:
        MOV     EAX,[EBX]
        TEST    EAX,EAX
        JE      @@2
        PUSH    EAX
        MOV     EAX,[EAX]
        CALL    [EAX].Pointer[8]
@@2:    MOV     EAX,[ESP+8]
        MOV     [EBX],EAX
        JMP     @ResDone

有趣的是，这会崩溃……

for Row := 1 to UsedRange.Rows.Count do begin
  for Col := 1 to UsedRange.Columns.Count do begin
  end;
end;

并且这个没有。

row := UsedRange.Rows.Count;
col := UsedRange.Columns.Count;
col := UsedRange.Columns.Count;

其原因是使用了隐藏的局部变量。在第一个示例中，代码编译为……

00564511 6874465600       push $00564674
00564516 6884465600       push $00564684
0056451B A12CF35600       mov eax,[$0056f32c]
00564520 50               push eax
00564521 8D8508FFFFFF     lea eax,[ebp-$000000f8]
00564527 50               push eax
00564528 E8933EEAFF       call DispCallByIDProc

并且被调用两次。

在第二个示例中，使用了堆栈上的两个不同的临时位置（ebp - ?????? 偏移量）：

00564466 6874465600       push $00564674
0056446B 6884465600       push $00564684
00564470 A12CF35600       mov eax,[$0056f32c]
00564475 50               push eax
00564476 8D8514FFFFFF     lea eax,[ebp-$000000ec]
0056447C 50               push eax
0056447D E83E3FEAFF       call DispCallByIDProc
...
0056449B 6874465600       push $00564674
005644A0 6884465600       push $00564684
005644A5 A12CF35600       mov eax,[$0056f32c]
005644AA 50               push eax
005644AB 8D8510FFFFFF     lea eax,[ebp-$000000f0]
005644B1 50               push eax
005644B2 E8093FEAFF       call DispCallByIDProc

当清除存储在该临时位置中的内部接口时，会发生该错误，这种情况仅在“for”情况为第二次执行是因为这个接口中已经存储了一些东西 - 当第一次调用“for”时它被放在那里。在第二个示例中，使用了两个位置，因此该内部接口始终初始化为 0，并且根本不调用 Release。

真正的 bug 是这个内部接口包含垃圾，当调用 Release 时，会发生 sh!t。

经过更多挖掘，我注意到释放旧接口的汇编代码不一样 - XE2版本缺少一条“mov eax, [eax]”指令。 IOW，

IDispatch(Result)._Release;

这是一个错误，它确实应该是

IDispatch(Result.VDispatch)._Release;

令人讨厌的 RTL bug。

Answer 2

其中大部分都超出了我的想象，但我确实想知道是否需要调用 CoInitialize。在网络上搜索 CoInitialize 返回此页面：

http://chrisbensen。 blogspot.com/2007/06/delphi-tips-and-tricks.html

看起来该页面几乎将 OP 和 gabr 的分析中的问题描述为它与对 .Release 的调用有关。将代码的功能转移到它自己的过程中可能会有所帮助。我没有 XE 或 XE2 来测试。

编辑：老鼠 - 旨在将其添加为上述内容的评论。