防止 Access 2007 中的意外数据覆盖

Question

我有一个简单的 Access 2007 数据库，并且在表单中添加了一个按钮，用于切换编辑当前显示记录的能力。

默认情况下，我将AllowEdits、AllowAdditions 和AllowDeletions 设置为 false。单击“编辑模式”按钮可以更改此设置。

我还添加了几个表单事件，以便当显示的记录更改时，编辑模式会被取消。

我现在发现无法创建新记录，因为当我单击 BtnNew（附加标准添加新记录宏）时，我收到错误“您无法转到指定的记录”。

我在数据库中的VB代码如下，任何人都可以看到我做错了什么，或者从哪里开始寻找？ （我缺乏 VB/Access 知识，但我理解这些概念，因为我是一名 C# 开发人员）。

Private Sub BtnEdit_Click()
    If lblEditMode.Caption = "Edit Mode" Then
        Disable
    Else
       Enable
    End If
End Sub

Private Sub Form_AfterDelConfirm(Status As Integer)
    Disable
End Sub

Private Sub Form_Current()
    Disable
End Sub

Private Sub Disable()
    AllowEdits = False
    AllowAdditions = False
    AllowDeletions = False
    BtnNew.Enabled = False
    BtnDelete.Enabled = False
    lblEditMode.Caption = ""
End Sub

Private Sub Enable()
    AllowEdits = True
    AllowAdditions = True
    AllowDeletions = True
    BtnNew.Enabled = True
    BtnDelete.Enabled = True
    lblEditMode.Caption = "Edit Mode"
End Sub

令我震惊的是，我没有将AllowAdditions 设置为True，但我的标签清楚地正确显示“编辑模式”。

Answer 1

您的问题是，当您转到新记录时，Access 通过 Form_Current 将 AllowAdditions 设置为 false，这使得保留在新记录上无效（本质上）。我不确定这是最好的解决方案，但我会设置一个与表单级别相同的状态变量，然后当选择新按钮时，设置该变量并设置 Form_Current 以跳过禁用功能。

Enum ValidStates
    Locked = 0
    Edit = 1
    NewRecord = 2
End Enum

Dim formState As ValidStates

然后对于 btnNew，使用 [事件过程]

Private Sub btnNew_Click()
    On Error GoTo Err_btnNew_Click

    formState = NewRecord
    DoCmd.GotoRecord , , acNewRec

    Exit Sub

Err_btnNew_Click:
    MsgBox Err.Description
End Sub

并在 Form_Current 事件中添加以下内容：

Private Sub Form_Current()
    If formState <> NewRecord Then Disable
    formState = Edit
End Sub

这将允许您编辑新记录。您的启用和禁用功能还将分别添加一行来设置正确的表单状态：

formState = Locked ' for Disable
formState = Edit ' for Enable