如何使用 Windows 命令提示符删除空文件夹？

乙白 2024-12-17 15:34:41

您可以使用ROBOCOPY命令。它非常简单，也可用于删除大型层次结构中的空文件夹。

ROBOCOPY folder1 folder1 /S /MOVE

这里源和目标都是folder1，因为您只需要删除空文件夹，而不是将其他（必需）文件移动到不同的文件夹。 /S 选项是跳过复制（移动 - 在上述情况下）空文件夹。由于文件在同一驱动器内移动，因此速度也更快。

You can use the ROBOCOPY command. It is very simple and can also be used to delete empty folders inside large hierarchy.

ROBOCOPY folder1 folder1 /S /MOVE

Here both source and destination are folder1, as you only need to delete empty folders, instead of moving other(required) files to different folder. /S option is to skip copying(moving - in the above case) empty folders. It is also faster as the files are moved inside the same drive.

回复收藏 0 原文

何以心动 2024-12-17 15:34:41

一种更简单的方法是使用 /s 开关执行 xcopy 来复制整个目录结构。 /s 的帮助说复制目录和子目录（空目录除外）。

xcopy dirA dirB /S

其中 dirA 是带有空文件夹的源。 DirB 将是没有空文件夹的副本

A simpler way is to do xcopy to make a copy of the entire directory structure using /s switch. help for /s says Copies directories and subdirectories except empty ones.

xcopy dirA dirB /S

where dirA is source with Empty folders. DirB will be the copy without empty folders

回复收藏 0 原文

荒路情人 2024-12-17 15:34:41

for /f "usebackq" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

来自： http://blogs.msdn.com/b /oldnewthing/archive/2008/04/17/8399914.aspx

当然，在执行该命令之前，我会先测试它而不删除。另外，这里有一个来自评论的修改版本，其中包括带有空格的文件夹：

 for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

PS，博客文章中还有更多评论可能会对您有所帮助，因此在尝试之前也请务必阅读这些评论

for /f "usebackq" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

from: http://blogs.msdn.com/b/oldnewthing/archive/2008/04/17/8399914.aspx

Of course I'd test it first without deleting before I do that command. Also, here's a modded version from the comments that includes folders with spaces:

 for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

P.S. there are more comments in the blog post that might help you out so be sure to read those too before you try this out

回复收藏 0 原文

怪我太投入 2024-12-17 15:34:41

你不需要 usebackq：

FOR /F delims^= %%A IN ('DIR/AD/B/S^|SORT/R') DO RD "%%A"

You don't need usebackq:

FOR /F delims^= %%A IN ('DIR/AD/B/S^|SORT/R') DO RD "%%A"

回复收藏 0 原文

简单 2024-12-17 15:34:41

从同一引用页面添加到被腐蚀的答案是 PowerShell 版本 http://blogs.msdn.com/b/oldnewthing/archive/2008/ 04/17/8399914.aspx#8408736

Get-ChildItem -Recurse 。 |其中 { $_.PSISContainer -and @( $_ | Get-ChildItem ).Count -eq 0 } | Remove-Item

或者更简洁地说，

gci -R 。 |其中 { $_.PSISContainer -and @( $_ | gci ).Count -eq 0 } | ri

归功于发布者

回复收藏 0 原文

↙温凉少女 2024-12-17 15:34:41

从命令行：
for /R /D %1 in (*) do rd "%1"

在批处理文件中
for /R /D %%1 in (*) do rd "%%1"

我不知道是否有这样的记录，但它适用于 W2K、XP 和 Win 7。而且我不知道是否如此总是有效，但它永远不会意外删除文件。

回复收藏 0 原文

絕版丫頭 2024-12-17 15:34:41

这是上述的混合体。它会删除超过 X 天的所有文件，并删除给定路径的所有空文件夹。使用时只需设置日期、文件夹路径和驱动器

@echo off
SETLOCAL
set days=30
set folderpath=E:\TEST\
set drive=E:

::Delete files
forfiles -p %folderpath% -s -d -%days% -c "cmd /c del /q @path "

