grails / gorm 支持 1 - 许多关联中的不同父实体

Question

我有以下“顶级”（父）域实体：

客户
公司
联系人

以及以下子实体：

地址

每个顶级域实体之间存在一对多关系：

客户 -> 客户地址
公司->地址
联系方式->地址

即客户、公司或联系人可以有一个或多个地址。

不幸的是我不知道如何在 grails / gorm 中对此进行建模。看来我只能在地址中定义一个父级或belongsTo声明，即我无法使用以下方式声明地址：

Address {
    Customer parent //??
    Company parent //??
    Contact parent //??
}

有人可以告诉我是否缺少某些内容或者是否可以以受支持的方式定义这种类型的关系？

谢谢，

考珀

Answer 1

正如 Tim 指出的那样，您应该能够使用 belongsTo 的数组版本：

Address {
    static belongsTo = [Customer, Company, Contact]
}

如果实体可以共享公共地址，则可能会改变您配置删除的方式。

另一种选择是让这三个类 从超类继承属性，但无论这对您的情况是否有意义，我不知道（看起来不像）。

Answer 2

在我们的应用程序中，我们有几个需要地址的实体。但我们选择以多对多关系对它们进行建模。

地址看起来像这样

class Address {

  // typical address properties

  Set<Company> getCompanies() {
    CompanyAddress.findAllByAddress(this).collect { it.company } as Set
  }

  static constraints = {
    // typical constraints
  }
}

对于每个“父母”，我们提供一个吸气剂。您可以在上面的代码中看到 getCompanies()。如果每个地址只有 1 个公司，那么只需让该 getter 返回 1 个公司而不是 Set。 Company 内部则相反，我们有一个 getAddresses()。

例如，公司地址看起来像这样......

class CompanyAddress implements Serializable{

  Address address
  Company company

  boolean equals(other) {

    if (this.is(other)){
      return true
    }

    if (!(other instanceof CompanyAddress)) {
      return false
    }

    other.address?.id == address?.id &&
        other.company?.id == company?.id
  }

  int hashCode() {
    def builder = new HashCodeBuilder()
    if (address) builder.append(address.id)
    if (company) builder.append(company.id)
    builder.toHashCode()
  }

  static CompanyAddress get(long companyId, long addressId) {
    find 'from CompanyAddress where address.id=:addressId and company.id=:companyId',
      [addressId: addressId, companyId: companyId]
  }

  static CompanyAddress create(Company company, Address address, boolean flush = false) {
    new CompanyAddress(address: address, company: company).save(flush: flush, insert: true)
  }

  static boolean remove(Company company, Address address, boolean flush = false) {
    CompanyAddress instance = CompanyAddress.findByAddressAndCompany(address, company)
    instance ? instance.delete(flush: flush) : false
  }

  static void removeAll(Address address) {
    executeUpdate 'DELETE FROM CompanyAddress WHERE address=:address', [address: address]
  }

  static void removeAll(Company company) {
    executeUpdate 'DELETE FROM CompanyAddress WHERE company=:company', [company: company]
  }

  static mapping = {
    id composite: ['address', 'company']
    version false
  }
}