在 Perl 中，如何使用 XML 文件中的数据生成 PDF 文件？

Question

可能的重复：
如何我使用 Perl 中的 XML 文件中的数据生成 PDF 文件？

我有存储在哈希中的 xml 标签，如下所示。

$var1={
     'stud.xml'={ 
                '24'=>'<address>
                        <streetname="xxxx"/>
                         <housenum="138"/">
                        </address>'
                 '20'=>'<address>
                       <streetname="xxxx"/>
                        <housenum="110"/">
                       </address>'
                     }...........

现在我需要使用 perl 脚本将其转换为 pdf。我搜索后发现 PDF::API2 是转换为 pdf 的最佳模块。阅读模块后，我可以创建新的 pdf 文件并设置一些设置，如字体、格式等......但我不明白如何将此 xml 数据处理为 pdf。

Answer 1

创建一个 LaTeX 模板，使用数据填充该模板，然后在其上运行 pdflatex。

请注意，您发布的 XMLish 内容没有帮助。发布实际的 XML 或 Perl 数据结构。

这是一个例子：

#!/usr/bin/env perl

use warnings; use strict;
use HTML::Template;
use XML::Simple;

my $xml = <<'EO_XML';
<students>
    <student id="24">
        <address>
            <streetname val="xxxx"/>
            <housenum val="138" />
        </address>
    </student>
    <student id="20">
        <address>
            <streetname val="xxxx"/>
            <housenum val="110" />
        </address>
    </student>
</students>
EO_XML

my $data = XMLin($xml)->{student};

my @loop_data;

for my $student (values %$data) {
    my $address = $student->{address};
    push @loop_data, {
        HOUSENUM => $address->{housenum}{val},
        STREETNAME => $address->{streetname}{val},
    };
}

my $tmpl = HTML::Template->new(filehandle => \*DATA);

$tmpl->param(STUDENTS => \@loop_data);
$tmpl->output(print_to => \*STDOUT);

__DATA__
\documentclass{article}

\begin{document}

<TMPL_LOOP STUDENTS>
<TMPL_VAR HOUSENUM> <TMPL_VAR STREETNAME>

</TMPL_LOOP>
\end{document}