无法在 Tcl 中使用 upvar 将变量传递给过程

Question

我需要一个能够从调用者的命名空间访问、读取和更改变量的过程。该变量称为_current_selection。我尝试以几种不同的方式使用 upvar 来做到这一点，但没有任何效果。 （我编写了一个小测试过程只是为了测试 upvar 机制）。这是我的尝试：

---

call to proc:

select_shape $this _current_selection

proc:

proc select_shape {main_gui var_name} {
    upvar  $var_name curr_sel
    puts " previously changed:  $curr_sel"
    set curr_sel [$curr_sel + 1]
}

---

对于我的第二次尝试：

call to proc:

select_shape $this

proc:

proc select_shape {main_gui} {
    upvar  _current_selection curr_sel
    puts " previously changed:  $curr_sel"
    set curr_sel [$curr_sel + 1]
}

---

在所有尝试中，一旦到达代码中的此区域，它就会说 can't read "curr_sel": no such变量

我做错了什么？

编辑：

对该函数的调用是通过bind命令进行的：

$this/zinc bind current <Button-1> [list select_shape $this _current_selection]

一开始我认为这并不重要。但也许确实如此。

Answer 1

我相信 bind 命令在全局命名空间中运行，因此应该在全局命名空间中找到变量。这可能有效：

$this/zinc bind current <Button-1> \
    [list select_shape $this [namespace current]::_current_selection]

Answer 2

要使 upvar 工作，变量必须存在于您调用它的范围内。请考虑以下事项：

proc t {varName} {
   upvar $varName var
   puts $var
}

#set x 1
t x

如果按原样运行它，您将收到报告的错误，请取消注释 set x 1 线，它会起作用。

Answer 3

在下面的示例中，我尝试涵盖从其他名称空间更改变量的大多数变体。它 100% 对我有用。也许会有帮助。

proc select_shape {main_gui var_name} {
    upvar  $var_name curr_sel
    puts " previously changed:  $curr_sel"
    incr curr_sel
}

namespace eval N {
  variable _current_selection 1
  variable this "some_value"

  proc testN1 {} {
    variable _current_selection
    variable this
    select_shape $this _current_selection
    puts " new: $_current_selection"
  }

  # using absolute namespace name
  proc testN2 {} {
    select_shape [set [namespace current]::this] [namespace current]::_current_selection
    puts " new: [set [namespace current]::_current_selection]"
  }

  select_shape $this _current_selection
  puts " new: $_current_selection"
}

N::testN1
N::testN2

#-------------------------------------
# Example with Itcl class
package require Itcl

itcl::class C {
  private variable _current_selection 10

  public method testC {} {
    select_shape $this [itcl::scope _current_selection]
    puts " new: $_current_selection"
  }
}

set c [C #auto]
$c testC