Vb.net所有组合

Question

我有 6 个项目需要组合，

列出的项目：（这是一个例子）

• 猿
• 猿牛
• 牛鹿 | 鹿小鹿|大鹿
• 羊，

所以“鹿”有 2 个子项。

这些项目都在如下列出的列表中：

ape 奶牛 {鹿|小鹿|大鹿} 羊，

这样你就可以看到哪个项目有更多的项目。

我想要的是所有这些组合：

• ape 奶牛 鹿

• 猿 奶牛 小鹿

• 猿 奶牛 大鹿

（有时有超过 6 个项目，有时更少。

有人可以帮助我吗？

编辑：

有时列表也是这样的：

• 猿
• 牛
• 鹿 |小鹿|大鹿
• 羊
• 鼠|黑鼠|白鼠

（因此更多带有子项目的项目）

Answer 1

您将需要我的解决方案的变体，我在 在此解决方案中有类似的问题。也许这足以让你们相处？

可能你看不到答案，所以我把它复制到这里。有人想要将 1 和 2 的所有组合串联起来，长度为 3

   Dim HighestValue As Integer = 2 ' max value
    Dim NrOfValues As Integer = 3 ' nr of values in one result
    Dim Values(NrOfValues) As Integer
    Dim i As Integer
    For i = 0 To NrOfValues - 1
        Values(i) = 1
    Next
    Values(NrOfValues - 1) = 0 ' to generate first as ALL 1
    For i = 1 To HighestValue ^ NrOfValues
        Values(NrOfValues - 1) += 1
        For j As Integer = NrOfValues - 1 To 0 Step -1
            If Values(j) > HighestValue Then
                Values(j) = 1
                Values(j - 1) += 1
            End If
        Next
        Dim Result As String = ""
        For j As Integer = 0 To NrOfValues - 1
            Result = Result & CStr(Values(j))
        Next
        Debug.WriteLine(Result)
    Next

您将需要放置按 1、2 等索引的数组值，而不是数字本身，并为每个子列表发明类似的操作。

Answer 2

我无法评论@Martin 提供的方法，因为我不是专家交换的成员，但以下是我解决该问题的方法。

您想要一个 IEnumerable (of IEnumerable (of T))

当您有“Ape”时，您需要将其视为 {Ape}。这就是你的清单：

{Ape}，
{奶牛}，
{鹿，小鹿，大鹿}，
{sheep}

从那里，您可以通过对外部列表进行分组并迭代内部列表来构建组合。

IE 第一项 {Ape} 只有一个元素，因此您只需迭代一次。与 {Cow} 相同，但包含所有鹿的第三个将被迭代 3 次。

这应该足以让您开始。

Answer 3

这是 VB 2010 的递归解决方案（当有很多组合时，性能可能不是很好，但它是一个开始）：

Function GetCombinations(items As String()(), Optional index As Integer = 0) As List(Of String())
    Dim combinations As New List(Of String())
    Dim lastIndex = items.Count - 1
    Select Case index
        Case Is < 0, Is > lastIndex
            Throw New ArgumentException("index should be 0 or greater")
        Case lastIndex
            For Each item In items(index)
                combinations.Add({item})
            Next
        Case Else
            Dim nextCombinations = GetCombinations(items, index + 1)
            For Each item In items(index)
                For Each nextCombination In nextCombinations
                    combinations.Add({item}.Concat(nextCombination).ToArray)
                Next
            Next
    End Select
    Return combinations
End Function

测试代码：

Dim items = {({"Ape"}), ({"Cow"}), ({"Deer", "Small deer", "Big deer"}), ({"Sheep"}), ({"Mouse", "Black Mouse", "White mouse"})}
For Each combination In GetCombinations(items)
    Console.WriteLine(String.Join(", ", combination))
Next

测试输出：

Ape, Cow, Deer, Sheep, Mouse
Ape, Cow, Deer, Sheep, Black Mouse
Ape, Cow, Deer, Sheep, White mouse
Ape, Cow, Small deer, Sheep, Mouse
Ape, Cow, Small deer, Sheep, Black Mouse
Ape, Cow, Small deer, Sheep, White mouse
Ape, Cow, Big deer, Sheep, Mouse
Ape, Cow, Big deer, Sheep, Black Mouse
Ape, Cow, Big deer, Sheep, White mouse

Answer 4

想要输入字符串吗？并且没有递归？那么这是最终的解决方案，是我之前示例的简单改编：

    Dim Lines As New List(Of List(Of String))
    AddItem(Lines, "a ")
    AddItem(Lines, "b ")
    AddItem(Lines, "c1|c2|c3 ")
    AddItem(Lines, "d ")
    AddItem(Lines, "e1|e2")
    AddItem(Lines, "f ") ' etc
    Dim i As Integer
    Dim j As Integer
    Dim ItemnrInLine(Lines.Count - 1) As Integer
    Dim NrCombinations = 1
    For i = 0 To (Lines.Count - 1)
        ItemnrInLine(i) = 0
        NrCombinations *= Lines(i).Count
    Next
    ItemnrInLine(Lines.Count - 1) = -1 ' to get first combination as solution
    For i = 1 To NrCombinations
        ItemnrInLine(Lines.Count - 1) += 1
        For j = Lines.Count - 1 To 0 Step -1
            If ItemnrInLine(j) = Lines(j).Count Then
                ItemnrInLine(j) = 0
                ItemnrInLine(j - 1) += 1
            End If
        Next
        printOut(Lines, ItemnrInLine)
    Next

Sub printOut(ByVal Lines As List(Of List(Of String)), ByVal ItemnrInLine() As Integer)
    Dim Result As String = ""
    For k = 0 To Lines.Count - 1
        Result = Result & Lines(k)(ItemnrInLine(k)).Trim & " "
    Next
    Debug.WriteLine(Result)
End Sub

Sub AddItem(ByVal Lines As List(Of List(Of String)), ByVal inputString As String)
    Dim words() As String = inputString.Split("|"c)
    Dim wordList As New List(Of String)
    For i As Integer = 0 To words.Count - 1
        wordList.Add(words(i))
    Next
    Lines.Add(wordList)
End Sub