为不同的加载器重用事件监听器 Flash - AS3

Question

我想重用我的 loadImage 函数，该函数传递一个 url 和一个字符串值，并将图像加载到影片剪辑中。

我有多个图像想要加载到不同的影片剪辑中。我以为我可以用我的 addEventListener(Event.COMPLETE, 传递一个变量，但它只在我第一次加载图像时起作用，下面是我的代码，下面是我的错误：

AS3

    //CALL loadImage  FUNCTION PASS URL TO LOCAL IMAGE AND UNIQUE NUMBER FOR EVENTLISTENER


loadImage('\\assets\\' + rootPath + '\\images\\bg.jpg',"1");
loadImage('\\assets\\' + rootPath + '\\images\\english.png',"2");
loadImage('\\assets\\' + rootPath + '\\images\\spanish.png',"3");

var imageLoader:Loader;

function loadImage(url:String,inc:String):void {
    trace(inc);
imageLoader = new Loader();
imageLoader.load(new URLRequest(url));
imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE,
    function(e:Event) : void { imageLoaded(inc) });

}

function imageLoaded(counter:String):void {
    trace(counter);
if (counter == "1"){

    trace("Background");
background.addChild(imageLoader);
}else if (counter == "2"){

    trace("english");

englishMC.addChild(imageLoader);
}else if (counter == "3"){

    trace("Spanish");

spanishMC.addChild(imageLoader);
}
}

错误：

TypeError: Error #2007: Parameter listener must be non-null.
    at flash.events::EventDispatcher/addEventListener()
    at Function/<anonymous>()
    at EndCap_fla::MainTimeline/processXML()
    at flash.events::EventDispatcher/dispatchEventFunction()
    at flash.events::EventDispatcher/dispatchEvent()
    at flash.net::URLLoader/onComplete()

我知道我可以为每个加载的图像设置单独的函数，但如果可能的话，我希望能够重用 loadImage 函数

Answer 1

问题是您在每次加载时都会覆盖相同的 imageLoader，因此基本上每次调用 imageLoaded 时，您都会使用最后一个图像。

在您的情况下，我将创建一个新类来处理将图像加载到指定容器中，围绕这些行：

class ResourceLoader {
    private var target: Container;
    private var loader: Loader;

    function ResourceLoader(target:Container, image: String) {
        loader = ...
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
    }

    function onComplete(e: Event):void {
        target.addChild(loader);
    }
}

并像这样使用它：（

new ResourceLoader(background, '\\assets\\' + rootPath + '\\images\\bg.jpg');

尚未测试代码，可能有一些拼写错误）

Answer 2

（看起来您已修复 Error #2007，正如 CapelliC 指出的那样。 )

要重用 loadImage()，它必须独立于其外部的任何内容。您当前的 loadImage() 需要 imageLoader，您应该在函数内声明它。

imageLoaded() 也依赖于它，但由于它进入事件侦听器，您应该通过执行 .addChild(e.currentTarget.loader) 来获取 imageLoader 而不是 .addChild(imageLoader)。

这种范围混乱是导致您丢失另外两个加载图像的原因（注意闭包！），因为在每次函数调用时 imageLoader 都会被自身的新实例覆盖。

此外，在对 imageLoaded() 进行小幅更改后，您可以使用 addEventListener() 轻松传递任何变量。这就是您应该如何完成这一切：

loadImage("\\assets\\" + rootPath + "\\images\\bg.jpg", "1");
loadImage("\\assets\\" + rootPath + "\\images\\english.png", "2");
loadImage("\\assets\\" + rootPath + "\\images\\spanish.png", "3");

function loadImage(url:String, inc:String):void {
  trace(inc);
  var imageLoader:Loader = new Loader();
  imageLoader.load(new URLRequest(url));
  imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded(inc));
}

function imageLoaded(counter:String):Function {
  return function(e:Event):void {
    trace(counter);
    if (counter == "1") {
      trace("Background");
      background.addChild(e.currentTarget.loader);
    } else if (counter == "2") {
      trace("english");
      englishMC.addChild(e.currentTarget.loader);
    } else if (counter == "3") {
      trace("Spanish");
      spanishMC.addChild(e.currentTarget.loader);
    }
    //e.currentTarget.removeEventListener(Event.COMPLETE, arguments.callee);
  }
}

现在您可以重用 loadImage() 和 imageLoaded()。

Answer 3

您应该内联编写事件处理程序，以传递计数器：

function loadImage(url:String,inc:String):void {
imageLoader = new Loader();
imageLoader.load(new URLRequest(url));
imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE,
    function(e:Event) : void { imageLoaded(inc) });
}