将符号暴露给 $ContextPath

Question

有多种有用的Internal`上下文函数，例如InheritedBlock, Bag 和 StuffBag 等，以及许多有用的 Developer` 功能。

我希望公开这些符号的选择，以便可以在没有上下文名称的情况下清楚地寻址它们，但我不想通过添加 Internal` 和 Developer` 到 $ContextPath。

我可以使用诸如 Bag = Internal`Bag 之类的代理符号，但这既不干净也不完全正确，因为它是一个引用，并且例如属性不是继承的。

有没有一种方法可以选择性地公开我想要的符号，而无需诉诸上面的麻烦？

Answer 1

在我看来，这是一个非常深刻和有效的问题，从投票数来看，我并不是唯一一个这么想的人。如果我们在语言级别上完全支持此功能，这将提供一种全新的方式来操作范围和封装，并且 IMO 通常会允许更清晰的代码和更好的信息隐藏。这类似于 Python 中的 from module-name import name1,name2,...。

也许和我们许多人一样，我尝试过多种方法，但所有这些方法似乎都很脆弱且不完整。最坏的情况是对于包，对此我没有很好的解决方案。对于前端的交互工作，这里是一个可能可以接受的。首先定义一个通用宏来进行文字替换：

ClearAll[withImported];
SetAttributes[withImported, HoldAll];
withImported[importingRules : {(_Symbol ->  _String) ..}, code_] :=
  With @@ Join[
     Hold[importingRules] /.
      (name_Symbol -> context_String) :>
          With[{eval =
               Block[{$ContextPath = Append[$ContextPath, context]},
                 ToExpression[context <> ToString[Unevaluated@name]]
               ]},
             Set[name, eval] /; True],
     Hold[code]];

withImported[importingRules : {({__Symbol} -> _String) ..}, code_] :=  
    Reverse[Hold @@ Flatten[Unevaluated[importingRules] /.
        ({syms__Symbol} -> s_String) :> Thread[s :> {syms}]], {2}] /. 
        RuleDelayed -> Rule /.
        Hold[expandedRules : ((_Symbol ->  _String) ..)] :> 
             withImported[{expandedRules}, code];

然后，创建一个包含您最喜欢的快捷方式的函数，例如：

shortcutF = 
   Function[code,
     withImported[
       {
         {PackedArrayQ, ToPackedArray, FromPackedArray} -> "Developer`",
         {InheritedBlock, WithLocalSettings} -> "Internal`"
       },
       code
     ],
     HoldAll];

您现在可以将代码包装在 shortcutF 中并开始使用短名称。到目前为止，这也适用于包，但您必须将所有代码（或至少包含快捷方式的代码）包装在 shortcutF 中，这不是很方便。作为进一步方便的步骤，您可以将上述函数分配给 $Pre：

$Pre = shortcutF;

以下是一些使用示例：

In[31]:= 
WithLocalSettings[Null,Abort[],Print["Cleanup"]]

During evaluation of In[31]:= Cleanup
Out[31]= $Aborted[]

In[32]:= PackedArrayQ[Range[10]]
Out[32]= True

In[33]:= PackedArrayQ@FromPackedArray[Range[10]]
Out[33]= False

由于 With 是在幕后使用的，所以真正发生的情况是在执行代码之前，您的快捷符号将被完全限定的符号名称替换。

这是我所能得到的，但这个功能似乎特别需要该语言的本地支持。

Answer 2

Leonid 的答案的一个变体适用于早期阶段：

InternalSymbols={"Bag","BagLength","BagPart","StuffBag"}
$PreRead=#/.(InternalSymbols/.{s_String:>s->"Internal`"<>s})&

在笔记本中输入此内容后，输入

?Bag

给我

Internal`Bag
Attributes[Internal`Bag]={Protected}

while

?AbsSquare

gets

Information::notfound: Symbol AbsSquare not found.

但

?Internal`AbsSquare

gets

Internal`AbsSquare
Attributes[Internal`AbsSquare]={Listable,NumericFunction,Protected}

但是它似乎只在笔记本界面中工作，而不是在命令行上使用数学时工作。