::Delete folders
cd %folderpath%
%drive%
for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"`

This is a hybird of the above. It removes ALL files older than X days and removes any empty folders for the given path. To use simply set the days, folderpath and drive

@echo off
SETLOCAL
set days=30
set folderpath=E:\TEST\
set drive=E:

::Delete files
forfiles -p %folderpath% -s -d -%days% -c "cmd /c del /q @path "

::Delete folders
cd %folderpath%
%drive%
for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"`

回复收藏 0 原文

甜柠檬 2024-12-17 15:34:41

它会工作得很好。这是删除旧文件并递归删除空目录的最佳方法。
下面的 .bat 文件是，

forfiles /p [PATH] /s /m [FILE-PATTERN] /d -[DAYS] /c "cmd /c del @path"
for /f "delims=" %%d in ('dir [PATH] /s /b /ad ^| sort /r') do rd "%%d"

占位符需要替换如下（不带引号）：

[DAYS] = Max. age of the files in days, e.g. “10”
[PATH] = Path to search for old files and empty folders, e.g. “C:\Backup\”
[FILE-PATTERN] = Pattern that matches files to delete, e.g. “*.bkp”

该脚本已在 Windows 7 和 Windows Server 2003 下成功测试。

It will be worked fine. This is best way to delete old files and remove empty directories recursively.
following .bat file is,

forfiles /p [PATH] /s /m [FILE-PATTERN] /d -[DAYS] /c "cmd /c del @path"
for /f "delims=" %%d in ('dir [PATH] /s /b /ad ^| sort /r') do rd "%%d"

The placeholders needs to be replaced as follows (without the quotation marks):

[DAYS] = Max. age of the files in days, e.g. “10”
[PATH] = Path to search for old files and empty folders, e.g. “C:\Backup\”
[FILE-PATTERN] = Pattern that matches files to delete, e.g. “*.bkp”

The script has been successfully tested under Windows 7 and Windows Server 2003.

回复收藏 0 原文

忆沫 2024-12-17 15:34:41

安装适用于 Windows 的任何 UNIX 解释器（Cygwin 或 Git Bash）并运行 cmd：

查找/path/to/directory -empty -type d

To find them

查找/path/to/directory -empty -type d -delete

To delete them

（并没有真正使用 Windows cmd 提示符，但它很简单，只需几秒钟即可运行）

Install any UNIX interpreter for windows (Cygwin or Git Bash) and run the cmd:

find /path/to/directory -empty -type d

To find them

find /path/to/directory -empty -type d -delete

To delete them

