您可以通过 cfscript 在函数中执行可选参数吗？

Question

我终于开始用 cfscript 编写东西了，所以我开始编写一些需要的格式化函数。这是一个示例：

    Function FormatBoolean(MyBool, Format) { 

    Switch(Format){
        Case "YES/NO":{
            If (MyBool eq 1)
                Return "YES";
            Else
                Return "NO";
            Break;
        }

        Default:{
            If (MyBool eq 1)
                Return "Yes";
            Else
                Return "";
            Break;
        }
    }
}

我想做的是将 Format 设为可选参数。如果不包含参数，该函数当前仍将运行，但找不到格式，并且 cfparam 似乎未转换为 cfscript。

我是否只需要检查格式是否已定义并给它一个值？或者有更好的方法吗？

谢谢

Answer 1

就我个人而言，我更喜欢为此类参数设置默认值。另外，我对函数进行了一些重构...但未经测试:)

function FormatBoolean(required any MyBool, string Format = "") { 

    switch(arguments.Format) {
        case "YES/NO":
            return YesNoFormat(arguments.MyBool EQ 1);
        default:
            return (arguments.MyBool eq 1) ? "Yes" : "";
    }

}

请注意，(arguments.MyBool EQ 1) 可能会替换为 (arguments.MyBool)，所以它涵盖了所有布尔值。您可能有兴趣使其更可靠，例如 (isValid("boolean",arguments.MyBool) AND argument.MyBool) ——这应该允许检查任何值。

Answer 2

传递到函数中的所有变量都可以通过 ARGUMENTS 范围以编程方式访问。您可以像数组一样引用它（因为它确实是数组），以及标准结构键访问（我在下面为 MyBool 参数完成的操作）：

<cfscript>
    Function FormatBoolean(MyBool) { 

    var theFormat = '';

    if (ArrayLen(ARGUMENTS) GT 1)
        theFormat = ARGUMENTS[2];

    Switch(theFormat){
        Case "YES/NO":{
            If (ARGUMENTS.MyBool eq 1)
                Return "YES";
            Else
                Return "NO";
            Break;
        }

        Default:{
            If (ARGUMENTS.MyBool eq 1)
                Return "Yes";
            Else
                Return "";
            Break;
        }
    }
}
</cfscript>

添加您首选的附加值必要时的数据验证级别。