如何处理来自 C++ 的 Objective-C 委托？

Question

简短版本：我有一个 Qt/C++，我必须向其中添加有限数量的 Cocoa/Objective-C 代码。我已将 .cpp 文件更改为 .mm 文件，并将 Objective-C 代码/对象添加到该文件中，它可以编译并运行。我现在需要我创建的对象之一的委托 - 准确地说是 NSPopUpButton （或者更确切地说，其菜单） - 但我陷入了困境。如何为该对象添加委托？

细节： 有问题的文件：

reportwindow.h、reportwindow.cpp 重命名为 reportwindow.mm -这些文件包含我的原始 C++ 实现以及一些 Objective-C 代码（打开包含 NSPopUpButton 的 NSSavePanel）。如果有影响的话，reportwindow.h 还包含在 .cpp 文件中。

菜单处理程序.h，菜单处理程序.mm -这些文件包含一个（当前为空的）objective-c 类，我打算将其用作委托

我的第一个想法是我可以简单地将 C++ 类作为委托，但这显然不起作用，因为直接 C++ 不起作用了解委托。然后我想我应该创建一个单独的 Objective-C 类作为 NSMenuDelegate 并将其实例作为成员对象添加到我的 C++ 类中。由于我已经能够添加其他 Objective-C 对象作为成员，我认为这应该可行。然而，一旦我将新的 Objective-C 类的标头包含在 C++ 类头文件中，我就会收到数百个关于“在 '@' 标记之前预期不合格的 id”的错误 - 来自苹果头文件 (NSValue.h) 、 NSObject.h 等）显然这不起作用，至少不能按原样起作用。当我的类头文件中包含任何可可头时，我得到相同的结果。

然后我想我应该尝试对 Objective-C 类进行前向声明（这就是我如何让其他 Objective-C 对象工作的）。但是，这也不起作用 - 如果我将其声明为“class myClassName”，我会收到有关将类重新定义为不同类型符号的错误（大概是 c++ 类与 Objective-c 协议）。如果我尝试将其转发声明为 @protocol myClassName，则会收到有关“‘@’令牌之前预期不合格的 id”的错误。那么我怎样才能做到这一点呢？

Answer 1

好的回答你的问题：

reportwindow.h 另外包含在 .cpp 文件中，如果这样的话
有区别。

它确实有所作为。任何涉及 Objective-C 代码的编译单元（在本例中为 cpp 文件）都必须重命名为 .mm 或 .m。包含标头反过来又将 Objective-C 内容包含在 C++ 文件中，将导致 C++ 编译器看到它无法处理的 Objective-C 代码的问题。

将 cpp 文件重命名为 mm 将在编译期间选择 Objective-C 选项（文件名为 cpp 或 c 时不会选择），因此允许使用 Objective-C 标记（在您的情况下主要是“@”）编译内容。

另一种方法是不将 Objective-C 委托类包含到 C++ 类中，而是在 Objective-C 委托中包含指向 C++ 类的指针（即以相反的方式实现它）。通过这种方式，您可以安排一些事情，使 Objective-C 代码不接触 C++ 代码。

编辑：实际上，我更喜欢第二个建议。下面是一个示例：

DelegateClass.h:

class MyCPPClassHandlingStuff;

@interface MyDelegateObject : NSObject <SomeDelegateProtocol> {
  MyCPPClassHandlingStuff *m_handlerInstance;
}

- (id) initWithCPPInstance:(MyCPPClassHandlingStuff*)cppInstance;

- (void) theDelegateProtocolMethod;

@end

DelegateClass.mm

#include "MyCPPClassHandlingStuff.h"

@implementation MyDelegateObject

- (id) initWithCPPInstance:(MyCPPClassHandlingStuff*)cppInstance
{
  self = [super init];
  if (self) {
    m_handlerInstance = cppInstance;
  }
  return self;
}

- (void) theDelegateProtocolMethod
{
  if (m_handlerInstance)
    m_handlerInstance->handleDelegateMethod();
}

@end

以及 MyCPPClassHandlingStuff.h:

#ifndef __MyCPPClassHandlingStuff_H__
#define __MyCPPClassHandlingStuff_H__

class MyCPPClassHandlingStuff
{
public:
  MyCPPClassHandlingStuff();
  void handleDelegateMethod();
};

#endif /* __MyCPPClassHandlingStuff_H__ */

MyCPPClassHandlingStuff 可以从 Objective-C 初始化，但不能从那里的 C++ 代码初始化任何 Objective-C 类。如果您需要在 C++ 代码中使用 Objective-C，则必须将其编译为 Objective-C（即使用 .mm 文件）。我将 .cpp 详细信息留给读者作为练习；）

Answer 2

创建一个 Objective-C 类来满足委托协议，并将其委托给您的 C++ 类。问题是 AppKit 期望与 Objective-C 对象对话，因此您需要一个垫片来委托给您的 C++ 对象。 （是的，你可以进行一些运行时滥用，在 C++ 类中定义一个 isa 指针，使其与 ObjC 对象在某种程度上兼容（达到可以向 C++ 类发送消息的程度），但不要这样做。这很糟糕。）

因此，制作一个用 C++ 类初始化的垫片，并将其作为 ivar。它应该实现您感兴趣的委托方法，并以它可以理解的方式将这些方法传递给您的 C++ 类。田田，完成了。

Answer 3

然后我想我应该尝试对 Objective-C 类进行前向声明（这就是我如何让其他 Objective-C 对象工作的）。但是，这也不起作用 - 如果我将其声明为“class myClassName”，我会收到有关将类重新定义为不同类型符号的错误（大概是 c++ 类与 Objective-c 协议）。

为什么不将其前向声明为@class myClassName？

Answer 4

我可以在编译和链接时将 C++ 主函数和类与 Objective-C 和/或 C 例程分开吗？