无法读取子内的公共标量

Question

Perl代码如下：问题是我无法在子tweak_server{} ....

my $key;
my %hash = ( flintstones => [ "C:/Users1/f1.xml", "C:/Users1/f2.xml" ], 
            jetsons => [ "C:/Users2/f1.xml" ], 
            simpsons =>    [ "C:/Users3/f1.xml", "C:/Users3/f1.xml", "C:/Users3/f1.xml" ], ); 

foreach $key (keys%hash){
if (scalar@{$hash{$key}}>1){
    foreach my $path (@{$hash{$key}}){
        my $filehandle;
        open($filehandle, "+<$path") or die "cannot open out file out_file:$!";
        my $roots = { TAG => 1 };
        my $handlers = { 'ROOT/TAG' => \&tweak_server,
                    };
        my $twig = new XML::Twig(TwigRoots => $roots,
                             TwigHandlers => $handlers,
                             twig_print_outside_roots => \*$filehandle);
        $twig->parsefile($path);
        say $key;#could read key
        sub tweak_server {
            my ($twig, $root) = @_;
            my $tag2=$root->first_child_text('TAG2'); 
            say $key;# could not read
            if ($tag2=~/$key/){
            #BLABLA
            }
            $twig->flush( $filehandle, pretty_print => 'indented');
        }
    }
}

}

中读取$key，正如我所说，$key可以在子外部读取，但不能在内部读取..出现错误：使用未初始化的值$key

，然后我尝试了一个简单的情况，就像

my $a="aaa";
open( $filehandle, "+<$path") or die "cannot open out file out_file:$!";
my $roots = { TAG => 1 };
my $handlers = { 'ROOT/TAG' => \&tweak_server,
            };
my $twig = new XML::Twig(TwigRoots => $roots,
                     TwigHandlers => $handlers,
                     twig_print_outside_roots => \*$filehandle
                     );
$twig->parsefile($path);
sub tweak_server {
    say $a;
    my ($twig, $root) = @_;
    my $tags=$root->first_child_text('TAG2');
    my $str="204B";
    if ($tag2=~m/$str/){
    foreach my $b(1...6){
                    say $a;             }
}
$twig->flush( $filehandle, pretty_print => 'indented');

}

在这段代码中一样，$a可以被读取...... 我花了一天的时间，但仍然无法修复它......现在疯了 预先感谢！

Answer 1

您在 for 循环之外声明 $key。然后，在 for 循环内，定义一个在 $key 上结束的子例程。

作为一般规则，在最小的适用范围内声明变量。例如：

for my $key (keys ...) {

或者

open my $filehandle, '<', ...

为什么要在 for 循环体中定义 subtweak_server？在我看来，你想要做的是为每次迭代定义一个新的匿名子。

首先，一个简短的示例来复制您所观察到的内容：

use warnings; use strict;

my $key;
my %hash = qw(a b c d e f);

foreach $key (keys %hash) {
    somesub();
    sub somesub {
        print "$key\n";
    }
}

现在，修复：

use warnings; use strict;

my %hash = qw(a b c d e f);

foreach my $key (keys %hash) {
    my $somesub = sub { print "$key\n" };
    $somesub->();
}

这样，我们在每次迭代时定义一个新的匿名函数，并且每个新的子函数都会关闭循环变量的每个值。

就您的代码而言，您应该将命名的 sub 替换为

my $tweak_server = sub {
    my ($twig, $root) = @_;
    my $tag2=$root->first_child_text('TAG2'); 
    say $key;# could not read
    if ($tag2=~/$key/){
        #BLABLA
    }
    $twig->flush( $filehandle, pretty_print => 'indented');
}

my $handlers = { 
    'ROOT/TAG' => $tweak_server,
};

或者，更好的是，正如 @mirod 观察到的那样，将 $key 传递给 tweak_server：

sub tweak_server { 
    my( $key, $twig, $root)= @_;
    ...
}

并且，在循环，

my $handlers = { 
    'ROOT/TAG' => sub { tweak_server($key, @_) },
};

Answer 2

简短版本：如果您在另一个子程序内部或循环内部有一个命名子程序声明（sub foo { ... }），那么您可能做错了什么，您可能需要一个匿名子程序。这里就是这种情况。

---

sub foo { ... }

基本上与如果 sub 引用其自身之外的任何词法 (my) 变量相同

BEGIN { *foo = sub { ... }; }

，则在执行 sub 时（即在编译时）将捕获它们与命名的潜艇。一个常见的错误是这样做

sub outer {
    my ($x) = @_;

    sub inner {
       ... $x ...
    }

   outer();
}

不起作用，因为 my $x 被多次调用来创建多个变量，但 inner 仅捕获编译时存在的变量。 （幸运的是，它会发出警告。）

乍一看，您的代码只有一个名为 $key 的变量，因此在编译时捕获它应该没有问题。但他们的外表是骗人的。由于 foreach 的别名功能，迭代器变量根本不是循环外部的变量。

$ perl -E'
   my $x; say "x: ", 0+\$x;   # Show address of variable.
   my $y; say "y: ", 0+\$y;
   my $z; say "z: ", 0+\$z;
   for $x ($y, $z) { say "i: ", 0+\$x; }
'
x: 155771632
y: 155771584
z: 155771744
i: 155771584
i: 155771744

在您的情况下，您希望

$ perl -E'
   my $x; say "x: ", 0+\$x;
   my $y; say "y: ", 0+\$y;
   my $z; say "z: ", 0+\$z;
   for $x ($y, $z) {
      say "i: ", 0+\$x;
      sub f { say "f: ", 0+\$x; }
      f();
   }
'
x: 142992144
y: 142992096
z: 142992256
i: 142992096
f: 142992144
i: 142992256
f: 142992144

子程序在运行时捕获$x，这是通过使用匿名子程序来完成的。

$ perl -E'
   my $x; say "x: ", 0+\$x;
   my $y; say "y: ", 0+\$y;
   my $z; say "z: ", 0+\$z;
   for $x ($y, $z) {
      say "i: ", 0+\$x;
      my $f = sub { say "f: ", 0+\$x; };
      $f->();
   }
'
x: 159675200
y: 159675152
z: 159675312
i: 159675152
f: 159675152
i: 159675312
f: 159675312

---

修复：

for my $key (keys %hash) {
   if (@{ $hash{$key} } > 1) {
      for my $path (@{ $hash{$key} }) {
         open(my $fh, "+<", $path)             # +< ???
            or die("Can't open \"$path\": $!\n");

         my $tweak_server = sub {
            my ($twig, $root) = @_;
            ...
         };

         my $twig = new XML::Twig->new(
            TwigRoots => { TAG => 1 },
            TwigHandlers => { 'ROOT/TAG' => $tweak_server },
            twig_print_outside_roots => $fh,   # No need for \*$fh
         );
         $twig->parsefile($path);
      }
   }
}

您还可以使用匿名包装器将变量作为参数传递给命名子。

sub tweak_server {
   my ($fh, $key, $twig, $root) = @_;
   ...
}

for my $key (keys %hash) {
   if (@{ $hash{$key} } > 1) {
      for my $path (@{ $hash{$key} }) {
         open(my $fh, "+<", $path)             # +< ???
            or die("Can't open \"$path\": $!\n");

         my $twig = new XML::Twig->new(
            TwigRoots => { TAG => 1 },
            TwigHandlers => {
               'ROOT/TAG' => sub { tweak_server($fh, $key, @_) },
            },
            twig_print_outside_roots => $fh,   # No need for \*$fh
         );
         $twig->parsefile($path);
      }
   }
}