在 PL/SQL 中将绑定变量与动态 SELECT INTO 子句结合使用

Question

我有一个关于 PL/SQL 中的动态 SQL 语句中可以使用绑定变量的问题。

例如，我知道这是有效的：

CREATE OR REPLACE FUNCTION get_num_of_employees (p_loc VARCHAR2, p_job VARCHAR2) 
RETURN NUMBER
IS
  v_query_str VARCHAR2(1000);
  v_num_of_employees NUMBER;
BEGIN
  v_query_str := 'SELECT COUNT(*) FROM emp_' 
                 || p_loc
                 || ' WHERE job = :bind_job';                           
  EXECUTE IMMEDIATE v_query_str
    INTO v_num_of_employees
    USING p_job;
  RETURN v_num_of_employees;
END;
/

我想知道是否可以在这样的 select 语句中使用绑定变量

CREATE OR REPLACE FUNCTION get_num_of_employees (p_loc VARCHAR2, p_job VARCHAR2) 
RETURN NUMBER
IS
  v_query_str VARCHAR2(1000);
  v_num_of_employees NUMBER;
BEGIN
  v_query_str := 'SELECT COUNT(*) INTO :into_bind FROM emp_' 
                 || p_loc
                 || ' WHERE job = :bind_job';                           
  EXECUTE IMMEDIATE v_query_str
    USING out v_num_of_employees, p_job;
  RETURN v_num_of_employees;
END;
/

注意：我使用 SELECT INTO 语句作为动态字符串，并在 INTO 子句中使用绑定变量。

我目前正在旅行，几天之内无法使用家里的计算机，但这已经困扰了我一段时间。尝试阅读 PL/SQL 参考，但他们没有这样的选择示例。

谢谢

Answer 1

在我看来，动态 PL/SQL 块有些晦涩难懂。虽然非常灵活，但也很难调整、调试和弄清楚发生了什么。
我投票给你的第一个选项，

EXECUTE IMMEDIATE v_query_str INTO v_num_of_employees USING p_job;

两者都使用绑定变量，但首先，对我来说，比 @jonearles 选项更可重做和可调整。

Answer 2

不，你不能那样使用绑定变量。在第二个示例中，v_query_str 中的 :into_bind 只是变量 v_num_of_employees 值的占位符。您的 select into 语句将变成类似以下内容：

SELECT COUNT(*) INTO  FROM emp_...

因为 EXECUTE IMMEDIATE 时 v_num_of_employees 的值为 null。

您的第一个示例展示了将返回值绑定到变量的正确方法。

编辑

原始发帖者编辑了我在答案中提到的第二个代码块，以使用v_num_of_employees的OUT参数模式而不是默认值IN 模式。此修改使两个示例在功能上等效。

Answer 3

将 select 语句放在动态 PL/SQL 块中。

CREATE OR REPLACE FUNCTION get_num_of_employees (p_loc VARCHAR2, p_job VARCHAR2) 
RETURN NUMBER
IS
  v_query_str VARCHAR2(1000);
  v_num_of_employees NUMBER;
BEGIN
  v_query_str := 'begin SELECT COUNT(*) INTO :into_bind FROM emp_' 
                 || p_loc
                 || ' WHERE job = :bind_job; end;';
  EXECUTE IMMEDIATE v_query_str
    USING out v_num_of_employees, p_job;
  RETURN v_num_of_employees;
END;
/

Answer 4

绑定变量可以在带有“in”子句的 Oracle SQL 查询中使用。

10g 即可工作；我不知道其他版本。

绑定变量是 varchar，最多 4000 个字符。

示例：绑定变量包含以逗号分隔的值列表，例如

:bindvar = 1,2,3,4,5

select * from mytable
  where myfield in
    (
      SELECT regexp_substr(:bindvar,'[^,]+', 1, level) items
      FROM dual
      CONNECT BY regexp_substr(:bindvar, '[^,]+', 1, level) is not null
    );

（与我在此处发布的信息相同：如何使用变量在动态查询中指定 IN 子句？）

Answer 5

Select Into 功能仅适用于 PL/SQL 块，当您使用 立即执行 时，oracle 会将 v_query_str 解释为 SQL 查询字符串，因此您不能使用 into 。将会出现关键字丢失异常。
在示例 2 中，我们使用 begin end；所以它变成了 pl/sql 块并且是合法的。