在 DOS 批处理中比较 2 个数字不起作用

Question

我是 DOS 批处理编程的老手，也是新手。我有一个认为非常简单的批处理脚本，但无法工作。我搜索了类似的帖子，但没有找到匹配的帖子。

我在 XP 上运行以下脚本。我的目标是在继续操作之前检查可用磁盘空间，但我在比较 2 个数字时遇到了问题，因此下面的脚本仅包含该逻辑。我有硬编码的数字来显示问题，即...比较（if x gtr y）似乎不起作用，因此分支逻辑到了错误的地方。要么是这样，要么我在 IF 语句的其他地方搞砸了。 （有些 echo 语句是不必要的 - 它们用于调试 - 但我现在将它们保留在其中。）

对于我出错的地方的任何启发将不胜感激。

谢谢...

@echo off

set Free=217522712576
set Need=20000000000

echo Free=%Free%
echo Need=%Need%

echo on
IF %Free% GTR %Need% (GOTO Sufficient_Space) ELSE GOTO Insufficient_Space
@echo off

:Insufficient_Space
@ECHO INSUFFICIENT SPACE
GOTO DONE

:Sufficient_Space
@ECHO SUFFICIENT SPACE

:DONE

Answer 1

这些数字会溢出 32 位整数，因此猜测您在 32 位版本的 Windows 上，这就是它失败的原因。

C:\>set /a test=1+2
3

C:\>set /a test=1+217522712576
Invalid number.  Numbers are limited to 32-bits of precision.

Answer 2

正如其他人所说，数字太大了，但是如果你将它们保留为字符串并填充到相同的长度，它看起来会起作用

@echo off

rem cant do this get: Invalid number.  Numbers are limited to 32-bits of precision.
set Free=217522712576
set Need=2000000000

rem can do 
set Free=00000000000%Free%X
set free=%Free:~-13%

set Need=00000000000%Need%X
set Need=%Need:~-13%


echo Free=%Free%
echo Need=%Need%

echo on
IF %Free% GTR %Need% (GOTO Sufficient_Space) ELSE GOTO Insufficient_Space
@echo off

:Insufficient_Space
@ECHO INSUFFICIENT SPACE
GOTO DONE

:Sufficient_Space
@ECHO SUFFICIENT SPACE

:DONE

Answer 3

请注意，CMD 的精度介于 -2^31 到 2^31-1 之间
等于 -2 147 483 648 到 2 147 483 647
如果小于或大于限制
出现警告：号码无效。数字的精度限制为 32 位。