(not really using the windows cmd prompt but it's easy and took few seconds to run)

回复收藏 0 原文

z祗昰~ 2024-12-17 15:34:41

一个更现代、更简单的解决方案是：

forfiles /p C:\Path\To\Folder /c "cmd /c if @isdir==TRUE rd @file"

这将尝试在位于 C:\Path\To\Folder 中的所有目录上执行 rd。包含内容的目录不会被删除。

如果排除 /p C:\Path\To\Folder 那么它将在当前目录中运行。

如果您添加 /s （在 /c 之前），那么它也会查找子目录。

A more modern and easier solution is:

forfiles /p C:\Path\To\Folder /c "cmd /c if @isdir==TRUE rd @file"

This will attempt to execute rd on all the directories located in C:\Path\To\Folder. Directories that have content in them will not be deleted.

If you exclude /p C:\Path\To\Folder then it'll run in the current directory.

If you add /s (before the /c) then it'll also look in sub-directories.

回复收藏 0 原文

独享拥抱 2024-12-17 15:34:41

@echo off
set /p "ipa= ENTER FOLDER NAME TO DELETE> "
set ipad="%ipa%"
IF not EXIST %ipad% GOTO notfound
IF EXIST %ipad% GOTO found
:found
echo DONOT CLOSE THIS WINDOW
md ccooppyy
xcopy %ipad%\*.* ccooppyy /s > NUL
rd %ipad% /s /q
ren ccooppyy %ipad%
cls
echo SUCCESS, PRESS ANY KEY TO EXIT
pause > NUL
exit 
:notfound
echo I COULDN'T FIND THE FOLDER %ipad%
pause
exit

@echo off
set /p "ipa= ENTER FOLDER NAME TO DELETE> "
set ipad="%ipa%"
IF not EXIST %ipad% GOTO notfound
IF EXIST %ipad% GOTO found
:found
echo DONOT CLOSE THIS WINDOW
md ccooppyy
xcopy %ipad%\*.* ccooppyy /s > NUL
rd %ipad% /s /q
ren ccooppyy %ipad%
cls
echo SUCCESS, PRESS ANY KEY TO EXIT
pause > NUL
exit 
:notfound
echo I COULDN'T FIND THE FOLDER %ipad%
pause
exit

回复收藏 0 原文

伴随着你 2024-12-17 15:34:41

如果您想在资源管理器上下文菜单（即右键单击）中使用 Varun 的 ROBOCOPY 命令行，这里是 Windows 注册表导入。我尝试将此作为评论添加到他的答案中，但内联标记不可行。

我已在我自己的 Windows 10 PC 上对此进行了测试，但使用风险需您自担。它将打开一个新的命令提示符，运行命令，然后暂停，以便您可以看到输出。

复制到新的文本文件中：

Windows 注册表编辑器版本 5.00

[HKEY_CURRENT_USER\Software\Classes\directory\Background\shell\删除空文件夹\命令]
@="C:\Windows\System32\Cmd.exe /C \"C:\Windows\System32\Robocopy.exe \"%V\" \"%V\" /s /move\" && 暂停”

[HKEY_CURRENT_USER\Software\Classes\directory\shell\删除空文件夹\命令]
@="C:\Windows\System32\Cmd.exe /C \"C:\Windows\System32\Robocopy.exe \"%V\" \"%V\" /s /move\" && 暂停"
将 .txt 扩展名重命名为 .reg
双击导入。

回复收藏 0 原文

萌逼全场 2024-12-17 15:34:41

for /r "D:\Music" /d %F in (.) do @dir /b "%F" | findstr "^" >nul || rmdir %~fF

D:\Fun 是包含空文件夹的文件夹
文件夹名称中存在空格时使用双引号（本例中不需要）

for /r "D:\Music" /d %F in (.) do @dir /b "%F" | findstr "^" >nul || rmdir %~fF

D:\Fun is the folder that contains empty folders
double quotation in the case of space in folder name (no need in this example)

回复收藏 0 原文

美羊羊 2024-12-17 15:34:41

以下 .cmd 是一个实验（有效）：

删除空目录并在 %temp% 和 %temp% 下包含“旧”(-1days)文件。 C:\Windows\Temp 文件夹，
将 cmd 输出日志写入 .txt 文件，关于 fouded &已删除的文件夹/文件。

%temp% = C:\Users(用户)\AppData\Local\Temp | %userprofile%\AppData\Local\Temp

代码：

::  This is a .cmd file
::    Use to:
::        Writes a Log about Temporary files & folders.
::        Cleans 'Windows Temp' folders/files.    (%userprofile%\AppData\Local\Temp  -&-  %windir%\Temp)
::        - a 'Cleaning_LOGs.txt'  will be created or updated in  Documents Library.    (%userprofile%\Documents\Cleaning_LOGs.txt)
::        
@echo off
title Log&CleanTemp

: Set the Path of 'Log file'  (%LogPath% variable)
set "LogPath=%userprofile%\Documents\Cleaning_LOGs.txt"
::  Note: ">> path\file.txt 2>&1" redirects cmd output to <path\to>\<log_file.txt>,    (will be created if does not exist)
::        (if exist, adds the new log at the end of the file, without deleting previous logs)

: Set  'C:\Windows\Temp'  (%WinTemp% var.)
set "WinTemp=%windir%\Temp"

: Seperator [Header] with Date-Time between (any) previous Logs in <log_file.txt>
echo: >> %LogPath% 2>&1
echo ======================================== >> %LogPath% 2>&1
echo %date% - %time% >> %LogPath% 2>&1
echo: >> %LogPath% 2>&1
echo Log Path: %LogPath%  (this text file) >> %LogPath% 2>&1
echo: >> %LogPath% 2>&1

: Report Output & Log
::  Writes a log about temporary files & folders. 
::  Note: ( %temp% = C:\Users\<user>\AppData\Local\Temp = %userprofile%\AppData\Local\Temp )
::         ( 'WinTemp' = C:\Windows\Temp = %windir%\Temp )
echo: >> %LogPath% 2>&1
echo __________ Empty (0 size) , Old (-1days)  files: >> %LogPath% 2>&1
ForFiles /p "%temp%" /s /d -1 /c "cmd /c if @fsize==0 ECHO @path " >> "%LogPath%" 2>&1
ForFiles /p "%WinTemp%" /s /d -1 /c "cmd /c if @fsize==0 ECHO @path " >> "%LogPath%" 2>&1
echo: >> %LogPath% 2>&1
echo __________ All Old (-1days) files: >> %LogPath% 2>&1
ForFiles /p "%temp%" /s /d -1 /c "cmd /c ECHO @path " >> "%LogPath%" 2>&1
ForFiles /p "%WinTemp%" /s /d -1 /c "cmd /c ECHO @path " >> "%LogPath%" 2>&1
::  Note: "ForFiles"  /p=Path  /s=SubDir  /d=Days(dd)  /c=cmd    "forfiles /?"  for info about command's Variables (@path, @file, etc.)

: Get permissions (unlock files/folders) (OPTIONAL)
::  Uncomment to make it work, IF needed.
::echo: >> %LogPath% 2>&1
::ForFiles /p "%temp%" /s /d -1 /c "cmd /c TAKEOWN /f * /r /d y && ICACLS @file /grant *S-1-3-4:F /t /c /l /q"

: Clean proper files  & Log it
::   Test: ForFiles /p "%temp%\" /s /d -1 /c "cmd /c if @fsize==0 DEL /f /s /q @file" >> "%LogPath%" 2>&1
::        ERROR: Invalid argument/option - '@fsize==0'
echo: >> %LogPath% 2>&1
echo __________ Deleted files: >> %LogPath% 2>&1
forfiles /p %temp%\ /s /d -1 /c "cmd /c DEL /f /s /q @path" >> "%LogPath%" 2>&1
forfiles /p %WinTemp%\ /s /d -1 /c "cmd /c DEL /f /s /q @path" >> "%LogPath%" 2>&1
echo: >> %LogPath% 2>&1
echo __________ Deleted empty directories: >> %LogPath% 2>&1
for /f "delims=" %%d in ('dir %temp%\ /s /b /ad ^| sort /r') do RD "%%d" >> "%LogPath%" 2>&1
for /f "delims=" %%d in ('dir %WinTemp%\ /s /b /ad ^| sort /r') do RD "%%d" >> "%LogPath%" 2>&1
::  Note:  'RD' = Remove-Directory (delete)

: Open Log file
:: this opens the log file    [(my) Documents\Cleaning_LOGs.txt]
explorer.exe %LogPath%

:: https://stackoverflow.com/questions/7831286/how-to-delete-empty-folders-using-windows-command-prompt/46617314#46617314

注意：
作为“预处理”的一部分，进行此实验的触发因素是为了防止（也已过时的）声卡的特定（过时的）驱动程序在每次启动时自动重新安装。以及干净的（幻影的）隐藏设备等等。 (...)（这篇笔记只是想了解一下使用的想法）

所以，简而言之：
这是清理留下的“temp”垃圾并提供报告的部分。

The following .cmd is an experiment (that works) to:

Deletes empty directories and included "Old"(-1days) files under %temp% & C:\Windows\Temp folders,
makes an cmd output log to a .txt file, about fouded & deleted folders/files .

%temp% = C:\Users(user)\AppData\Local\Temp | %userprofile%\AppData\Local\Temp

code:

::  This is a .cmd file
::    Use to:
::        Writes a Log about Temporary files & folders.
::        Cleans 'Windows Temp' folders/files.    (%userprofile%\AppData\Local\Temp  -&-  %windir%\Temp)
::        - a 'Cleaning_LOGs.txt'  will be created or updated in  Documents Library.    (%userprofile%\Documents\Cleaning_LOGs.txt)
::        
@echo off
title Log&CleanTemp

: Set the Path of 'Log file'  (%LogPath% variable)
set "LogPath=%userprofile%\Documents\Cleaning_LOGs.txt"
::  Note: ">> path\file.txt 2>&1" redirects cmd output to <path\to>\<log_file.txt>,    (will be created if does not exist)
::        (if exist, adds the new log at the end of the file, without deleting previous logs)

: Set  'C:\Windows\Temp'  (%WinTemp% var.)
set "WinTemp=%windir%\Temp"

: Seperator [Header] with Date-Time between (any) previous Logs in <log_file.txt>
echo: >> %LogPath% 2>&1
echo ======================================== >> %LogPath% 2>&1
echo %date% - %time% >> %LogPath% 2>&1
echo: >> %LogPath% 2>&1
echo Log Path: %LogPath%  (this text file) >> %LogPath% 2>&1
echo: >> %LogPath% 2>&1

: Report Output & Log
::  Writes a log about temporary files & folders. 
::  Note: ( %temp% = C:\Users\<user>\AppData\Local\Temp = %userprofile%\AppData\Local\Temp )
::         ( 'WinTemp' = C:\Windows\Temp = %windir%\Temp )
echo: >> %LogPath% 2>&1
echo __________ Empty (0 size) , Old (-1days)  files: >> %LogPath% 2>&1
ForFiles /p "%temp%" /s /d -1 /c "cmd /c if @fsize==0 ECHO @path " >> "%LogPath%" 2>&1
ForFiles /p "%WinTemp%" /s /d -1 /c "cmd /c if @fsize==0 ECHO @path " >> "%LogPath%" 2>&1
echo: >> %LogPath% 2>&1
echo __________ All Old (-1days) files: >> %LogPath% 2>&1
ForFiles /p "%temp%" /s /d -1 /c "cmd /c ECHO @path " >> "%LogPath%" 2>&1
ForFiles /p "%WinTemp%" /s /d -1 /c "cmd /c ECHO @path " >> "%LogPath%" 2>&1
::  Note: "ForFiles"  /p=Path  /s=SubDir  /d=Days(dd)  /c=cmd    "forfiles /?"  for info about command's Variables (@path, @file, etc.)

: Get permissions (unlock files/folders) (OPTIONAL)
::  Uncomment to make it work, IF needed.
::echo: >> %LogPath% 2>&1
::ForFiles /p "%temp%" /s /d -1 /c "cmd /c TAKEOWN /f * /r /d y && ICACLS @file /grant *S-1-3-4:F /t /c /l /q"

: Clean proper files  & Log it
::   Test: ForFiles /p "%temp%\" /s /d -1 /c "cmd /c if @fsize==0 DEL /f /s /q @file" >> "%LogPath%" 2>&1
::        ERROR: Invalid argument/option - '@fsize==0'
echo: >> %LogPath% 2>&1
echo __________ Deleted files: >> %LogPath% 2>&1
forfiles /p %temp%\ /s /d -1 /c "cmd /c DEL /f /s /q @path" >> "%LogPath%" 2>&1
forfiles /p %WinTemp%\ /s /d -1 /c "cmd /c DEL /f /s /q @path" >> "%LogPath%" 2>&1
echo: >> %LogPath% 2>&1
echo __________ Deleted empty directories: >> %LogPath% 2>&1
for /f "delims=" %%d in ('dir %temp%\ /s /b /ad ^| sort /r') do RD "%%d" >> "%LogPath%" 2>&1
for /f "delims=" %%d in ('dir %WinTemp%\ /s /b /ad ^| sort /r') do RD "%%d" >> "%LogPath%" 2>&1
::  Note:  'RD' = Remove-Directory (delete)

: Open Log file
:: this opens the log file    [(my) Documents\Cleaning_LOGs.txt]
explorer.exe %LogPath%

:: https://stackoverflow.com/questions/7831286/how-to-delete-empty-folders-using-windows-command-prompt/46617314#46617314

Note that:
The trigger to Experiment with this, as part of a 'pre-process', was to prevent the specific (obsolete) driver of the (also obsolete) sound card from automatically reinstalling at each boot. And clean (ghosted) hidden Devices and more other. (...) (this note was just about to get an idea for the use)

So, in a few words:
This is the part that cleans up the 'temp' garbage left behind and gives a report.

回复收藏 0 原文

新雨望断虹 2024-12-17 15:34:41

在forfiles中使用for：

for /f "delims=" %%d in ('forfiles /s /p %delRoot% /c "cmd /c echo @path" 2^>nul ^| sort /R') do rd %%d 2>nul

自下而上删除需要排序/R

Use for in forfiles:

for /f "delims=" %%d in ('forfiles /s /p %delRoot% /c "cmd /c echo @path" 2^>nul ^| sort /R') do rd %%d 2>nul

sort /R required to delete bottom-up

回复收藏 0 原文

野生奥特曼 2024-12-17 15:34:41

好吧，只是一个快速而肮脏的建议，针对没有空格的简单一级目录结构，[编辑]以及仅包含我发现有用的一种类型文件的目录（在某些时候来自 http://www.pcreview.co.uk/forums/can-check-if-folder-empty-bat-file-t1468868.html):

for /f %a in ('dir /ad/b') do if not exist %a\*.xml echo %a Empty

/ad : 仅显示目录条目
/b ：使用裸格式（仅名称）

[编辑] 使用普通星号检查任何文件（上面的%a\*）将不起作用，感谢您的更正

，因此删除将是：

for /f %a in ('dir /ad/b') do if not exist %a\*.xml rmdir %a

well, just a quick and dirty suggestion for simple 1-level directory structure without spaces, [edit] and for directories containing only ONE type of files that I found useful (at some point from http://www.pcreview.co.uk/forums/can-check-if-folder-empty-bat-file-t1468868.html):

for /f %a in ('dir /ad/b') do if not exist %a\*.xml echo %a Empty

/ad : shows only directory entries
/b : use bare format (just names)

[edit] using plain asterisk to check for ANY file (%a\* above) won't work, thanks for correction

therefore, deleting would be:

for /f %a in ('dir /ad/b') do if not exist %a\*.xml rmdir %a

回复收藏 0 原文

阳光下慵懒的猫 2024-12-17 15:34:41

这可以通过使用带有两个参数的 rd 命令轻松完成：

rd <folder> /Q /S

/Q - 安静模式，不询问是否可以删除目录树
/S
/S - 删除指定目录中的所有目录和文件
除了目录本身。用于删除目录树。

This can be easily done by using rd command with two parameters:

rd <folder> /Q /S

/Q - Quiet mode, do not ask if ok to remove a directory tree with
/S
/S - Removes all directories and files in the specified directory
in addition to the directory itself. Used to remove a directory tree.

回复收藏 0 原文

如何使用 Windows 命令提示符删除空文件夹？

如果你对这篇内容有疑问，欢迎到本站社区发帖提问参与讨论，获取更多帮助，或者扫码二维码加入 Web 技术交流群。

发布评论

评论（17）

关于作者

相关话题

热门标签

推荐作者

已经忘了多久

15867725375

LonelySnow

走过海棠暮

轻许诺言

信馬由缰

友情链接

如何使用 Windows 命令提示符删除空文件夹？

如果你对这篇内容有疑问，欢迎到本站社区发帖提问 参与讨论，获取更多帮助，或者扫码二维码加入 Web 技术交流群。

发布评论

评论（17）

关于作者

相关话题

热门标签

推荐作者

已经忘了多久

15867725375

LonelySnow

走过海棠暮

轻许诺言

信馬由缰

友情链接

如果你对这篇内容有疑问，欢迎到本站社区发帖提问参与讨论，获取更多帮助，或者扫码二维码加入 Web 技术交流群。