为什么子类不继承其父类的常量？

Question

所以我正在处理我的 Moosey 业务，我想在我使用数字的这些地方使用常量可能会很好，以明确这些数字的含义或以防它们稍后发生变化

所以在父类中我添加了标准“使用常量”

package Parent;
    use constant {
        NO_LEVEL => 0,
        MY_LEVEL => 1,
        YOUR_LEVEL => 2,
    };

package Child;
extends 'Parent';

#just to demonstrate that child can or cannot access the constant
sub printMyLevel{
 print MY_LEVEL;
}

，但子类不知道父类中设置的常量！哦！

我猜我必须施展一些驼鹿魔法才能让它正常工作，或者完全是别的东西。我对这个问题的搜索没有得到任何结果=/

Answer 1

常量是子例程。

{
    package Parent;
    use Moose;
    use namespace::autoclean;

    use constant {
        NO_LEVEL => 0,
        MY_LEVEL => 1,
        YOUR_LEVEL => 2,
    };
    __PACKAGE__->meta->make_immutable;
};

{
    package Child;
    use Moose;
    use namespace::autoclean;

    extends 'Parent';

    sub printMyLevel {
        my $self = shift;
        my $class = ref $self;

        print $class->MY_LEVEL;
    }
    __PACKAGE__->meta->make_immutable;
}

package main;

my $child = Child->new;
$child->printMyLevel;

请记住，常量是具有空原型的子例程。 perl 利用这一点在编译期间内联它们。但是，方法调用忽略原型，因此以这种方式访问​​的可继承常量不会被内联。

Answer 2

这实际上在文档中提到过，如果只是顺便说一下：

“常量属于定义它们的包。要引用另一个包中定义的常量，请指定完整的包名称，如 Some::Package::CONSTANT 中。常量可以是由模块导出，也可以作为类或实例方法调用，即作为 Some::Package->CONSTANT 或作为 $obj->CONSTANT在哪里$obj 是 Some::Package 的实例。子类可以定义自己的常量来覆盖其基类中的常量。”

Answer 3

由于常量是子例程，并且您可以通过将它们作为方法调用来获得继承位已经被覆盖到了，这里有一个不同的旋转。

如果您知道您只在单个文件中工作，则可以使用词法常量来桥接包：

package Parent;
    our ($NO_LEVEL, $MY_LEVEL, $YOUR_LEVEL);
    *NO_LEVEL   = \0;  # this split declaration installs aliases to numbers
    *MY_LEVEL   = \1;  # into the lexicals.  since numbers are constants
    *YOUR_LEVEL = \2;  # to perl, the aliased names are also constants

package Child;

# just to demonstrate that anything below can access the constants
sub printAll {
    print "$NO_LEVEL $MY_LEVEL $YOUR_LEVEL\n";
}

Child->printAll; # 0 1 2

eval {$NO_LEVEL = 3} or print "error: $@\n";
# error: Modification of a read-only value attempted at ...

如果您在分配给常量时不需要 Perl 死机，则 our 声明会变得更简单一些（并且可以是 my）：

our ($NO_LEVEL, $MY_LEVEL, $YOUR_LEVEL) = (0, 1, 2);

您可以恢复常量性质，同时仍然使用简洁的语法，并带有一点魔力：

my $constant = sub {Internals::SvREADONLY($_[$_], 1) for 0 .. $#_};

package Parent;
    $constant->(our ($NO_LEVEL, $MY_LEVEL, $YOUR_LEVEL) = (0, 1, 2));

package Child;

# just to demonstrate that anything below can access the constants
sub printAll {
    print "$NO_LEVEL $MY_LEVEL $YOUR_LEVEL\n";  # interpolates :)
}

Child->printAll; # 0 1 2

eval {$NO_LEVEL = 3} or print "error: $@\n";
# error: Modification of a read-only value attempted at ...

您当然可以省略 $constant coderef 和内联魔法：

package Parent;
    Internals::SvREADONLY($_, 1)
        for our ($NO_LEVEL, $MY_LEVEL, $YOUR_LEVEL) = (0, 1, 2);

Answer 4

将它们称为方法。

sub printMyLevel{
    my ( $self, ) = $_;
    print $self->MY_LEVEL;
}

Answer 5

继承会影响方法调用 ($x->m)，句号。