如何编写一个批处理文件，显示可执行文件的路径和 Python 版本，在 Windows 上处理 Python 脚本？

Question

对于直接调用 Python 运行的脚本 (python myscript.py) 以及直接运行的脚本 (myscript.py)，它应该显示可执行文件的路径和 Python 版本。脚本不应该对系统的配置做出太多假设。例如，它应该处理可能没有可用的 Python 的情况。

基本原理
我正在尝试设置运行 Python 脚本的环境的不同方法，我认为让一个脚本告诉我当前的配置是什么会很有帮助。我关心操作系统提供的标准方法 - PATH 环境变量以及文件类型与处理程序的关联（assoc 和 ftype 命令以及 PATHEXT 环境变量）。这使得 pylauncher 超出了这个问题的范围。

Answer 1

这可能就是您正在寻找的：

python -c "import sys; print sys.executable"

Answer 2

这是我的第一个解决方案：

解决方案 1

@echo off
set test_script=.pyexe.py
rem Let's create temporary Python script which prints info we need
echo from __future__ import print_function; import sys; print(sys.executable); print(sys.version) > %test_script%
echo Python accessible through system PATH:
python %test_script%
echo ---
echo Python set as handler for Python files:
%test_script%
del %test_script%
set test_script=

但是，我遇到了问题。当没有与 Python 文件关联的有效 Python 解释器时，尝试使用 some_script.py 打开 Python 文件时，会弹出打开方式系统对话框。解决这个问题需要对批处理文件有很好的了解。因此，试图提出一个解决方案，我提出了以下问题：

• 从命令窗口打开文件时如何防止“打开方式”对话框窗口?
• 如何转义批处理文件中 if 子句内带括号的变量？
• 为什么批处理文件中的延迟扩展在这种情况下不起作用？
• 如何在批处理文件中拆分带有嵌入空格的双引号字符串？

原始批处理文件的改进版本现在如下所示：

解决方案 1b

@echo off
setlocal
set test_script=.pyexe.py
rem Let's create temporary Python script which prints info we need
echo from __future__ import print_function; import sys; print(sys.executable); print(sys.version) > %test_script%
echo Python accessible through the system PATH:
python %test_script%
echo ---
echo Python set as a handler for Python files:
rem We need to check if a handler set in the registry exists to prevent "Open With"
rem dialog box in case it doesn't exist
rem ftype Python.File hypothetical return value:
rem Python.File="%PYTHON_HOME%\python.exe" "%1" %*
for /f "tokens=2 delims==" %%i in ('ftype Python.File') do set reg_entry=%%i
rem ...now in 'reg_entry' variable we have everything after equal sign:
rem "%PYTHON_HOME%\python.exe" "%1" %*
set "handler="
setlocal enableDelayedExpansion
for %%A in (!reg_entry!) do if not defined handler endlocal & set handler=%%A
rem ...now in 'handler' variable we have the first token:
rem "%PYTHON_HOME%\python.exe"
rem Now we expand any environment variables that might be present
rem in the handler's path
for /f "delims=" %%i in ('echo %handler%') do set expanded_handler=%%i
if exist "!expanded_handler!" (
    "%test_script%"
) else (
  if not "!handler!" == "!expanded_handler!" (
    set "handler=!expanded_handler! ^(!handler!^)"
  )
  echo Handler is set to !handler! which does not exist
)
del %test_script%

这是避免上述两个问题的另一种方法：

解决方案2

@echo off
setlocal
echo Python accessible through the system PATH:
where python
echo ---
echo Python set as a handler for Python source files (.py):
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\.py /ve') do set "file_type=%%k"
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\%file_type%\shell\open\command /ve') do echo %%k

...以及改进版本：

解决方案 2b

@echo off
setlocal EnableDelayedExpansion
echo Python interpreter accessible through the system PATH:
where python
if not errorlevel 1 (
    python -c "from __future__ import print_function; import sys; print(sys.version)"
)
echo ---
echo Python interpreter registered as a handler for Python source files (.py):
reg query HKCR\.py /ve >nul 2>&1
if errorlevel 1 (
    echo No "HKEY_CLASSES_ROOT\.py" registry key found
) else (
    for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\.py /ve 2^>nul') do set "file_type=%%k"
    if "!file_type!"=="(value not set)" (
        echo "No file type set for .py extension"
    ) else (
        reg query HKCR\!file_type!\shell\open\command /ve >nul 2>&1
        if errorlevel 1 (
            echo No "HKEY_CLASSES_ROOT\!file_type!\shell\open\command" registry key found
        ) else (
            for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\!file_type!\shell\open\command /ve 2^>nul') do set "handler=%%k"
            if "!handler!"=="(value not set)" (
                echo No command set for !file_type!
            ) else (
                echo !handler!
            )
        )
    )
)