Perl：删除特定点的字符。

Question

我尝试搜索已经提出的问题，但似乎找不到任何东西。我确信它做起来非常简单，但我对 Perl 完全陌生。

我想要做的是删除字符串中的字符直到某个点。例如，我有：

Parameter1 : 0xFFFF

我想做的是删除“Parameter1:”并只留下“0xFFFF”。如果有人可以提供帮助并给出所使用的运算符的简单解释，那就太好了。

Answer 1

听起来您需要 substr 函数。

  #!/usr/bin/perl
  use strict;
  use warnings;

  my $string = 'Parameter1 : 0xFFFF';
  my $fragment =  substr $string, 12;
  print "  string: <$string>\n";
  print "fragment: <$fragment>\n";

Answer 2

s/.*:\s*//;

或

$s =~ s/.*:\s*//;

这将删除所有内容，直到并包括第一次出现的 : 后跟零个或多个空白字符。对于 $s =~ ，它会应用于 $s；如果没有它，它将应用于 $_。

Answer 3

您是否考虑过使用类似 Config::Std 的东西？

以下是如何手动解析这样的配置文件：

#!/usr/bin/perl

use strict; use warnings;

my %params;

while ( my $line = <DATA> ) {
    if ($line =~ m{
            ^
            (?<param> Parameter[0-9]+)
            \s*? : \s*?
            (?<value> 0x[[:xdigit:]]+)
        }x ) {
        $params{ $+{param} } = $+{value};
    }
}

use YAML;
print Dump \%params;

__DATA__
Parameter1 : 0xFFFF
Parameter3 : 0xFAFF
Parameter4 : 0xCAFE

使用 Config::Std：

#!/usr/bin/perl

use strict; use warnings;
use Config::Std;

my $config = do { local $/; <DATA> };

read_config \$config, my %params;

use YAML;
print Dump \%params;

__DATA__
Parameter1 : 0xFFFF
Parameter3 : 0xFAFF
Parameter4 : 0xCAFE

当然，在现实生活中，您可以将文件名传递给 read_config吸食它。

Answer 4

我喜欢分割这些参数/值对。

my $str = "Parameter1 : 0xFFFF";
my ($param, $value) = split /\s*:\s*/, $str, 2;

请注意在拆分中使用 LIMIT，它将拆分限制为两个字段（以防值中存在其他冒号）。