如何删除基于 J 列 = 0 内发布的行？

Question

我在 Excel 电子表格中有以下内容

如何根据其中发布的内容删除行J 列 = 0？

最好剪切该行并将其粘贴到另一张纸中。但是如果您可以帮助我删除它，那就太好了。

Answer 1

此代码自动筛选活动工作表上 J = 0 的行，将它们复制到第二个工作表上的第一个空白行，然后从活动工作表中删除这些行。

更改此行 Set ws2 = Sheets(2) 将行复制到不同的工作表，即 Set ws2 = Sheets("Your Sheet Name") 或 Set ws2 = Sheets(5) 第五张纸等

Sub MoveEm()
    Dim ws1 As Worksheet
    Dim ws2 As Worksheet
    Set ws1 = ActiveSheet
    Set ws2 = Sheets(2)
    Dim rng1 As Range
    Application.ScreenUpdating = False
    With ws1
        .AutoFilterMode = False
        .Columns("j").AutoFilter Field:=1, Criteria1:="0"
        With .AutoFilter.Range.Offset(1, 0).EntireRow
        Set rng1 = ws2.Cells.Find("*", ws2.[a1], xlValues, , xlRows, xlPrevious)
        If rng1 Is Nothing Then
        Set rng1 = ws2.[a1]
        Else
        Set rng1 = ws2.Cells(rng1.Row + 1, "A")
        End If
            .Copy rng1
            .Delete
        End With
        .AutoFilterMode = False
    End With
    Application.ScreenUpdating = True
End Sub

Answer 2

Sub Delete_Zero_Codes()  ' Deletes The Zero  Codes 
    Dim rCell As Range
    Dim strAddress As String
Application.ScreenUpdating = False

    With Thisworkbook.Sheets("sheetname").Columns("J")
        Set rCell = .Find(What:=0, LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByColumns)
        If Not rCell Is Nothing Then
            Do
            strAddress = rCell.Address
            rCell.EntireRow.Delete
            Set rCell = .FindNext(Range(strAddress))
            Loop Until rCell Is Nothing
        End If
    End With

Application.ScreenUpdating = True

End Sub

这些宏删除 J 列的零代码，并且不会将它们粘贴到其他工作表，如果您需要将 J 列的零代码复制到其他工作表，请告诉我，我会更新它