perl DBI 和占位符

Question

我有这个查询 select * from table where ID in (1,2,3,5...)

如何使用占位符通过 DBI 构建此查询？

例如：

my @list = (1, 2, 3, 4, 5);
my $sql = "select * from table where ID in (?)";

$sth->prepare($sql);
$sth->execute();

我应该发送什么参数来执行？它是一个列表还是一个由 、 或其他内容分隔的字符串？

Answer 1

我总结了上述所有建议，找到了一种可行的方法。我的生产查询（我在这里发布了一个更简单的版本）使用 IN <>，其中代码及其数量都是未知的。它可以是单个代码（例如FIN），也可以是一系列代码（FITLC FITLD FITLU FITSC FITSD FITSU MDYLC MDYLD MDYLU）。某些函数将其作为列表返回。

实现这一点的代码是

            @codes =  get_muni_evcode( $category );
            my $in = join( ', ', ('?') x @codes );
            print "\n\nProcessing Category: $category --> Codes: @codes   .. in: $in\n";

            my $sql = "select distinct cusip9 
            from material_event 
            where event_date between (trunc(sysdate) - 1) + 2/3 and trunc(sysdate) + 2/3 
            and event_code in ($in)";
            my $sth2 = $dbh->prepare($sql);
            $sth2->execute( @codes );

            while (my $s2 = $sth2->fetchrow_hashref('NAME_lc'))
            {
                    my $cusip9 = $s2->{cusip9};
                    print "$cusip9\t";
                   .................. further processing ..............

            }

结果示例：

Processing Category: RatingChange -->代码： FITLC FITLD FITLU FITSC FITSD FITSU MDYLC MDYLD MDYLU MDYSC MDYSD MDYSU SPLD SPLPR SPLU SPSD SPSPR SPSU .. 中： ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?
359496HQ2 359496GB6 359496GH3 359496GL4 359496HU3 359496HS8 359496HA7 359496HF6 359496GM2 359496HM1 359496HR0 359496HT6 359496GY6 359496GJ9 359496HL3 359496GU4 359496HK5 359496HN9 359496HP4 359496GW0 359496GZ3 359496HC3 359496GC4 359496GK6 359496GP5 359496GV2 359496GX8 359496GN0

我非常感谢在这里发表想法的每个人，他们最终让我找到了正确的方法来做到这一点。我想这一定是一个很常见的问题。

Answer 2

这应该根据数组中的项目数动态构建您的查询

my @list =(1,2,3,4,5);
my $sql ="select * from table where ID in (@{[join',', ('?') x @list]})";

Answer 3

那样的话是不可能的。您需要为数组中的每个项目指定一个占位符：

my @list = (1,2,3,4,5);
my $sql = "select * from table where ID in (?,?,?,?,?)";

$sth->prepare($sql);
$sth->execute(@list);

如果您的 @list 不是固定大小，则需要使用适当数量的占位符构建 $sql 。

Answer 4

引用 DBI 文档：

此外，占位符只能表示单个标量值。例如，以下语句将不会按预期工作
对于多个值：

 SELECT 姓名、年龄 FROM people WHERE name IN (?) # 错误
     SELECT name,age FROM people WHERE name IN (?,?) # 两个名字

重写为：

my $sql = 'select * from table where ID in ( ?, ?, ?, ?, ? )';
$sth->prepare($sql);
$sth->execute(@list);

Answer 5

如果您使用 DBI 通过 DBD::Pg 驱动程序访问 PostgreSQL 数据库，则可以使用：

my @list = (1, 2, 3, 4, 5);
my $sql = "select * from table where ID = ANY(?::INT[]);";

$sth->prepare ($sql);
$sth->execute (\@list);

Answer 6

除非您知道元素的确切数量，否则不能使用占位符。试试这个：

my @list = (1, 2, 3, 4, 5);  # any number of elements
my $in = join(',', map { $dbh->quote($_) } @list);
my $sql = "select * from table where someid IN ($in)";

Answer 7

如果您切换到 DBIx::Simple 您可以直接说：

$db->query('INSERT INTO foo VALUES (??)', $foo, $bar, $baz);

??意思是“需要多少就多少”

编辑：

实际上，我有点太乐观了：“如果查询中存在字符串 (??)，它将被替换为 as 的列表许多问号为@values。”

所以这似乎不起作用：

$db->query( "SELECT * FROM foo WHERE id IN (??) AND stuff=?", @ids, $stuff )

但仍然有用......

对于好奇的人来说，模块中的代码是：

# Replace (??) with (?, ?, ?, ...)
sub _replace_omniholder {
  my ($self, $query, $binds) = @_;
  return if $query !~ /\(\?\?\)/;
  my $omniholders = 0;
  my $q = $self->{dbd} =~ /mysql/ ? $quoted_mysql : $quoted;
  $query =~ s[($q|\(\?\?\))] {
    $1 eq '(??)'
    ? do {
        Carp::croak('There can be only one omniholder')
            if $omniholders++;
        '(' . join(', ', ('?') x @$binds) . ')'
    }
    : $1
  }eg;
}