模拟 Length 函数来获取列表的长度

Question

我正在尝试模拟 Mathematica v.8 中的 Length 函数来获取列表的长度。鉴于以下事实：

• 空列表表示为 {}
• l = Rest[l] 将没有第一个元素的列表 l 分配给 l （这是一个列表）
• While 循环

这是我使用 mathematica 的第一年，我不太擅长所以我正在做的事情可能有问题（或一切）：

Ej1[l_List] := Module[{i, v},
v = {{}};
i = 1;
While[l != v, l = Rest[l]; i++]
Return[i]
]

l={a,b,c,d,e};

当我尝试运行它时，循环永远不会结束，并且它给了我以下警告：

Set::shape: Lists {a,b,c,d,e} and {b,c,d,e} are not the same shape. >>

Set::shape: Lists {a,b,c,d,e} and {b,c,d,e} are not the same shape. >>

Set::shape: Lists {a,b,c,d,e} and {b,c,d,e} are not the same shape. >>

General::stop: Further output of Set::shape will be suppressed during this calculation. >>

Answer 1

主要问题是您试图修改输入变量 l，这是不可能的，并且缺少分号。

Ej1[l_List] := Module[{i = 0, v = {}, thisl},
  thisl = l;
  While[thisl != v, thisl = Rest[thisl]; i++];
  i]

Answer 2

您还可以使用 NestWhile：

Clear[f];
f[l_List] := NestWhile[{Rest[#[[1]]], (#[[2]]) + 1} &, {l, 0}, 
   (#[[1]] != {}) &][[2]]

此代码不受 $RecursionLimit 或 $IterationLimit 限制，因此它也适用于非常大的列表。缺点是它效率不高，因为在每个迭代步骤中都会对剩余列表进行复制。计算列表中元素的更快方法是执行类似

f2[l_List] := Fold[(# + 1) &, 0, l]

比较的操作：

list=RandomReal[1,10000];
Timing[f[list]]
(* ==> {3.35747, 10000} *)

Timing[f2[list]]
(* ==> {0.000658, 10000} *)

Answer 3

length[myList_List] := Module[{x = 0}, Scan[x++ &, myList]; x]

length[{a, b, c, d, e, f, g}]

==> 7

Answer 4

递归地，使用 If[]：

ClearAll[f];

f[l_List, i_: 0] := If[l != {}, f[Rest[l], i + 1], i];

f[{1,2}]
(*
-> 2
*)

Answer 5

这是另一个递归解决方案，我认为这是相当惯用的函数式编程：

myLength[{}] := 0
myLength[lis_List] := 1 + myLength[Rest[lis]]

In[47]:= myLength[{}]
Out[47]= 0

In[48]:= myLength[{1}]
Out[48]= 1

In[49]:= myLength[{1,2,3,4,5}]
Out[49]= 5

Answer 6

与贝利萨留相同，但没有显式编写 If：

ClearAll[ej2];
ej2[lst_ /; (lst == {}), i_: 0] := i
ej2[lst_, i_: 0] := ej2[Rest[lst], i + 1]

ej2[{1, 2, 3, 4, 5}]
(*
5
*)